flash.desktop.DockIcon （Flex 3.2）

（AIR のみ）

パッケージ	flash.desktop
クラス	public class DockIcon
継承	DockIcon InteractiveIcon Icon EventDispatcher Object

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0

DockIcon クラスは MacOS X^® スタイルのドックアイコンを表します。

DockIcon クラスを使用すると、たとえば、アイコンをアニメーション化したり内容を表すグラフィックを追加して、標準のアイコンの外観を変更できます。ドックアイコンメニューにアイテムを追加することもできます。追加したメニューアイテムは、標準メニューアイテムよりも上に表示されます。

DockIcon クラスのインスタンスは作成できません。NativeApplication.icon からオペレーティングシステムドックアイコンを表すオブジェクトを取得します。

ドックアイコンのないオペレーティングシステムもあります。現在のシステムでドックアイコンがサポートされているかどうかを確認するには、NativeApplication.supportsDockIcon を調べます。ドックアイコンがサポートされている場合は、NativeApplication.icon プロパティのタイプが DockIcon に設定されています。サポートされていない場合、NativeApplication.icon のタイプは、InteractiveIcon の別のサブクラスである SystemTrayIcon などに設定されています。

重要 : AIR がドックアイコンをサポートしていないオペレーティングシステムで NativeApplication.icon オブジェクトの DockIcon クラスのメソッドを呼び出そうとすると、ランタイム例外が生成されます。

例を表示

	プロパティ	定義元
		bitmaps : Array [override] さまざまなサイズの BitmapData オブジェクトの配列としてのアイコンイメージです。	DockIcon
		constructor : Object 指定されたオブジェクトインスタンスのクラスオブジェクトまたはコンストラクタ関数への参照です。	Object
		height : int [override] [読み取り専用] アイコンの現在の表示の高さです (ピクセル単位)。	DockIcon
		menu : NativeMenu このドックアイコンのシステム指定のメニューです。	DockIcon
		prototype : Object [静的] クラスまたは関数オブジェクトのプロトタイプオブジェクトへの参照です。	Object
		width : int [override] [読み取り専用] アイコンの現在の表示幅です (ピクセル単位)。	DockIcon

	メソッド	定義元
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void イベントリスナーオブジェクトを EventDispatcher オブジェクトに登録し、リスナーがイベントの通知を受け取るようにします。	EventDispatcher
		bounce(priority:String = "informational"):void 注意を要するイベントが発生したことをユーザーに通知します。	DockIcon
		dispatchEvent(event:Event):Boolean イベントをイベントフローに送出します。	EventDispatcher
		hasEventListener(type:String):Boolean EventDispatcher オブジェクトに、特定のイベントタイプに対して登録されたリスナーがあるかどうかを確認します。	EventDispatcher
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメータとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し、列挙できるかどうかを示します。	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void EventDispatcher オブジェクトからリスナーを削除します。	EventDispatcher
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object
		willTrigger(type:String):Boolean 指定されたイベントタイプについて、この EventDispatcher オブジェクトまたはその祖先にイベントリスナーが登録されているかどうかを確認します。	EventDispatcher

	イベント	概要	定義元
		activate	[ブロードキャストイベント] Flash Player または AIR アプリケーションがオペレーティングシステムのフォーカスを取得して、アクティブになったときに送出されます。	EventDispatcher
		deactivate	[ブロードキャストイベント] Flash Player または AIR アプリケーションがオペレーティングシステムのフォーカスを失って、非アクティブになったときに送出されます。	EventDispatcher

プロパティの詳細

bitmaps

プロパティ

bitmaps:Array[override]

ランタイムバージョン:

AIR 1.0

さまざまなサイズの BitmapData オブジェクトの配列としてのアイコンイメージです。

指定されたオペレーティングシステムのコンテキストでアイコンを表示する場合、表示するサイズに最も近い配列のビットマップが使用されます (必要に応じて伸縮)。一般的なサイズには、16x16、32x32、48x48 および 128x128 があります (512x512 ピクセルのアイコンは、近い将来にいくつかのオペレーティングシステムアイコンで使用される可能性があります)。

一部のコンテキストでは、bitmaps プロパティに何も割り当てられていない場合、オペレーティングシステムがデフォルトのシステムアイコンを使用することがあります。その他のコンテキストでは、アイコンは表示されません。

アイコンの外観を設定または変更するには、BitmapData オブジェクトの配列を bitmaps プロパティに割り当てます。

  icon.bitmaps = new Array(icon16x16.bitmapData, icon128x128.bitmapData);

bitmaps 配列を直接変更しても効果はありません。

アイコンイメージを消去するには、bitmaps プロパティに空の配列を割り当てます。

メモ : アイコン用のイメージファイルをロードする場合、通常、最も適切なアルファブレンドが提供されるのは PNG ファイル形式です。GIF 形式は透明度のオンまたはオフのみをサポートし、ブレンドは行いません。JPG 形式は、透明度をまったくサポートしません。

実装
override public function get bitmaps():Array
override public function set bitmaps(value:Array):void

height

プロパティ

height:int [読み取り専用] [override]

ランタイムバージョン:

AIR 1.0

アイコンの現在の表示の高さです (ピクセル単位)。

一部のアイコンのコンテキストでは、動的なサイズ調整がサポートされます。height プロパティは、現在のコンテキストの bitmaps 配列から選択されたアイコンの高さを示します。オペレーティングシステムによってアイコンが伸縮されている場合は、実際の表示の高さはこれとは異なります。

実装
override public function get height():int

プロパティ

menu:NativeMenu

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0

このドックアイコンのシステム指定のメニューです。

メニュー内のすべてのアイテムは標準アイテムの上に表示されます。標準アイテムは変更および削除できません。

実装
public function get menu():NativeMenu
public function set menu(value:NativeMenu):void

例

次の例では、アイテムをドックアイコンメニューに追加します。

 import flash.desktop.NativeApplication;
 import flash.events.Event;
 
private function createDockIconMenu():void{
    if(NativeApplication.supportsDockIcon){                
        var dockIcon:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;
        
        var dockMenu:NativeMenu = new NativeMenu();
        var command:NativeMenuItem = dockMenu.addItem(new NativeMenuItem("Command"));
        command.addEventListener(Event.SELECT, onCommand);
        
        dockIcon.menu = dockMenu;
    }
}

 private function onCommand(event:Event):void{
     //do command...
 }

width

プロパティ

width:int [読み取り専用] [override]

ランタイムバージョン:

AIR 1.0

アイコンの現在の表示幅です (ピクセル単位)。

一部のアイコンのコンテキストでは、動的なサイズ調整がサポートされます。width プロパティは、現在のコンテキストの bitmaps 配列から選択されたアイコンの幅を示します。オペレーティングシステムによってアイコンが伸縮されている場合は、実際の表示幅はこれとは異なります。

実装
override public function get width():int

メソッドの詳細

bounce

()

メソッド

public function bounce(priority:String = "informational"):void

言語バージョン:

ActionScript 3.0

ランタイムバージョン:

AIR 1.0

注意を要するイベントが発生したことをユーザーに通知します。

アプリケーションがバックグラウンドで動作している場合にのみ、このメソッドを呼び出すとドックアイコンがバウンドします。priority が NotificationType.Informational の場合、アイコンが 1 回バウンドします。priority が NotificationType.Critical の場合、アプリケーションがフォアグラウンドで実行されるまで、ドックアイコンがバウンドします。

パラメータ

priority:String (default = "informational") — ドックがバウンドする緊急度です。

例

次の例では、ユーザーがアプリケーションをアクティブ化するまでドックアイコンがバウンドします。

 import flash.display.DockIcon;
 import flash.display.NotificationType;
 import flash.desktop.NativeApplication;

 if(NativeApplication.supportsDockIcon){
     var dockIcon:DockIcon = NativeApplication.nativeApplication.icon As DockIcon;
     dockIcon.bounce(NotificationType.CRITICAL);
 }

例例の使用法

DockIconExample.as

次の例では、一連のイメージをロードし、ドックメニューアイコンを使用してタイマーが起動されたときに、アイコンイメージをアニメーション化します。この例を動作させるには、一連のアイコンイメージを用意し、imageURLs 配列の URL を変更する必要があります。


 package {
    import flash.desktop.DockIcon;
    import flash.desktop.NativeApplication;
    import flash.display.Loader;
    import flash.display.NativeMenu;
    import flash.display.NativeMenuItem;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.TimerEvent;
    import flash.net.URLRequest;
    import flash.utils.Timer;

    public class AnimatedDockIcon extends Sprite
    {
        private var imageURLs:Array =  ['gfx/frame01.png',
                                        'gfx/frame02.png',
                                        'gfx/frame03.png',
                                        'gfx/frame04.png'];
        
        private var images:Array = new Array();
        private var animTimer:Timer = new Timer(100);
                                        
        public function AnimatedDockIcon()
        {
            NativeApplication.nativeApplication.autoExit = false;
            
            addEventListener(Event.COMPLETE, loadImages);
            loadImages();
            
            animTimer.addEventListener(TimerEvent.TIMER,advanceFrame);
            addMenu();
            stage.nativeWindow.close();
        }
        
        private function addMenu():void{
            var menu:NativeMenu = new NativeMenu();
            var start:NativeMenuItem = menu.addItem(new NativeMenuItem("Start animation"));
            var stop:NativeMenuItem = menu.addItem(new NativeMenuItem("Stop animation"));
            start.addEventListener(Event.SELECT, startTimer);
            stop.addEventListener(Event.SELECT, stopTimer);
            
            var dockIcon:DockIcon =    NativeApplication.nativeApplication.icon as DockIcon;
            dockIcon.menu = menu;
        }
        
        private function startTimer(event:Event):void{
            animTimer.start();
        }

        private function stopTimer(event:Event):void{
            animTimer.stop();
        }

        private var currentFrame:int = 0;
        private function advanceFrame(event:Event):void{
            if(currentFrame < images.length){
                currentFrame++;
            } else {
                currentFrame = 0;
            }
            NativeApplication.nativeApplication.icon.bitmaps = [images[currentFrame]];
        }
        

        private function loadImages(event:Event = null):void{
            if(event != null){
                images.push(event.target.content.bitmapData);
            }
            if(imageURLs.length > 0){
                var urlString:String = imageURLs.pop();
                var loader:Loader = new Loader();
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadImages, false, 0, true);
                loader.load(new URLRequest(urlString));
            } else {
                var complete:Event = new Event(Event.COMPLETE,false,false);
                dispatchEvent(complete);
            }
        }
    }
}

現在のページ: http://livedocs.adobe.com/flex/3_jp/langref/flash/desktop/DockIcon.html

Adobe® Flex™ 3.2 リファレンスガイド This Help system only	すべてのパッケージ \| すべてのクラス \| 言語エレメント \| 索引 \| 付録 \| 規則 \| フレームフレームなし
DockIcon	プロパティ \| メソッド \| イベント \| 例