PackageTop Level
Classpublic final class int
Inheritanceint Inheritance Object

A data type representing a 32-bit signed integer. The range of values represented by the int class is -2,147,483,648 (-2^31) to 2,147,483,647 (2^31-1).

The properties of the int class are static, which means you do not need an object to use them, so you do not need to use the constructor. The methods, however, are not static, which means that you do need an object to use them. You can create an int object by using the int class constructor or by declaring a variable of type int and assigning the variable a literal value.

The int data type is useful for loop counters and other situations where a floating point number is not needed, and is similar to the int data type in Java and C++. The default value of a variable typed as int is 0

If you are working with numbers that exceed int.MAX_VALUE, consider using Number.

The following example calls the toString() method of the int class, which returns the string 1234: 

 var myint:int = 1234;
 myint.toString();

The following example assigns the value of the MIN_VALUE property to a variable declared without the use of the constructor:

 var smallest:int = int.MIN_VALUE;

View the examples.

See also
uint, Number

Public Constants
 PropertyDefined by
  MAX_VALUE : int = 2147483647
[static] The largest representable 32-bit signed integer, which is 2,147,483,647.
int
  MIN_VALUE : int = -2147483648
[static] The smallest representable 32-bit signed integer, which is -2,147,483,648.
int
Public Properties
Hide Inherited Public Properties
Show Inherited Public Properties
 PropertyDefined by
 Inheritedconstructor : Object
A reference to the class object or constructor function for a given object instance.
Object
 Inheritedprototype : Object
[static] A reference to the prototype object of a class or function object.
Object
Public Methods
Hide Inherited Public Methods
Show Inherited Public Methods
 FunctionDefined by
  
int(num:Object)
Constructor; creates a new int object.
int
 Inherited
hasOwnProperty(name:String):Boolean
Indicates whether an object has a specified property defined.
Object
 Inherited
isPrototypeOf(theClass:Object):Boolean
Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter.
Object
 Inherited
propertyIsEnumerable(name:String):Boolean
Indicates whether the specified property exists and is enumerable.
Object
 Inherited
setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void
Sets the availability of a dynamic property for loop operations.
Object
  
toString(radix:uint):String
Returns the string representation of an int object.
int
  
valueOf():int
Returns the primitive value of the specified int object.
int
Constant detail
MAX_VALUE constant
public static const MAX_VALUE:int = 2147483647

The largest representable 32-bit signed integer, which is 2,147,483,647.

Example
The following ActionScript displayswrites the largest and smallest representable ints to the Output panelto the log file: 
 trace("int.MIN_VALUE = "+int.MIN_VALUE);
 trace("int.MAX_VALUE = "+int.MAX_VALUE);

This code logsdisplays the following values:

 int.MIN_VALUE = -2147483648
 int.MAX_VALUE = 2147483647

MIN_VALUE constant
public static const MIN_VALUE:int = -2147483648

The smallest representable 32-bit signed integer, which is -2,147,483,648.

Example
The following ActionScript displayswrites the largest and smallest representable ints to the Output panel to the log file: 
     trace("int.MIN_VALUE = "+int.MIN_VALUE);
     trace("int.MAX_VALUE = "+int.MAX_VALUE);

This code logsdisplays the following values:

 int.MIN_VALUE = -2147483648
 int.MAX_VALUE = 2147483647

Constructor detail
int constructor

public function int(num:Object)

Constructor; creates a new int object. You must use the int constructor when using int.toString() and int.valueOf(). You do not use a constructor when using the properties of a int object. The new int constructor is primarily used as a placeholder. A int object is not the same as the int() function that converts a parameter to a primitive value.

Parameters
num:Object — The numeric value of the int object being created or a value to be converted to a number. The default value is 0 if value is not provided.

Example
The following code constructs new int objects: 
  var n1:int = new int(3.4);
  var n2:int = new int(-10);

See also
int.toString(), int.valueOf()
Method detail
toString method

public function toString(radix:uint):String

Returns the string representation of an int object.

Parameters
radix:uint — Specifies the numeric base (from 2 to 36) to use for the number-to-string conversion. If you do not specify the radix parameter, the default value is 10.

Returns
String — A string.

Example
The following example uses 2 and 8 for the radix parameter and returns a string that contains the corresponding representation of the number 9: 
  var myint:int = new int(9);
  trace(myint.toString(2)); // output: 1001
  trace(myint.toString(8)); // output: 11

The following example results in a hexadecimal value.

  var r:int = new int(250);
  var g:int = new int(128);
  var b:int = new int(114);
  var rgb:String = "0x"+ r.toString(16)+g.toString(16)+b.toString(16);
  trace(rgb); 
  // output: rgb:0xFA8072 (Hexadecimal equivalent of the color 'salmon')

valueOf method

public function valueOf():int

Returns the primitive value of the specified int object.

Returns
int — An int value.

Example
The following example results in the primative value of the numSocks object. 
  var numSocks = new int(2);
  trace(numSocks.valueOf()); // output: 2

Class examples

The following example uses the class IntExample to show how to work with and check the validity of int data types. This is accomplished using the following steps:
  1. Two int variables a and b are declared in the constructor.
  2. The two ints are added using the method addIntegers().
  3. A third int variable c is assigned the outcome of parseInteger(), which checks the validity of the string passed to it to ensure it is an integer value in the acceptable range for int data types and returns an int equal to the integer value of the string if it is valid.
  4. a and c are then added together using addIntegers().
package {
    import flash.display.Sprite;

    public class IntExample extends Sprite {    
        public function IntExample() {
            var a:int = 512;
            var b:int = -128;
            
            trace(addIntegers(a, b)); // 384

            var c:int = parseInteger("32");
            
            trace(addIntegers(a, c)); // 544
        }
            
        public function addIntegers(a:int, b:int):int {
            return a + b;
        }
        
        public function parseInteger(str:String):int {
            var num:Number = parseInt(str);
            if(!isNaN(num) && num <= int.MAX_VALUE && num >= int.MIN_VALUE) {
                return int(num);
            }
            
            return 0;
        }
        
    }
}



© 1996-2006 Adobe Systems Incorporated. All rights reserved.
Fri Apr 21 2006, 12:34 PDT