Flash Player またはブラウザでのステージの配置を指定する StageAlign クラスの値です。使用できる値は次のとおりです。

align プロパティは、メイン SWF ファイルであるステージ所有者と同じセキュリティ Sandbox 内にあるオブジェクトでのみ使用できます。これを回避するには、ステージ所有者が Security.allowDomain() メソッドまたは Security.alowInsecureDomain() メソッドを呼び出して呼び出し元オブジェクトのドメインに許可を与えるようにします。詳細については、『ActionScript 3.0 のプログラミング』の「Flash Player セキュリティ」の章を参照してください。

関連項目

ディスプレイに対する Flash Player のカラー補正を制御します。カラー補正は、メインモニタに有効な ICC カラープロファイルが割り当てられている場合にのみ機能します。このカラープロファイルは、デバイスの特別なカラー属性を指定します。デフォルトでは、Flash Player はそのホスト (通常はブラウザ) と同じカラー補正を使用しようとします。

現在のシステムでカラー補正が使用できるかどうかとデフォルトの状態を確認するには、Stage.colorCorrectionSupport プロパティを使用します。カラー補正を利用できる場合、ステージのすべてのカラーは、最も標準的なカラー空間である RGB カラー空間にあると見なされます。カラー補正中、入力デバイスのソースプロファイルは考慮されません。入力カラー補正は適用されません。ステージ出力のみがメインモニタの ICC カラープロファイルにマップされます。

カラー管理をアクティブにする一般的な利点としては、予測可能な一貫性のあるカラー、変換性能の向上、正確なプルーフィング、より効率的なクロスメディア出力などがあります。ただし、色域がデバイスごとに異なり、元のイメージとも異なるため、カラー管理では完全な変換はできない点にご注意ください。また、カラー管理では、カスタムプロファイルも編集済みプロファイルも必要ありません。カラープロファイルは、ブラウザ、オペレーティングシステム（OS）、OS 拡張、出力デバイス、アプリケーションサポートに依存します。

カラー補正を適用すると、Flash Player のパフォーマンスが低下します。Flash Player のカラー補正は、ドキュメントスタイルのカラー補正です。このため、SWF ムービーはすべて暗黙の sRGB プロファイルを持つドキュメントと見なされます。Stage.colorCorrectionSupport プロパティを使用して、SWF (ドキュメント) をディスプレイカラースペースに表示するときに、最高レベルでカラー補正を行うことを Flash Player に通知します。Flash Player では、モニター間の補正のみを行い、カメラやスキャナなどの入力デバイス間の補正は行いません。

3 つの値として、flash.display.ColorCorrection クラスの対応する定数を持つストリングを使用できます。

• "default" : ホストシステムと同じカラー補正を使用します。
• "on" : 常にカラー補正を実行します。
• "off" : 常にカラー補正を実行しません。

関連項目

Flash Player が実行されているオペレーティングシステムがカラー補正をサポートしているかどうか、および Flash Player がメイン (主) モニタのカラープロファイルを解読できるかどうかを示します。また、このプロパティはホストシステム (通常はブラウザ) のカラー補正のデフォルト状態を返します。現在、戻り値は次のとおりです。

3 つの値として、flash.display.ColorCorrectionSupport クラスの対応する定数を持つストリングを使用できます。

• "unsupported" : カラー補正を使用できません。
• "defaultOn" : 常にカラー補正を実行します。
• "defaultOff" : 常にカラー補正を実行しません。

関連項目

使用する表示状態を指定する StageDisplayState クラスの値です。使用できる値は次のとおりです。

• StageDisplayState.FULL_SCREEN キーボード入力を無効にして、ユーザーの画面全体にステージを拡張するように AIR アプリケーションまたは Flash Player が設定されます。
• StageDisplayState.FULL_SCREEN_INTERACTIVE キーボード入力を許可して、ユーザーの画面全体にステージを拡張するように AIR アプリケーションが設定されます (Flash Player で実行されるコンテンツについては使用できません)。
• StageDisplayState.NORMAL によって、Flash Player を標準のステージ表示モードに戻します。

フルスクリーンモードでのムービーの拡大 / 縮小動作は、scaleMode 設定 (Stage.scaleMode プロパティまたは HTML ファイル内の SWF ファイルの embed タグ設定を使用して設定) で決定されます。アプリケーションがフルスクリーンモードに移行する際に、scaleMode プロパティが noScale に設定されていると、Stage の width プロパティと height プロパティが更新され、Stage の resize イベントが送出されます。

次の制限は、HTML ページで実行されている SWF ファイルに適用されます (スタンドアローンの Flash Player を使用する場合、または AIR ランタイムで実行されている場合には適用されません) 。

• フルスクリーンモードを有効にするには、次の例のように allowFullScreen パラメータを SWF ファイルを含む HTML ページの object および embed タグに追加します。このとき、allowFullScreen は "true" に設定します。

  <param name="allowFullScreen" value="true" />
           ...
    <embed src="example.swf" allowFullScreen="true" ... >

  HTML ページでは、スクリプトを使用して SWF 埋め込みタグを生成することもできます。allowFullScreen 設定が正しく挿入されるように、スクリプトを変更する必要があります。Flash および Flex Builder で生成された HTML ページでは、AC_FL_RunContent() 関数を使用して SWF ファイルへの参照を埋め込みます。ユーザーは、次のように allowFullScreen パラメータの設定を追加する必要があります。

  AC_FL_RunContent( ... "allowFullScreen", "true", ... )

• フルスクリーンモードは、マウスクリックまたはキー操作に対応して開始されます。ムービーでは、ユーザー入力なしに Stage.displayState を変更できません。Flash Player では、フルスクリーンモードでのキーボード入力は制限されます。入力可能なキーには、フルスクリーンモードを終了するキーボードショーカットや、矢印キー、スペースキー、Shift キー、Tab キーなどの非出力キーがあります。フルスクリーンモードは、次のキーボードショートカットで終了します。Esc キー（Windows、Linux、および Macintosh）、Ctrl + W （Windows）、Command + W （Macintosh）、および Alt + F4。

  フルスクリーンモードに入ると、ムービーの上に Flash Player ダイアログボックスが表示されます。このダイアログボックスには、現在フルスクリーンモードであり、Esc キーを押すとフルスクリーンモードを終了できるというメッセージが表示されます。

• Flash Player 9.0.115.0 以降からは、ウィンドウモードの場合と同じようにウィンドウレスモードでフルスクリーンモードが動作するようになりました。ウィンドウモード（HTML では wmode）を不透明表示（opaque）または透明表示（transparent）に設定すると、フルスクリーンを開始できますが、フルスクリーンウィンドウは常に不透明になります。

これらの制約は、スタンドアローンの Flash Player または AIR ランタイムで実行されている SWF コンテンツには適用されません。AIR では、キーボード入力を許可するインタラクティブフルスクリーンモードがサポートされています。

フルスクリーンモードで実行される AIR コンテンツの場合、システムのスクリーンセーバーと節電オプションは、ビデオコンテンツが再生中のときとビデオが停止するかフルスクリーンモードが終了するまで無効になっています。

Linux の場合、displayState を StageDisplayState.FULL_SCREEN または StageDisplayState.FULL_SCREEN_INTERACTIVE に設定する操作は非同期的に実行されます。

関連項目

package {
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.*;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    
    public class FullScreenExample extends Sprite
    {
        private var videoURL:String = "testVideo.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video;        
        
        public function FullScreenExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
            
            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK,toggleFullScreen);
        }        
        
        private function toggleFullScreen(event:MouseEvent):void {
            switch(stage.displayState) {
                case "normal":
                    stage.displayState = "fullScreen";    
                    break;
                case "fullScreen":
                default:
                    stage.displayState = "normal";    
                    break;
            }
        }    
        
        // Video related:
        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }
        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);

            video = new Video(stage.stageWidth,stage.stageHeight);
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }            
    }
}

キーボードフォーカスを持つインタラクティブオブジェクトです。フォーカスが設定されていない場合、またはフォーカスが設定されたオブジェクトが呼び出し元オブジェクトからアクセスできないセキュリティ Sandbox に属している場合は null となります。

ステージのフレームレートを取得または設定します。フレームレートの定義は、1 秒あたりのフレーム数です。デフォルトでは、フレームレートは最初にロードされた SWF ファイルのものに設定されます。フレームレートの有効範囲は、1 秒あたり 0.01 から 1000 フレームです。

メモ : ターゲットプラットフォームのフレーム設定が対応していないため、または Flash Player が表示デバイスの垂直帰線期間との同期が取れていないため、アプリケーションで高いフレームレートを設定できない場合があります。垂直帰線期間は、LCD デバイスでは通常 60 Hz です。CPU 使用率が高くなることが予想される場合、ターゲットプラットフォームの最大フレームレートを低くすることもできます。

Adobe AIR で実行されるコンテンツの場合、Stage オブジェクトの frameRate プロパティを設定することで、さまざまな NativeWindow オブジェクトによって使用されるすべての Stage オブジェクトのフレームレートが変更されます。

フルスクリーンサイズに移行したときに使用されるモニタの高さを返します (直ちに移行する場合)。ユーザーが複数のモニタを持っている場合、使用されるモニタは、そのときに最も多くのステージが表示されているモニタです。

メモ : 値を取得してから、フルスクリーンサイズに移行するまでの間に、あるモニタから別のモニタにブラウザを移動する機会がある場合、値が不正になる可能性があります。Stage.displayState を StageDisplayState.FULL_SCREEN に設定するイベントハンドラで値を取得すると、値は正しくなります。

これはモニタのピクセルの高さであり、Stage.align が StageAlign.TOP_LEFT に設定され、Stage.scaleMode が StageScaleMode.NO_SCALE に設定された場合には、ステージの高さと同じになります。

関連項目

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

ステージの特定の領域を Flash Player で拡大 / 縮小してフルスクリーンモードにするように設定します。可能な場合、拡大 / 縮小は、ユーザーのコンピュータ上でグラフィックカードやビデオカードを使用してハードウェアで行われます。通常、この方が、ソフトウェアで拡大 / 縮小するよりもすばやくコンテンツが表示されます。

このプロパティを有効な矩形に設定し、displayState プロパティをフルスクリーンモードに設定すると、指定された領域が Flash Player により拡大 / 縮小されます。ActionScript 内の実際のステージサイズ (ピクセル単位) は変更されません。標準の "フルスクリーンモードを終了するには、Esc キーを押します" というメッセージに対応するため、矩形のサイズに最小限度が適用されます。通常、この限度は約 260 × 30 ピクセルですが、プラットフォームおよび Flash Player のバージョンによって異なる場合があります。

このプロパティを設定できるのは、Flash Player がフルスクリーンモードでない場合のみです。このプロパティを正しく使用するには、コード例に示すように、このプロパティを最初に設定し、次に displayState プロパティをフルスクリーンモードに設定します。

拡大 / 縮小を有効にするには、次のように fullScreenSourceRect プロパティを矩形オブジェクトに設定します。

  
  // valid, will enable hardware scaling
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240); 
  

拡大 / 縮小を無効にするには、ActionScript 3.0 では fullScreenSourceRect=null に設定し、ActionScript 2.0 では undefined に設定します。

  stage.fullScreenSourceRect = null;
  

エンドユーザーが Flash Player の表示設定を使用して、ハードウェアの拡大 / 縮小をオフにすることもできます。この機能はデフォルトでは有効になっています。詳細については、www.adobe.com/go/display_settings_jp を参照してください。

関連項目

 
import flash.geom.*; 
{
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240);
  stage.displayState = StageDisplayState.FULL_SCREEN;
}

package {
    import flash.display.Sprite;
    import flash.display.StageDisplayState;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.NetStatusEvent;
    import flash.events.AsyncErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class Stage_fullScreenSourceRectExample2 extends Sprite {
        private var videoURL:String = "testVideo1.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var myVideo:Video;        
        private    var savedWidth:uint;
        private    var savedHeight:uint;
 
        public function Stage_fullScreenSourceRectExample2() {
    
            connection = new NetConnection();
             connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);    
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);

            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK, toggleFullScreen);
        }        

        private function toggleFullScreen(event:MouseEvent):void {

            if(stage.displayState == StageDisplayState.NORMAL) {
                myVideo.width = myVideo.videoWidth;
                  myVideo.height = myVideo.videoHeight;

                try {
                    stage.fullScreenSourceRect = new Rectangle(myVideo.x, myVideo.y, 
                                                           myVideo.width, myVideo.height);
                     stage.displayState = StageDisplayState.FULL_SCREEN;

                 } catch (e:SecurityError) {
                     trace ("A security error occurred while switching to full screen: " + event);
                    myVideo.width = savedWidth;
                    myVideo.height = savedHeight;
                 }

            }else {
                myVideo.width = savedWidth;
                myVideo.height = savedHeight;
                stage.displayState = StageDisplayState.NORMAL;
            }
        }    

       private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace ("Unable to locate video: " + videoURL);
                    break;
            }
        }

       private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);     

             myVideo = new Video();
            myVideo.attachNetStream(stream);
            stream.play(videoURL);

            savedWidth = myVideo.width;
            savedHeight = myVideo.height;

            addChild(myVideo);
        }
       
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);    
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            
        }            
    }
}

フルスクリーンサイズに移行したときに使用されるモニタの幅を返します (直ちに移行する場合) 。ユーザーが複数のモニタを持っている場合、使用されるモニタは、そのときに最も多くのステージが表示されているモニタです。

メモ : 値を取得してから、フルスクリーンサイズに移行するまでの間に、あるモニタから別のモニタにブラウザを移動する機会がある場合、値が不正になる可能性があります。Stage.displayState を StageDisplayState.FULL_SCREEN に設定するイベントハンドラで値を取得すると、値は正しくなります。

これはモニタのピクセル幅であり、Stage.align が StageAlign.TOP_LEFT に設定され、Stage.scaleMode が StageScaleMode.NO_SCALE に設定された場合には、ステージ幅と同じになります。

関連項目

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

表示オブジェクトの高さを示します (ピクセル単位)。この高さは、表示オブジェクトのコンテンツの境界に基づいて計算されます。次のコードに示すように、この height プロパティを設定すると、それに合わせて scaleY プロパティの値が調整されます。

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleY) // 1;
    rect.height = 200;
    trace(rect.scaleY) // 2;

TextField と Video オブジェクトを除いて、height を別の値に設定しようとしても、コンテンツのない表示オブジェクト (例えば、空のスプラインなど) の高さは 0 になります。

オブジェクトの子に対してマウスが有効かどうかを調べます。オブジェクトが使用可能なマウスの場合、マウスを使用して対話できます。デフォルト値は true です。

このプロパティは、SimpleButton クラスではなく、Sprite クラスのインスタンスを使用してボタンを作成するときに役立ちます。Sprite インスタンスを使用してボタンを作成する場合、他の Sprite インスタンスを追加するために addChild() メソッドを使用してボタンの修飾を選択できます。子として追加する Sprite インスタンスは、親インスタンスをターゲットオブジェクトとすることを想定するときに、マウスイベントのターゲットオブジェクトとなる場合があるため、マウスイベントについて予期しない動作を引き起こす可能性があります。親インスタンスが確実にマウスイベントのターゲットオブジェクトになるようにするには、親インスタンスの mouseChildren プロパティを false に設定します。

このプロパティを設定すると、イベントは送出されなくなります。インタラクティブな機能を作成するには、addEventListener() メソッドを使用する必要があります。

このステージを含む NativeWindow オブジェクトへの参照です。

window は、ネイティブのオペレーティングシステムのウィンドウを表します。Stage は、そのウィンドウに含まれるコンテンツを表します。このプロパティは、AIR で実行されているコンテンツでのみ有効です。Flash Player (ブラウザで実行されているコンテンツ) では、このプロパティは null になります。

このオブジェクトの子の数を返します。

使用するレンダリング品質を指定する StageQuality クラスの値です。使用できる値は次のとおりです。

• StageQuality.LOW — 低いレンダリング品質。グラフィックはアンチエイリアス処理されず、ビットマップはスムージングされません。この設定は Adobe AIR ではサポートされません。
• StageQuality.MEDIUM — 普通のレンダリング品質。グラフィックは 2 x 2 ピクセルグリッドを使用してアンチエイリアス処理されますが、ビットマップはスムージングされません。この設定は、テキストを含まないムービーに適しています。この設定は Adobe AIR ではサポートされません。
• StageQuality.HIGH — 高いレンダリング品質。グラフィックは 4 x 4 ピクセルグリッドを使用してアンチエイリアス処理されます。ビットマップは、ムービーが静的なものである場合は、スムージングされます。これは、Flash Player が使用するデフォルトのレンダリング品質設定です。
• StageQuality.BEST — 非常に高いレンダリング品質。グラフィックは 4 × 4 ピクセルグリッドを使用してアンチエイリアス処理され、ビットマップは常にスムージングされます。

品質設定が高ければ高いほど、拡大 / 縮小されたビットマップのよりよいレンダリングが生成されます。ただし、品質設定が高くなればなるほど計算上のコストも高くなります。特に、拡大 / 縮小されたビデオをレンダリングするときには、より高い品質の設定を使用するほうがフレームレートを減らすことができます。

Adobe AIR で実行されるコンテンツの場合、quality は StageQuality.BEST または StageQuality.HIGH に設定できます (また、デフォルト値は StageQuality.HIGH になります)。別の値に設定しても無視されます (プロパティは変更されません)。

Adobe AIR で実行されるコンテンツの場合、Stage オブジェクトの quality プロパティを設定することで、さまざまな NativeWindow オブジェクトによって使用されるすべての Stage オブジェクトのレンダリング品質が変更されます。

関連項目

使用する拡大 / 縮小モードを指定する StageScaleMode クラスの値です。使用できる値は次のとおりです。

• StageScaleMode.EXACT_FIT — 指定された領域にちょうど収まるようにアプリケーション全体が表示され、元の縦横比は保たれません。 歪みが発生し、アプリケーションが拡大または圧縮されて表示されることがあります。
• StageScaleMode.SHOW_ALL — 指定された領域内にアプリケーション全体が、アプリケーションの元の縦横比を維持したまま歪まずに表示されます。 ただし、アプリケーションの両側に境界枠が表示されることがあります。
• StageScaleMode.NO_BORDER — 指定された領域いっぱいにアプリケーション全体が歪まずに表示されます。ただし、アプリケーションの元の縦横比を保つために、ある程度トリミングされることがあります。
• StageScaleMode.NO_SCALE — アプリケーションの全体のサイズが固定され、プレーヤーウィンドウのサイズが変更された場合でも、サイズが維持されます。 Flash Player のウィンドウがコンテンツよりも小さい場合は、トリミングされることがあります。

関連項目

Flash Player のコンテキストメニューにデフォルトの項目を表示するかどうかを指定します。

showDefaultContextMenu プロパティを true に設定すると、すべてのコンテキストメニュー項目が表示されます。これがデフォルトです。showDefaultContextMenu プロパティを false に設定すると、メニュー項目として [設定] および [Adobe Flash Player について] だけが表示されます。

オブジェクトがフォーカスを持つ場合に強調表示された境界線を表示するかどうかを指定します。

現在のステージの高さ (ピクセル数) です。

ユーザーがウィンドウのサイズを変更するときに Stage.scaleMode プロパティの値が StageScaleMode.NO_SCALE に設定された場合、stageHeight プロパティが SWF ファイルで占有された画面領域の新しい高さサイズを反映するように変更されても、Stage コンテンツはそのサイズを維持します (他の伸縮モードでは、stageHeight プロパティは常に SWF ファイルの元の高さを反映します)。resize イベントにイベントリスナーを追加してから、Stage クラスの stageHeight プロパティを使用してサイズが変更された Flash Player ウィンドウの実際のピクセルサイズを決定することができます。イベントリスナーでは、ユーザーがウィンドウのサイズを変更するときに画面コンテンツがどのように調整されるかを制御できます。

メモ : SWF ファイルをホスティングする HTML ページでは、object タグおよび embed タグの height 属性はピクセル単位ではなくパーセンテージ (100% など) で設定する必要があります。設定が JavaScript コードによって設定される場合、height パラメータ (AC_FL_RunContent() メソッドのパラメータ) もパーセンテージで設定する必要があります。このパーセンテージは stageHeight 値に適用されます。

関連項目

ステージの現在の幅をピクセル単位で指定します。

ユーザーがウィンドウのサイズを変更するときに Stage.scaleMode プロパティの値が StageScaleMode.NO_SCALE に設定された場合、stageWidth プロパティが SWF ファイルで占有された画面領域の新しい幅サイズを反映するように変更されても、Stage コンテンツは定義済みのサイズを維持します (他の伸縮モードでは、stageWidth プロパティは常に SWF ファイルの元の幅を反映します)。resize イベントにイベントリスナーを追加してから、Stage クラスの stageWidth プロパティを使用してサイズが変更された Flash Player ウィンドウの実際のピクセルサイズを決定することができます。イベントリスナーでは、ユーザーがウィンドウのサイズを変更するときに画面コンテンツがどのように調整されるかを制御できます。

メモ : SWF ファイルをホスティングする HTML ページでは、object タグおよび embed タグの width 属性はピクセル単位ではなくパーセンテージ (100% など) で設定する必要があります。設定が JavaScript コードによって生成される場合、width パラメータ (AC_FL_RunContent() メソッドのパラメータ) もパーセンテージで設定する必要があります。このパーセンテージは stageWidth 値に適用されます。

関連項目

オブジェクトの子に対してタブが有効かどうかを調べます。オブジェクトの子に対してタブを有効または無効にします。デフォルト値は true です。

この DisplayObjectContainer インスタンスの TextSnapshot オブジェクトを返します。

表示オブジェクトの幅を示します (ピクセル単位)。この幅は、表示オブジェクトのコンテンツの境界に基づいて計算されます。次のコードに示すように、この width プロパティを設定すると、それに合わせて scaleX プロパティの値が調整されます。

    var rect:Shape = new Shape();
    rect.graphics.beginFill(0xFF0000);
    rect.graphics.drawRect(0, 0, 100, 100);
    trace(rect.scaleX) // 1;
    rect.width = 200;
    trace(rect.scaleX) // 2;

TextField と Video オブジェクトを除いて、width を別の値に設定しようとしても、コンテンツのない表示オブジェクト (例えば、空のスプラインなど) の幅は 0 になります。

この DisplayObjectContainer インスタンスに子 DisplayObject インスタンスを追加します。子インスタンスは、この DisplayObjectContainer インスタンスにある他のすべての子の前 (上) に追加されます。 (特定のインデックス位置に子を追加する場合は、addChildAt() メソッドを使用します。)

既に異なる表示オブジェクトコンテナを親に持つ子オブジェクトを追加する場合は、もう一方の表示オブジェクトコンテナの子リストからそのオブジェクトが削除されます。

パラメータ

関連項目

この DisplayObjectContainer インスタンスに子 DisplayObject インスタンスを追加します。子インスタンスは、指定されたインデックス位置に追加されます。インデックス 0 は、この DisplayObjectContainer オブジェクトの表示リストの背景または一番下を表します。

例えば、a、b、c というラベルの 3 個の表示オブジェクトをインデックス位置 0、2、1 にそれぞれ配置すると、以下のようになります。

既に異なる表示オブジェクトコンテナを親に持つ子オブジェクトを追加する場合は、もう一方の表示オブジェクトコンテナの子リストからそのオブジェクトが削除されます。

パラメータ

関連項目

イベントリスナーオブジェクトを EventDispatcher オブジェクトに登録し、リスナーがイベントの通知を受け取るようにします。イベントリスナーは、特定のタイプのイベント、段階、および優先度に関する表示リスト内のすべてのノードに登録できます。

イベントリスナーが正常に登録された後に、addEventListener() () をさらに呼び出して優先度を変更することはできません。リスナーの優先度を変更するには、最初に removeListener() () を呼び出す必要があります。その後、同じリスナーを新しい優先度レベルで再度登録できます。

リスナーが登録された後に、addEventListener()（type または useCapture に別の値を設定）を再度呼び出すと、別のリスナー登録が作成されることに注意してください。たとえば、最初にリスナーを登録するときに useCapture を true に設定すると、そのリスナーはキャプチャ段階のみでリスニングします。同じリスナーオブジェクトを使用して再度 addEventListener() を呼び出すと（このとき、useCapture を false に設定）、異なる 2 つのリスナーが登録されます。1 つはキャプチャ段階でリスニングするリスナーで、もう 1 つはターゲット段階とバブリング段階でリスニングするリスナーです。

ターゲット段階またはバブリング段階のみを対象とするイベントリスナーを登録することはできません。登録時にこれらの段階が組み合わされるのは、バブリングはターゲットノードの祖先にしか適用されないためです。

イベントリスナーが不要になった場合は、removeEventListener() を呼び出して、イベントリスナーを削除します。削除しない場合、メモリの問題が発生する可能性があります。ガベージコレクターは参照を有するオブジェクトを削除しないため、登録されているイベントリスナーに関係したオブジェクトはメモリから自動的に除去されません。

EventDispatcher インスタンスをコピーしても、それに関連付けられているイベントリスナーはコピーされません。新しく作成したノードにイベントリスナーが必要な場合は、ノードを作成した後に、リスナーを関連付ける必要があります。ただし、EventDispatcher インスタンスを移動した場合は、関連付けられているイベントリスナーも一緒に移動されます。

イベントがノードで処理されるときに、イベントリスナーがそのノードに登録中であれば、イベントリスナーは現在の段階ではトリガされません。ただし、バブリング段階など、イベントフローの後の段階でトリガすることができます。

イベントがノードで処理されているときにイベントリスナーがノードから削除された場合でも、イベントは現在のアクションによってトリガされます。削除された後は、その後の処理で再び登録されない限り、イベントリスナーは二度と呼び出されません。

パラメータ

function(evt:Event):void

関連項目

キーボードフォーカスを objectToFocus で指定されたインタラクティブオブジェクトに設定します。このとき、フォーカスの方向は direction パラメータで指定されます。

フォーカス方向の概念は、アプリケーション (またはアプリケーションフレームワーク) で定義する必要があります。インタラクティブオブジェクト固有のフォーカス並べ替え設定が存在しません。ただし、並べ替え方針を確立するには、利用可能な他のプロパティを使用することもできます。例えば、インタラクティブオブジェクトをステージ内のその位置によってまたは表示リストで並べ替えることができます。assignFocus() を呼び出すことは、Stage.focus プロパティを設定することと同じであり、さらに、フォーカスを設定する元の方向を示すという追加の機能もあります。

objectToFocus は、フォーカスを受け取ると focusIn イベントを送出します。FocusEvent オブジェクトの direction プロパティは、direction パラメータの設定を報告します。

HTMLLoader オブジェクトを objectToFocus パラメータに割り当てた場合、HTMLLoader オブジェクトは、direction パラメータ値に基づいて、HTML DOM 内で適切なフォーカス可能なオブジェクトを選択します。値が FocusDirection.BOTTOM である場合、読み取り順の最後にある HTML DOM 内のフォーカス可能なオブジェクトにフォーカスが設定されます。値が FocusDirection.TOP である場合、読み取り順の最初にある HTML DOM 内のフォーカス可能なオブジェクトにフォーカスが設定されます。値が NONE である場合は、現在フォーカスがあるエレメントを変更せずに、HTMLLoader オブジェクトにフォーカスが設定されます。

パラメータ

関連項目

イベントをイベントフローに送出します。イベントターゲットは EventDispatcher オブジェクトです。これに対して dispatchEvent() メソッドが呼び出されます。

パラメータ

EventDispatcher オブジェクトに、特定のイベントタイプに対して登録されたリスナーがあるかどうかを確認します。これにより、EventDispatcher オブジェクトがイベントタイプの処理をイベントフロー階層のどこで変更したかを判断できます。特定のイベントタイプが実際にイベントリスナーをトリガするかどうかを判別するには、willTrigger() () を使用します。

hasEventListener() と willTrigger() の違いは、hasEventListener() では自身が属するオブジェクトのみが検証され、willTrigger() では type パラメータで指定されたイベントのイベントフロー全体が検証されることです。

hasEventListener() が LoaderInfo オブジェクトから呼び出された場合は、呼び出し側がアクセスできるリスナーのみが考慮されます。

パラメータ

invalidate() メソッドは、表示リストをレンダリングする必要のある次の機会に、表示オブジェクトに警告するよう Flash Player に通知します。例えば、再生ヘッドを新しいフレームに進める場合などです。invalidate() メソッドを呼び出すと、表示リストが次にレンダリングされるときに、Flash Player から render イベントが、render イベントを受け取るように登録されている各表示オブジェクトに対して送出されます。その都度 invalidate() メソッドを呼び出す必要があります (Flash Player に render イベントを送出させたい場合) 。

render イベントによって、実際に表示される直前に表示リストに変更を加えることができます。こうすることで、表示リストへの更新を最後まで遅らせることが可能です。この方法では、画面の更新を不必要に行わなくてよいため、パフォーマンスを向上させることができます。

render イベントは、stage.invalidate() メソッドを呼び出すコードと同じセキュリティドメイン内の表示オブジェクト、または Security.allowDomain() メソッドで許可が与えられているセキュリティドメインの表示オブジェクトに対してのみ、送出されます。

関連項目

Stage.focus プロパティがセキュリティ上の理由で null を返すかどうかを決定します。つまり、フォーカスを持つオブジェクトが、SWF ファイルがアクセスできないセキュリティ Sandbox に属している場合、isFocusInaccessible は true を返します。

DisplayObjectContainer の子リストの指定された index 位置から子 DisplayObject を削除します。削除された子の parent プロパティは null に設定されます。その子に対する参照が存在しない場合、そのオブジェクトはガベージコレクションによって収集されます。DisplayObjectContainer の子より上位にある表示オブジェクトのインデックス位置は 1 つ下がります。

ガベージコレクターは、未使用のメモリスペースの再割り当てを行います。 変数またはオブジェクトがアクティブに参照されなくなり、任意の場所に保存されていない場合、ガベージコレクターによってメモリ内が探索され、それらに対する参照が存在しなければメモリスペースを占有している変数またはオブジェクトが一掃されます。

パラメータ

表示オブジェクトコンテナの既存の子の位置を変更します。これは、子オブジェクトのレイヤーに影響します。例えば、a、b、c というラベルの 3 個の表示オブジェクトをインデックス位置 0、1、2 にそれぞれ配置すると、以下のようになります。

setChildIndex() を使用し、既に占有されているインデックス位置を指定した場合、表示オブジェクトの前の位置と新しい位置の間にある位置だけが変化します。その他は変化しません。現在のインデックスよりも小さいインデックスに子を移動すると、その間のすべての子が、それぞれのインデックス参照について 1 増加します。現在のインデックスよりも大きいインデックスに子を移動すると、その間のすべての子が、それぞれのインデックス参照について 1 減少します。たとえば、上記の例の表示オブジェクトコンテナの名前が container である場合、次に示すコードを呼び出すことによって、a および b というラベルが付けられた表示オブジェクトの位置を入れ替えることができます。

container.setChildIndex(container.getChildAt(1), 0);

このコードによって、次に示すようなオブジェクトの配置になります。

パラメータ

子リスト内の指定されたインデックス位置に該当する 2 つの子オブジェクトの z 順序 (重ね順) を入れ替えます。表示オブジェクトコンテナの他のすべての子オブジェクトは、同じインデックス位置に残されます。

パラメータ

指定されたイベントタイプについて、この EventDispatcher オブジェクトまたはその祖先にイベントリスナーが登録されているかどうかを確認します。指定されたタイプのイベントがこの EventDispatcher オブジェクトまたはその子孫に送出されたときに、イベントリスナーがイベントフローの任意の段階でトリガされる場合、このメソッドは true を返します。

hasEventListener() と willTrigger() メソッドの違いは、hasEventListener() では自身が属するオブジェクトのみが検証され、willTrigger() メソッドでは type パラメータで指定されたイベントのイベントフロー全体が検証されることです。

willTrigger() が LoaderInfo オブジェクトから呼び出された場合は、呼び出し側がアクセスできるリスナーのみが考慮されます。

パラメータ

Stage オブジェクトが、フルスクリーンモードに設定または設定解除されると送出されます。フルスクリーンモードの変更は、ActionScript、ユーザーによるキーボードショートカットの呼び出し、または現在のフォーカスのフルスクリーンウィンドウからの移動によって開始できます。

このイベントには、次のプロパティがあります。

マウスポインタがステージ領域から離れたときに、Stage オブジェクトによって送出されます。

このイベントには、次のプロパティがあります。

Stage オブジェクトの scaleMode プロパティが StageScaleMode.NO_SCALE に設定され、SWF ファイルのサイズが変更されたときに送出されます。

このイベントには、次のプロパティがあります。

1. 最初にクラスコンストラクタは、Flash Player のウィンドウのサイズに関係なく、activateHandler() メソッドおよび resizeHandler() メソッドを使用して、固定する Flash アプリケーションを設定します。
2. マウスの左ボタンをクリックすると、activateHandler()メソッドが実行されます。
3. ステージのサイズを変更すると、resizeHandler() メソッドが実行されます。

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;

    public class StageExample extends Sprite {

        public function StageExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            stage.addEventListener(Event.ACTIVATE, activateHandler);
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function activateHandler(event:Event):void {
            trace("activateHandler: " + event);
        }

        private function resizeHandler(event:Event):void {
            trace("resizeHandler: " + event);
            trace("stageWidth: " + stage.stageWidth + " stageHeight: " + stage.stageHeight);
        }
    }
}