一个字符串数组，其中包含此 Clipboard 对象中的可用数据格式的名称。

用作标准格式名称的字符串常量在 ClipboardFormats 类中定义。应用程序定义的其他字符串也可以用作要作为对象传输的数据的格式名称。

另请参见

 var availableFormats:Array = Clipboard.generalClipboard.formats;

操作系统剪贴板。

粘贴到系统剪贴板中的任何数据均对其他应用程序可用。这可能包括网络浏览器中运行的不安全的远程代码。

generalClipboard 对象是自动创建的。不能为此属性分配 Clipboard 的另一个实例。改用 getData() 和 setData() 方法可以读取现有对象中的数据和将数据写入现有对象。

在向剪贴板中写入新数据之前，应始终清理剪贴板，以确保擦除所有格式的旧数据。

创建空 Clipboard 对象。

另请参见

 import flash.desktop.Clipboard;
 
 var clipboard:Clipboard = new Clipboard();

从此 Clipboard 对象中删除所有数据表示形式。

 Clipboard.generalClipboard.clear();

删除指定格式的数据表示形式。

参数

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.clearData(ClipboardFormats.TEXT_FORMAT);

如果指定格式的数据存在，则获取剪贴板数据。

在访问标准数据格式时，将会以相应 AIR 类型的新对象的形式返回数据。

在访问应用程序定义的格式时，transferMode 参数的值确定是返回对原始对象的引用，还是返回包含原始对象的序列化副本的匿名对象。如果指定了 originalPreferred 或 clonePreferred 模式，则当首选的版本不可用时，AIR 将返回替代版本。如果指定了 originalOnly 或 cloneOnly 模式，则当请求的版本不可用时，AIR 将返回 undefined。

参数

另请参见

 import flash.desktop.ClipboardFormats;

 var pasteData:String = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT) as String;

检查指定格式的数据在此 Clipboard 对象中是否存在。

使用 ClipboardFormats 类中的常量以检查是否存在标准格式的数据。

参数

另请参见

if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
    //do something 
}

使用指定的数据格式添加要传输的信息的表示形式。

可以将相同信息的不同表示形式以不同格式添加到剪贴板，这可提高其他组件或应用程序利用可用数据的能力。例如，图像可以添加为位图数据以供图像编辑应用程序使用、添加为 Bitmap 对象供其他 AIR 应用程序使用以及添加为编码的 PNG 文件以便传输到本机文件系统。

data 参数必须是适用于指定格式的相应数据类型：

自定义格式名称不能以“air:”或“flash:”开头。为了避免在使用自定义格式时发生命名冲突，您可能希望使用应用程序 ID 或包名称作为格式的前缀，如“com.example.applicationName.dataPacket”。

当在 AIR 应用程序内或 AIR 应用程序之间传输时，serializable 参数确定引用和副本是否都可用，或是否只有对象的引用才可用。将 serializable 设置为 true 可使该数据对象的引用和副本都可用。将 serializable 设置为 false 则只使对象引用可用。对象引用仅在当前应用程序中有效，因此，将 serializable 设置为 false 还意味着使用该格式的数据将对其他 AIR 应用程序不可用。组件可以通过在访问该格式的数据时设置适当的剪贴板传输模式来选择获取该对象的引用或获取该对象的副本。

注意：当在 AIR 应用程序外部粘贴或拖动数据时，标准格式始终转换成本机格式，因此，serializable 参数的值不影响采用标准格式的数据对于非 AIR 应用程序的可用性。

若要延迟呈现某一格式的数据，请改用 setDataHandler() 方法。如果同时使用 setData() 和 setDataHandler() 方法添加具有相同格式名称的数据表示方式，则永远也不会调用该处理函数。

参数

另请参见

 import flash.desktop.ClipboardFormats;
 
 var urlString:String = "http://www.adobe.com";
 Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, urlString);
 Clipboard.generalClipboard.setData(ClipboardFormats.URL_FORMAT, urlString);

添加对某个处理函数的引用，该函数根据需要生成指定格式的数据。使用此方法可将数据的创建或呈现延迟到实际访问数据时。

处理函数必须返回适合指定格式的相应数据类型：

当且仅当读取指定格式的数据时才会调用该处理函数。请注意，在添加处理函数时和读取数据时之间，基础数据可能会发生更改，除非应用程序采取保护数据的措施。多次读取剪贴板中由处理函数表示的数据时发生的行为没有保证。AIR 可能会返回由第一个函数调用生成的数据，也可能会再次调用该函数。不要依赖任一行为。

若要直接向此 Clipboard 对象添加数据，请改用 setData() 方法。如果使用相同的格式名称调用 setData() 和 setDataHandler() 方法，则永远也不会调用该处理函数。

参数

另请参见

 import flash.desktop.ClipboardFormats;
 
 Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, randomNumberGenerator);

 public function randomNumberGenerator():String{
     return Math.random().toString();
 }

1. 将数据（在本例中为一个字符串）写入到 Clipboard.generalClipboard 中。
2. 从 Clipboard.generalClipboard 读取剪贴板内容。

package
{
    import flash.display.Sprite;
    import flash.desktop.Clipboard;
    import flash.desktop.ClipboardFormats;
    import flash.desktop.ClipboardTransferMode;

    public class ClipboardExample extends Sprite
    {
        public function ClipboardExample()
        {
            var sally:String = "Sally";
            var person:String;
            
            copy(sally);
            person = paste();
            trace(person); //traces: "Sally"
        }

        private function copy(text:String):void{
            Clipboard.generalClipboard.clear();
            Clipboard.generalClipboard.setData(ClipboardFormats.TEXT_FORMAT, text);
        }
        
        private function paste():String{
            if(Clipboard.generalClipboard.hasFormat(ClipboardFormats.TEXT_FORMAT)){
                return String(Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT));
            } else {return null;}
        }
        
    }
}