指定是否应为此请求处理身份验证请求，如果是，则为 true，否则为 false。如果为 false，则验证挑战返回 HTTP 错误。

支持的身份验证方法有：

• Windows — HTTP 基本/摘要、Windows 集成式身份验证（包括 NTLM 和 Kerberos）、SSL 证书身份验证。
• Mac — HTTP 基本/摘要、NTLM、SSL 证书身份验证。

注意：FileReference.upload()、FileReference.download() 和 HTMLLoader.load() 方法不支持 URLRequest.authenticate 属性。

默认值为 true.

另请参见

指定是否应为此请求缓存成功的响应数据。设置为 true 时，AIR 应用程序将使用操作系统的 HTTP 缓存。

注意：HTMLLoader.load() 方法不支持 URLRequest.cacheResponse 属性。

默认值为 true.

另请参见

data 属性中内容的 MIME 内容类型。

注意：FileReference.upload()、FileReference.download() 和 HTMLLoader.load() 方法不支持 URLRequest.contentType 属性。

另请参见

一个对象，它包含将随 URL 请求一起传输的数据。

该属性与 method 属性一起使用。在 Adobe AIR 中，当使用 GET 以外的任意 HTTP 方法时发送数据。在 Flash Player 中，当使用 POST HTTP 方法时发送数据。

URLRequest API 支持二进制 POST，并支持 URL 编码变量和字符串。该数据对象可以是 ByteArray、URLVariables 或 String 对象。

该数据的使用方式取决于所用对象的类型：

• 如果该对象为 ByteArray 对象，则 ByteArray 对象的二进制数据用作 POST 数据。对于 GET，不支持 ByteArray 类型的数据。对于 FileReference.upload() 和 FileReference.download()，也不支持 ByteArray 类型的数据。
• 如果该对象是 URLVariables 对象，并且该方法是 POST，则使用 x-www-form-urlencoded 格式对变量进行编码，并且生成的字符串会用作 POST 数据。一种例外情况是对 FileReference.upload() 的调用，在该调用中变量将作为 multipart/form-data 发布中的单独字段进行发送。
• 如果该对象是 URLVariables 对象，并且该方法是 GET，则 URLVariables 对象将定义要随 URLRequest 对象一起发送的变量。
• 否则，该对象会转换为字符串，并且该字符串会用作 POST 或 GET 数据。

在方法（如 navigateToURL() 或 FileReference.upload()）使用 URLRequest 对象前，不会发送该数据。

另请参见

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

唯一地标识将存储到 Flash Player 缓存中（或从中检索）的已签名 Adobe 平台组件的字符串。摘要对应于单个缓存文件；如果对该文件进行了任何更改，则其摘要的更改将以不可预知的方式进行。通过使用摘要，您可以跨多个域验证缓存文件。具有相同摘要的两个文件是同一个文件，具有不同摘要的两个文件是不同的文件。实际上无法创建文件来“窃听”摘要以假装是另一个摘要。此属性仅适用于 SWF 内容，不适用于在 AIR 中运行的 JavaScript 代码。

摘要基于 SHA-256 消息摘要算法（长度为 64 个字符，采用十六进制格式）。

 
var myURLReq:URLRequest = new URLRequest();
myURLReq.url = "http://yourdomain/users/jdoe/test01/_rsc/Automated/AssetCaching_rsc/test01/rsl.swz";
myURLReq.digest = "3B0AA28C7A990385E044D80F5637FB036317BB41E044D80F5637FB036317BB41";
var myURLLoader:URLLoader = new URLLoader();
myURLLoader.dataFormat = URLLoaderDataFormat.BINARY;
myURLLoader.addEventListener("complete", onC);

myURLLoad.load(myURLReq);

function onC(e) {
    var someLoader:Loader = new Loader();
    addChild(someLoader);
    someLoader.loadBytes((ByteArray)(myURLLoad.data)); 
}

指定是否要遵循重定向，如果是，则为 true，否则为 false。

注意：FileReference.upload()、FileReference.download() 和 HTMLLoader.load() 方法不支持 URLRequest.followRedirects 属性。

默认值为 true.

另请参见

指定 HTTP 协议堆栈是否应管理此请求的 cookie。如果为 true，则将 cookie 添加到请求中并记住响应 cookie。如果为 false，则不 将 cookie 添加到请求中且不 记住响应 cookie，但用户可以通过直接处理标头来自行管理 cookie。

在 Mac OS 上，cookie 与 Safari 共享。清除 Mac OS 上的 cookie：

1. 打开 Safari。
2. 选择“Safari”>“首选参数”，然后单击“安全”面板。
3. 单击“显示 Cookie”按钮。
4. 单击“全部删除”按钮。

清除 Windows 上的 cookie：

1. 打开“Internet 属性”控制面板并单击“常规”选项卡。
2. 单击“删除 Cookie”按钮。

默认值为 true.

另请参见

控制 HTTP 式提交方法。

对于在 Flash Player 中（在浏览器中）运行的 SWF 内容，此属性限制为 GET 或 POST 操作，有效值为 URLRequestMethod.GET 或 URLRequestMethod.POST。对于在 Adobe AIR 中运行的内容，如果内容位于 application 安全域中，则可以使用任意字符串值；否则（如果内容在 AIR application 安全域中），仍将限于使用 GET 或 POST。

注意：如果在 Flash Player 中运行并且引用的表单没有正文，则即使未将该方法设置为 URLRequestMethod.POST，Flash Player 也会自动使用 GET 操作。

默认值为 URLRequestMethod.GET.

另请参见

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

要追加到 HTTP 请求的 HTTP 请求标头的数组。该数组由 URLRequestHeader 对象组成。数组中的每一对象必须是包含一个名称字符串和一个值字符串的 URLRequestHeader 对象，如下所示：

  var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
  

Flash Player 和 AIR 运行时对请求标头强加某些限制；有关详细信息，请参阅 URLRequestHeader 类的描述。

FileReference.upload() 和 FileReference.download() 方法不支持 URLRequest.requestHeaders 参数。

另请参见

所请求的 URL。

对于在 Flash Player 中运行的内容和在 Adobe AIR 中运行且不在 application 安全沙箱中的内容，默认情况下，URL 必须与调用文件位于完全相同的域中，包括子域。例如，分别位于 www.adobe.com 和 store.adobe.com 中的文件的域不同。

确保对统一资源定位器规范（请参阅 http://www.faqs.org/rfcs/rfc1738.html）中说明为不安全的字符或 URLRequest 对象的 URL 架构中保留的字符（如果未用于其保留用途）进行编码。例如，按照“http://www.example.com/orderForm.cfm?item=%23B-3&discount=50%25”的规定，对百分比符号 (%) 使用“%25”，对数字符号 (#) 使用“%23”。

若要从其它域中加载数据，请在承载数据的服务器上放置一个跨域策略文件。有关详细信息，请参阅 URLRequest 类说明中所述的安全性文档。此限制不适用于在应用程序安全沙箱中运行的 AIR 内容。

对于在 Adobe AIR 中运行的内容，应用程序安全域中的文件（随 AIR 应用程序一起安装的文件）可以通过使用以下任一 URL 架构访问 URL：

• http 和 https
• file
• app-storage
• app

注意：AIR 和 Flash Player 9.0.115.0 及其更高版本均支持 IPv6（Internet 协议版本 6）。IPv6 是支持 128 位地址的 Internet 协议版本（它是支持 32 位地址的早期 IPv4 协议的改进版本）。您可能需要在网络接口中激活 IPv6。有关详细信息，请参阅承载数据的操作系统的帮助。如果承载系统中支持 IPv6，您可以在用方括号 ([]) 括起的 URL 中指定数字 IPv6 文本地址，如下所示：

指定在此 URLRequest 获取数据之前是否应查询本地缓存。

注意：HTMLLoader.load() 方法不支持 URLRequest.useCache 属性。

默认值为 true.

另请参见

指定要在 HTTP 请求中使用的用户代理字符串。

默认值是由 Flash Player 使用的同一用户代理字符串，该字符串在 Mac 和 Windows 上不同。

注意：在将 URLRequest 对象与 HTMLLoader 对象的 load() 方法一起使用时，此属性不影响用户代理字符串。若要设置 HTMLLoader 对象的用户代理字符串，请设置 HTMLLoader 对象的 userAgent 属性或设置静态 URLRequestDefaults.userAgent 属性。

另请参见

创建 URLRequest 对象。如果 System.useCodePage 为 true，则使用系统代码页对该请求进行编码，而不使用 Unicode。如果 System.useCodePage 为 false，则使用 Unicode 对该请求进行编码，而不使用系统代码页。

另请参见

若要运行该示例，请将名为 XMLFile.xml 的文件与 SWF 文件放在同一个目录下。

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {

        public function URLRequestExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}