true に設定され、テキストフィールドにフォーカスがない場合、テキストフィールド内の選択内容は灰色でハイライト表示されます。false に設定され、テキストフィールドにフォーカスがない場合、テキストフィールド内の選択内容はハイライト表示されません。

デフォルト値false.

関連項目

    package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_alwaysShowSelection extends Sprite {
        public function TextField_alwaysShowSelection() {
            var label1:TextField = createTextField(0, 20, 200, 20);
            label1.text = "This text is selected.";
            label1.setSelection(0, 9);
            label1.alwaysShowSelection = true;

            var label2:TextField = createTextField(0, 50, 200, 20);
            label2.text = "Drag to select some of this text.";
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x; result.y = y;
            result.width = width; result.height = height;
            addChild(result);
            return result;
        }
    }
}

このテキストフィールドに使用されるアンチエイリアス処理のタイプです。このプロパティには、flash.text.AntiAliasType 定数を使用します。この設定は、フォントが埋め込まれている (embedFonts プロパティが true に設定されている) 場合にのみ制御できます。デフォルト設定は、flash.text.AntiAliasType.ADVANCED です。

このプロパティの値を設定するには、次のストリング値を使用します。

関連項目

テキストフィールドの自動的な拡大・縮小および整列を制御します。TextFieldAutoSize 定数の有効な値は次のとおりです。TextFieldAutoSize.NONE (デフォルト)、TextFieldAutoSize.LEFT、TextFieldAutoSize.RIGHT、および TextFieldAutoSize.CENTER。

autoSize が TextFieldAutoSize.NONE (デフォルト値) に設定されていると、サイズ変更は行われません。

autoSize を TextFieldAutoSize.LEFT に設定すると、テキストは左揃えテキストとして扱われます。つまり、テキストフィールドの左マージンが固定され、テキストフィールドの単一行の右マージンのみが伸縮します。テキストに改行 ("\n" または "\r" など) が含まれる場合、テキストの次の行が収まるようにフィールドの下側も拡張されます。wordWrap も true に設定した場合、テキストフィールドの下側だけが伸縮し、右側は固定されたままになります。

autoSize を TextFieldAutoSize.RIGHT に設定すると、テキストは右揃えテキストとして扱われます。つまり、テキストフィールドの右マージンが固定され、テキストフィールドの単一行の左マージンのみが伸縮します。テキストに改行 ("\n" または "\r" など) が含まれる場合、テキストの次の行が収まるようにフィールドの下側も拡張されます。wordWrap も true に設定した場合、テキストフィールドの下側だけが伸縮し、左側は固定されたままになります。

autoSize を TextFieldAutoSize.CENTER に設定すると、テキストは中央揃えテキストとして扱われます。つまり、テキストフィールドの単一行のサイズ変更を行うと、左右両マージンが均等に伸縮されます。テキストに改行 ("\n" または "\r" など) が含まれる場合、テキストの次の行が収まるようにフィールドの下側も拡張されます。wordWrap も true に設定した場合、テキストフィールドの下側だけが伸縮し、左右両側は固定されたままになります。

関連項目

テキストフィールドに背景の塗りがあるかどうかを指定します。true である場合、テキストフィールドに背景の塗りがあります。false である場合、テキストフィールドには背景の塗りがありません。backgroundColor プロパティを使用して、テキストフィールドの背景色を設定します。

デフォルト値false.

関連項目

テキストフィールドの背景の色です。デフォルト値は 0xFFFFFF (白) です。このプロパティは、現在背景がない場合でも取得または設定できます。ただし、背景の色が表示されるのはテキストフィールドの background プロパティが true に設定されている場合のみです。

関連項目

テキストフィールドに境界線があるかどうかを指定します。true である場合、テキストフィールドに境界線があります。false である場合、テキストフィールドに境界線がありません。borderColor プロパティを使用して、境界線の色を設定します。

デフォルト値false.

関連項目

テキストフィールドの境界線の色です。デフォルト値は 0x000000 (黒) です。このプロパティは、現在境界線がない場合でも取得または設定できます。ただし、境界線の色が表示されるのはテキストフィールドの border プロパティが true に設定されている場合のみです。

関連項目

指定されたテキストフィールドの現在の表示範囲で最終行を示す整数です (1 から始まるインデックス)。テキストフィールドは、テキストのブロックにかぶせたウィンドウのようなものです。scrollV プロパティは、そのウィンドウに表示されている先頭行を示すインデックスです (1 から始まるインデックス)。

scrollV と bottomScrollV で示される行の間のすべてのテキストが、テキストフィールドに現在表示されています。

関連項目

カーソル (キャレット) 位置のインデックスです。カーソルが表示されていない場合、値は、フォーカスをフィールドに戻した場合にカーソルが表示される位置を示します。通常は、カーソルの最後の位置を示します。フィールドにフォーカスがなかった場合は、0 を示します。

選択範囲のインデックスはゼロから始まります。つまり、第 1 の位置は 0、第 2 の位置は 1、以下同様です。

関連項目

この例を実行し、TextField をクリックしてテキストの選択を試みます。次に、 テキストを選択しないでフィールドをクリックします。選択しないでテキストをクリックした場合、 caretIndex プロパティはカーソルが表示される位置を示し、 selectionBeginIndex selectionEndIndex プロパティは caretIndex プロパティの値と等しくなります。

package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.text.TextField;
    import flash.text.TextFieldType;

    public class TextField_caretIndex extends Sprite {
        public function TextField_caretIndex() {
            var tf:TextField = createTextField(10, 10, 100, 100);
            tf.wordWrap = true;
            tf.type = TextFieldType.INPUT;
            tf.text = "Click in this text field. Compare the difference between clicking without selecting versus clicking and selecting text.";
            tf.addEventListener(MouseEvent.CLICK, printCursorPosition);
        }

        private function printCursorPosition(event:MouseEvent):void {
            var tf:TextField = TextField(event.target);
            trace("caretIndex:", tf.caretIndex);
            trace("selectionBeginIndex:", tf.selectionBeginIndex);
            trace("selectionEndIndex:", tf.selectionEndIndex);
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            addChild(result);
            return result;
        }
    }
}

HTML テキストを持つテキストフィールド内の余分な空白 (スペース、改行など) を削除するかどうかを指定するブール値です。デフォルト値は false です。condenseWhite プロパティは、text プロパティではなく htmlText プロパティで設定されたテキストにのみ影響します。text プロパティでテキストを設定した場合、condenseWhite は無視されます。

condenseWhite を true に設定した場合は、テキストフィールド内で改行を指定するときに <BR> や <P> などの標準の HTML コマンドを使用する必要があります。

condenseWhite プロパティは htmlText プロパティを設定する前に設定します。

関連項目

package {
    import flash.display.Sprite;
    import flash.text.TextField;

    public class TextField_condenseWhite extends Sprite {
        public function TextField_condenseWhite() {
            var tf1:TextField = createTextField(0, 0, 200, 50);
            tf1.condenseWhite = false;
            tf1.htmlText = "keep    on\n\ttruckin'";
            
            var tf2:TextField = createTextField(0, 120, 200, 50);
            tf2.condenseWhite = true;
            tf2.htmlText = "keep    on\n\ttruckin'";
        }

        private function createTextField(x:Number, y:Number, width:Number, height:Number):TextField {
            var result:TextField = new TextField();
            result.x = x;
            result.y = y;
            result.width = width;
            result.height = height;
            result.border = true;
            addChild(result);
            return result;
        }
    }
}

新しく挿入するテキスト (replaceSelectedText() メソッドで挿入したテキストまたはユーザーが入力したテキストなど) に適用するフォーマットを指定します。

defaultTextFormat プロパティにアクセスすると、すべてのプロパティが定義された TextFormat オブジェクトが返されます。null のプロパティはありません。

関連項目

テキストフィールドがパスワードテキストフィールドであるかどうかを指定します。このプロパティの値が true である場合、テキストフィールドはパスワードテキストフィールドとして扱われ、入力された文字は実際の文字の代わりにアスタリスクで隠されます。false である場合、テキストフィールドはパスワードテキストフィールドとして扱われません。パスワードモードを有効にすると、[カット] コマンドと [コピー] コマンド、およびそれに対応するキーボードショートカットが機能しなくなります。このセキュリティ機能により、ユーザーの不在時にキーボードショートカットを使用して悪質なユーザーがパスワードを盗むことを防止できます。

デフォルト値false.

埋め込みフォントのアウトラインを使ってレンダリングするかどうかを指定します。false である場合は、デバイスフォントを使用してテキストフィールドをレンダリングします。

テキストフィールドの embedFonts プロパティを true に設定する場合、テキストフィールドに適用される TextFormat オブジェクトの font プロパティを使用して、そのテキストのフォントを指定する必要があります。指定したフォントが SWF ファイルに埋め込まれていない場合、テキストは表示されません。

デフォルト値false.

関連項目

このテキストフィールドに使用されるグリッドフィッティングのタイプです。このプロパティは、テキストフィールドの flash.text.AntiAliasType プロパティが flash.text.AntiAliasType.ADVANCED に設定されている場合にのみ適用されます。

使用されるグリッドフィッティングのタイプによって、太い水平線と垂直線がピクセルグリッドまたはサブピクセルグリッドに合わされるか合わされないかが決定されます。

flash.text.GridFitType プロパティでは、次のストリング値を使用できます。

デフォルト値pixel.

関連項目

テキストフィールドの内容を HTML で示します。

Flash Player では、次の HTML タグがサポートされています。