事後処理中に、デコードされたビデオに適用されるフィルタのタイプを示します。デフォルト値の 0 に設定すると、ビデオコンプレッサは必要に応じて非ブロックフィルタを適用します。

ビデオの圧縮によって、好ましくない生成結果となる場合があります。deblocking プロパティを使用して、ブロッキングと、On2 コーデックを使用して圧縮されたビデオのリンギングを低減するフィルタを設定できます。

ブロッキングとは、各ビデオフレームを構成するブロックの境界と境界の間に見られる不具合のことです。リンギングとは、ビデオイメージ内の要素の周囲が歪曲することです。

次の 2 つの非ブロックフィルタを使用できます。1 つは Sorenson コーデックにあり、もう 1 つは On2 VP6 コーデックにあります。さらに、On2 VP6 コーデックを使用する際にはリンギング除去フィルタを使用できます。フィルタを設定するには、次のいずれかの値を使用します。

• 0 - ビデオコンプレッサは必要に応じて非ブロックフィルタを適用します。
• 1 - 非ブロックフィルタを使用しません。
• 2 - Sorenson 非ブロックフィルタを使用します。
• 3 - On2 ビデオにのみ、On2 非ブロックフィルタを使用し、リンギング除去フィルタは使用しません。
• 4 - On2 ビデオにのみ、On2 非ブロックフィルタとリンギング除去フィルタを使用します。
• 5 - On2 ビデオにのみ、On2 非ブロックフィルタとパフォーマンスが向上した On2 リンギング除去フィルタを使用します。

Sorenson コーデックの使用時にビデオに 2 より大きい値を選択すると、Sorenson デコーダはデフォルトで 2 になります。

非ブロックフィルタを使用すると、全体的な再生のパフォーマンスに影響します。高帯域幅のビデオには、通常は必要ありません。非ブロックフィルタを有効にしたビデオは、処理能力の低いシステムでは再生が困難なことがあります。

ビデオを拡大 / 縮小する際にスムージング (補間) するかどうかを指定します。スムージングを行うには、Flash Player が高品質モードである必要があります。デフォルト値は false (スムージングなし) です。

Flash Player 9.0.115.0 以降のバージョンを使用するビデオ再生では、このプロパティを true に設定して、ミップマッピングイメージ最適化を利用します。

関連項目

ビデオストリームの高さをピクセル単位で指定する整数です。ライブストリームの場合、この値はビデオストリームをキャプチャしている Camera オブジェクトの Camera.height プロパティと同じです。FLV ファイルの場合、この値は FLV として書き出されたファイルの高さになります。

このプロパティは、ステージ上の実際の Video オブジェクトのサイズとは関係なく、キャプチャしたのと同じサイズでユーザーに対してビデオを表示する場合などに使用します。

関連項目

ビデオストリームの幅をピクセル単位で指定する整数です。ライブストリームの場合、この値はビデオストリームをキャプチャしている Camera オブジェクトの Camera.width プロパティと同じです。FLV ファイルの場合、この値は FLV ファイルとして書き出されたファイルの幅になります。

このプロパティは、ステージ上の実際の Video オブジェクトのサイズとは関係なく、キャプチャしたのと同じサイズでユーザーに対してビデオを表示する場合などに使用します。

関連項目

新しい Video インスタンスを作成します。width パラメータと height パラメータの値が指定されていない場合は、デフォルト値が使用されます。Video オブジェクトの初期構築後に、Video.width と Video.height を使用して幅と高さのプロパティを設定することもできます。新しい Video オブジェクトを作成する際に、幅または高さに 0 は設定できません。0 を渡すと、デフォルト値が適用されます。

Video オブジェクトの作成後、DisplayObjectContainer.addChild() メソッドまたは DisplayObjectContainer.addChildAt() メソッドを呼び出して、親 DisplayObjectContainer オブジェクトに Video オブジェクトを追加できます。

アプリケーション内の Video オブジェクトの境界内に表示するカメラからのビデオストリームを指定します。

このメソッドを使用して、ユーザーのコンピュータのライブビデオを Video オブジェクトに関連付けます。ライブビデオをキャプチャした同じコンピュータで、ローカルにライブビデオを再生することも、Flash Media Server に送信し、サーバーを使用して、他のユーザーにストリームすることもできます。

パラメータ

関連項目

アプリケーション内の Video オブジェクトの境界内に表示するビデオストリームを指定します。ビデオストリームは、NetStream.play() で再生される FLV ファイル、Camera オブジェクト、または null です。FLV ファイルを使用する場合、ファイルはローカルファイルシステムまたは Flash Media Server に保存できます。netStream 引数の値に null を指定すると、Video オブジェクト内でビデオが再生されなくなります。

FLV ファイルにオーディオしか含まれない場合は、このメソッドを使用する必要はありません。FLV ファイルのオーディオ部分は、NetStream.play() () が呼び出されると自動的に再生されます。FLV ファイルに関連付けられたオーディオを制御するには、FLV ファイルを再生する NetStream オブジェクトの soundTransform プロパティを使用します。

パラメータ

関連項目

Video オブジェクトに現在表示されているイメージ（ビデオストリームではない）をクリアします。このメソッドは、現在のイメージを処理する場合に便利です。例えば、最後のイメージをクリアしたり、Video オブジェクトを非表示にせずにスタンバイ情報を表示したりできます。

関連項目

この例では、Video オブジェクトと NetStream オブジェクトを作成し、Video.attachNetStream() および NetStream.play() メソッドを呼び出すコードがハンドラ関数に配置されます。ハンドラは、NetConnection オブジェクトへの接続が成功した場合にのみ呼び出されます。つまり、netStatus イベントが、成功したことを示す code プロパティと共に info オブジェクトを返す場合です。接続に成功するまで待ってから、NetStream.play() () を呼び出すことをお勧めします。

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class VideoExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function VideoExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }
    }
 }