指定した String オブジェクト内にある文字数を表す整数です。

すべてのストリングインデックスはゼロから始まるため、各ストリング x の最終文字のインデックスは x.length - 1 のようになります。

関連項目

指定されたストリングに初期化された新しい String オブジェクトを作成します。

メモ :String オブジェクトよりもストリングリテラルを使用する方が負荷が少なく、一般的により簡単に使用できます。String オブジェクトを使用することに特別な理由がない場合以外は、String クラスよりもストリングリテラルを使用することをお勧めします。

関連項目

index パラメータで指定された位置にある文字を返します。index に指定された値が 0 ～ string.length - 1 の範囲内にない場合は、空のストリングを返します。

このメソッドは String.charCodeAt() に似ていますが、16 ビット整数の文字コードではなく文字が返される点が異なります。

関連項目

指定された index にある文字の数値 Unicode 文字コードを返します。index に指定された値が 0 ～ string.length - 1 の範囲内にない場合は、NaN を返します。

このメソッドは、String.charAt() と似ていますが、実際の文字ではなく 16 ビット整数文字コードを返す点が異なります。

関連項目

指定された引数を必要に応じてストリングに変換し、String オブジェクトの最後に追加して結果のストリングを返します。ソースの String オブジェクトの元の値は変更されません。

関連項目

パラメータ内の Unicode 文字コードに対応する文字をストリングとして返します。

関連項目

ストリング内を検索し、ストリング内の startIndex 以降の位置で見つかった最初の val の位置を返します。このインデックスはゼロから始まります。つまりストリングの最初の文字は、インデックス 1 ではなくインデックス 0 にあると見なされます。val が見つからない場合、メソッドは -1 を返します。

関連項目

ストリングを右から左へと探し、startIndex の前に見つかった最後の val のインデックスを返します。このインデックスはゼロから始まります。つまり最初の文字はインデックス 0 にあり、最後の文字は string.length - 1 にあります。val が見つからなかった場合は、-1 を返します。

関連項目

複数のストリングのソート順を比較し、比較の結果を整数で返します。このメソッドはロケールに特化した方法で比較を処理することを目的としていますが、ActionScript 3.0 実装では、等価 (==) 演算子または不等価 (!=) 演算子などの他のストリング比較と異なる結果を生成しません。ストリングが等価の場合、戻り値は 0 になります。元のストリング値が other で指定されたストリング値より前に来る場合、戻り値は負の整数になります。この値の絶対値は、2 つのストリング値を隔てる文字数を表します。元のストリング値が other の後に来る場合、戻り値は正の整数になります。この値の絶対値は、2 つのストリング値を隔てる文字数を表します。

指定された pattern をストリングと照合します。

関連項目

指定された pattern をストリングと照合し、新しいストリングを返します。この新しいストリングでは、pattern と最初に一致した部分が repl で指定された内容に置き換えられます。pattern パラメータには、ストリングまたは正規表現を指定できます。repl パラメータには、ストリングまたは関数を指定できます。関数を指定した場合、一致した部分が、関数によって返されるストリングに置き換えられます。元のストリングは変更されません。

次の例では、"sh" (大文字と小文字は区別) の最初のインスタンスのみが置き換えられます。

 var myPattern:RegExp = /sh/;  
 var str:String = "She sells seashells by the seashore.";
 trace(str.replace(myPattern, "sch"));  
    // She sells seaschells by the seashore.

次の例では、g (グローバル) フラグが正規表現で設定されているので、"sh" (大文字と小文字は区別) のすべてのインスタンスが置き換えられます。

 var myPattern:RegExp = /sh/g;  
 var str:String = "She sells seashells by the seashore.";
 trace(str.replace(myPattern, "sch"));  
    // She sells seaschells by the seaschore.

次の例では、g (グローバル) フラグが正規表現で設定されているので、"sh" のすべてのインスタンスが置き換えられます。また、i (ignoreCase) フラグが設定されているため、一致は大文字と小文字を区別 しません。

 var myPattern:RegExp = /sh/gi;  
 var str:String = "She sells seashells by the seashore.";
 trace(str.replace(myPattern, "sch"));  
    // sche sells seaschells by the seaschore.

var str:String = "flip-flop";
 var pattern:RegExp = /(\w+)-(\w+)/g;
 trace(str.replace(pattern, "$2-$1")); // flop-flip

 var str1:String = "abc12 def34";
 var pattern:RegExp = /([a-z]+)([0-9]+)/;
 var str2:String = str1.replace(pattern, replFN);
 trace (str2);   // 12abc 34def
 
 function replFN():String {
  return arguments[2] + arguments[1];
 }

 {"abc12", "abc", "12", 0, "abc12 def34"}

 {"def34", "def", "34", 6, "abc123 def34"}

関連項目

指定された pattern を検索し、最初に一致したサブストリングのインデックスを返します。一致するサブストリングがなかった場合、メソッドは -1 を返します。

関連項目

返されるストリングには、startIndex 文字から endIndex 文字の前までのすべての文字が含まれます。元の String オブジェクトは変更されません。endIndex パラメータを指定しないと、サブストリングの終わりはストリングの終わりです。startIndex で指定されたインデックス文字が、endIndex で指定されたインデックス文字と同じか、その右側にある場合、メソッドは空のストリングを返します。

関連項目

指定された delimiter パラメータがある各位置で String オブジェクトをサブストリングの配列に分割します。

delimiter パラメータが正規表現の場合、ストリング内の特定の位置で見つかった最初の一致のみが考慮されます。バックトラッキングにより、同じ位置で空でないサブストリングの一致が見つかったとしても、それは考慮されません。次に例を示します。

  var str:String = "ab";
  var results:Array = str.split(/a*?/); // results == ["","b"]
  
  results = str.split(/a*/); // results == ["","b"].)

delimiter パラメータがグループ化括弧を含む正規表現の場合、delimiter が一致するたびに、未定義結果を含むグループ化括弧の結果が出力配列にスプライスされます。次に例を示します。

  var str:String = "Thi5 is a tricky-66 example.";
  var re:RegExp = /(\d+)/;
  var results:Array = str.split(re);
      // results == ["Thi","5"," is a tricky-","66"," example."]

limit パラメータを指定した場合、配列には指定された数を超えるエレメントは返されません。

delimiter が空のストリング、空の正規表現、または空のストリングも一致とされる正規表現の場合、ストリング内のそれぞれの 1 文字が配列内のエレメントとして出力されます。

delimiter パラメータが未定義の場合は、ストリング全体が返される配列の最初のエレメントに挿入されます。

関連項目

指定された startIndex で開始する文字で構成され、len で指定された長さを持つサブストリングを返します。元のストリングは変更されません。

関連項目

startIndex で指定された文字から endIndex - 1 までのすべての文字で構成されるストリングを返します。endIndex が指定されていない場合、String.length が使用されます。startIndex の値が endIndex の値と等しい場合、空のストリングが返されます。startIndex の値が endIndex の値より大きい場合、関数を実行する前にパラメータが自動的に入れ替わります。元のストリングは変更されません。

関連項目

このストリングのコピーを返します。すべての大文字が小文字に変換されます。元のストリングは変更されません。このメソッドはロケールに特化した方法で変換を処理することを目的としていますが、ActionScript 3.0 実装では、toLowerCase() と異なる結果を生成しません。

関連項目

このストリングのコピーを返します。すべての小文字が大文字に変換されます。元のストリングは変更されません。このメソッドはロケールに特化した方法で変換を処理することを目的としていますが、ActionScript 3.0 実装では、toUpperCase() と異なる結果を生成しません。

関連項目

このストリングのコピーを返します。すべての大文字が小文字に変換されます。元のストリングは変更されません。

このメソッドは、対応する Unicode の小文字が存在するすべての文字 (単に A ～ Z ではない) を変換します。

  var str:String = " JOSÉ BARÇA";
  trace(str.toLowerCase()); // josé barça

これらの大文字と小文字のマッピングは、Unicode Character Database で定義されているとおりに、UnicodeData.txt ファイルと SpecialCasings.txt ファイルで定義されています。

関連項目

このストリングのコピーを返します。すべての小文字が大文字に変換されます。元のストリングは変更されません。

このメソッドは、対応する Unicode の大文字が存在するすべての文字 (単に a ～ z ではない) を変換します。

  var str:String = "José Barça";
  trace(str.toUpperCase()); // JOSÉ BARÇA

これらの大文字と小文字のマッピングは、Unicode Character Database で定義されているとおりに、UnicodeData.txt ファイルと SpecialCasings.txt ファイルで定義されています。

関連項目

String インスタンスのプリミティブ値を返します。このメソッドは、String オブジェクトをプリミティブなストリング値に変換するように設計されています。Flash Player は必要時に自動的に valueOf() を呼び出すようになっているため、このメソッドを明示的に呼び出すことが必要となることはほとんどありません。

1. StringExample のコンストラクタは、いくつかのローカルの String インスタンスを宣言します。 これらのインスタンスはさまざまなストリングと新しい StringHelper オブジェクトにより初期化されます。
2. StringHelper クラスには次のメソッドがあります。
   • replace(): String の split() メソッドと join() メソッドを呼び出して、 新しいストリングに渡されるストリングのサブストリングを削除します。
   • trim(): 渡されたストリングを使用して trimBack() と trimFront() の両方を呼び出し、 更新されたストリングを返します。
   • trimFront(): ストリングの最後から開始して先頭に向かって、ストリングの末尾の文字が char パラメータに一致しなくなるまで、 char パラメータに一致するすべての文字を再帰的に削除し、 更新されたストリングを返します。
   • trimBack(): ストリングの最後から開始して先頭に向かって、ストリングの末尾の文字が char パラメータに一致しなくなるまで、 char パラメータに一致するすべての文字を再帰的に削除し、 更新されたストリングを返します。
   • stringToCharacter(): 渡されたストリングの先頭文字を返します。
3. 宣言されているストリング変数を使用して、2 番目のストリングの作成に replace() メソッド、 3 番目のストリングの作成に trim() メソッドを呼び出して、 3 つのストリングを作成します。

package {
    import flash.display.Sprite;

    public class StringExample extends Sprite {
        public function StringExample() {
            var companyStr:String = new String("     Company X");
            var productStr:String = "Product Z Basic     ";
            var emptyStr:String = " ";
            var strHelper:StringHelper = new StringHelper();

            var companyProductStr:String = companyStr + emptyStr + productStr;
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Basic     '

            companyProductStr = strHelper.replace(companyProductStr, "Basic", "Professional");
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Professional     '

            companyProductStr = strHelper.trim(companyProductStr, emptyStr);
            trace("'" + companyProductStr + "'");    // 'Company X Product Z Professional'
        }
    }
}

class StringHelper {
    public function StringHelper() {
    }

    public function replace(str:String, oldSubStr:String, newSubStr:String):String {
        return str.split(oldSubStr).join(newSubStr);
    }

    public function trim(str:String, char:String):String {
        return trimBack(trimFront(str, char), char);
    }

    public function trimFront(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(0) == char) {
            str = trimFront(str.substring(1), char);
        }
        return str;
    }

    public function trimBack(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(str.length - 1) == char) {
            str = trimBack(str.substring(0, str.length - 1), char);
        }
        return str;
    }

    public function stringToCharacter(str:String):String {
        if (str.length == 1) {
            return str;
        }
        return str.slice(0, 1);
    }
}