package {
    import flash.display.Sprite;

    public class ProxyExample extends Sprite {        
        public function ProxyExample() {
            var customArr:CustomArray = new CustomArray("one");
            customArr.push("two");
            customArr.push("three");
            customArr.push("four");
            
            trace(customArr.length);// 4
            trace(customArr[0]);    // one
            trace(customArr[1]);    // two
            trace(customArr[2]);    // three

            var lengthOfThree:CustomArray;
            lengthOfThree = customArr.select(3, function(item:String, value:int){ return item.length == value });
            trace(lengthOfThree);    // one,two
        }
    }
}

import flash.errors.IllegalOperationError;
import flash.utils.Proxy;
import flash.utils.flash_proxy;

dynamic class CustomArray extends Proxy {
    protected var arr:Array;
    protected var props:XML;
        
    public function CustomArray(... args) {
        arr = (args.length == 1 && !isNaN(args[0])) ? new Array(args[0]) : args;
        props = describeType(arr);
    }
        
    public function select(val:int, fn:Function):CustomArray {
        var selArr:CustomArray = new CustomArray();
        for(var i:uint = 0; i < arr.length; i++) {
            if(fn.call(this, arr[i], val)) {
                selArr.push(arr[i]);
            }
        }
        return selArr;
    }        
        
    flash_proxy override function callProperty(methodName:*, ...args):* {
        if(props.method.(@name == methodName.toString()).toXMLString() != "") {
            return arr[methodName.toString()].apply(null, args);
        }
            
        throw new IllegalOperationError("Error: Call to a possibly undefined method " + methodName.toString() + " through a reference with static type CustomArray");
    }
        
    flash_proxy override function getProperty(variableName:*):* {
        if((props.accessor.(@name == variableName.toString()).toXMLString() != "") || parseInt(String(variableName)) < arr.length) {
            return arr[variableName.toString()];
        }

        throw new IllegalOperationError("Error: Access of undefined property " + variableName.toString() + " through a reference with static type CustomArray");
    }
}