flash.text.StyleSheet (Flex™ 2.0.1 Language Reference)

Package	flash.text
Class	public dynamic class StyleSheet
Inheritance	StyleSheet EventDispatcher Object

The StyleSheet class lets you create a StyleSheet object that contains text formatting rules for font size, color, and other styles. You can then apply styles defined by a style sheet to a TextField object that contains HTML- or XML-formatted text. The text in the TextField object is automatically formatted according to the tag styles defined by the StyleSheet object. You can use text styles to define new formatting tags, redefine built-in HTML tags, or create style classes that you can apply to certain HTML tags.

To apply styles to a TextField object, assign the StyleSheet object to a TextField object's styleSheet property.

Note: A text field with a style sheet is not editable. In other words, a text field with the type property set to TextFieldType.INPUT applies the StyleSheet to the default text for the text field, but the content will no longer be editable by the user. Consider using the TextFormat class to assign styles to input text fields.

Flash Player supports a subset of properties in the original CSS1 specification (www.w3.org/TR/REC-CSS1). The following table shows the supported Cascading Style Sheet (CSS) properties and values, as well as their corresponding ActionScript property names. (Each ActionScript property name is derived from the corresponding CSS property name; if the name contains a hyphen, the hyphen is omitted and the subsequent character is capitalized.)

CSS property	ActionScript property	Usage and supported values
`color`	`color`	Only hexadecimal color values are supported. Named colors (such as `blue`) are not supported. Colors are written in the following format: `#FF0000`.
`display`	`display`	Supported values are `inline`, `block`, and `none`.
`font-family`	`fontFamily`	A comma-separated list of fonts to use, in descending order of desirability. Any font family name can be used. If you specify a generic font name, it is converted to an appropriate device font. The following font conversions are available: `mono` is converted to `_typewriter`, `sans-serif` is converted to `_sans`, and `serif` is converted to `_serif`.
`font-size`	`fontSize`	Only the numeric part of the value is used. Units (px, pt) are not parsed; pixels and points are equivalent.
`font-style`	`fontStyle`	Recognized values are `normal` and `italic`.
`font-weight`	`fontWeight`	Recognized values are `normal` and `bold`.
`kerning`	`kerning`	Recognized values are `true` and `false`. Kerning is supported for embedded fonts only. Certain fonts, such as Courier New, do not support kerning. The kerning property is only supported in SWF files created in Windows, not in SWF files created on the Macintosh. However, these SWF files can be played in non-Windows versions of Flash Player and the kerning still applies.
`leading`	`leading`	The amount of space that is uniformly distributed between lines. The value specifies the number of pixels that are added after each line. A negative value condenses the space between lines. Only the numeric part of the value is used. Units (px, pt) are not parsed; pixels and points are equivalent.
`letter-spacing`	`letterSpacing`	The amount of space that is uniformly distributed between characters. The value specifies the number of pixels that are added after each character. A negative value condenses the space between characters. Only the numeric part of the value is used. Units (px, pt) are not parsed; pixels and points are equivalent.
`margin-left`	`marginLeft`	Only the numeric part of the value is used. Units (px, pt) are not parsed; pixels and points are equivalent.
`margin-right`	`marginRight`	Only the numeric part of the value is used. Units (px, pt) are not parsed; pixels and points are equivalent.
`text-align`	`textAlign`	Recognized values are `left`, `center`, `right`, and `justify`.
`text-decoration`	`textDecoration`	Recognized values are `none` and `underline`.
`text-indent`	`textIndent`	Only the numeric part of the value is used. Units (px, pt) are not parsed; pixels and points are equivalent.

You can use the StyleSheet class to perform low-level text rendering. However, in Flex, you typically use the Label, Text, TextArea, and TextInput controls to process text.

View the examples.

See also

flash.text.TextField

	Property	Defined by
		constructor : Object A reference to the class object or constructor function for a given object instance.	Object
		prototype : Object [static] A reference to the prototype object of a class or function object.	Object
		styleNames : Array [read-only] An array that contains the names (as strings) of all of the styles registered in this style sheet.	StyleSheet

Public Methods

Hide Inherited Public Methods

Show Inherited Public Methods

	Method		Defined by
		StyleSheet() Creates a new StyleSheet object.	StyleSheet
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registers an event listener object with an EventDispatcher object so that the listener receives notification of an event.	EventDispatcher
		clear():void Removes all styles from the style sheet object.	StyleSheet
		dispatchEvent(event:Event):Boolean Dispatches an event into the event flow.	EventDispatcher
		getStyle(styleName:String):Object Returns a copy of the style object associated with the style named `styleName`.	StyleSheet
		hasEventListener(type:String):Boolean Checks whether the EventDispatcher object has any listeners registered for a specific type of event.	EventDispatcher
		hasOwnProperty(name:String):Boolean Indicates whether an object has a specified property defined.	Object
		isPrototypeOf(theClass:Object):Boolean Indicates whether an instance of the Object class is in the prototype chain of the object specified as the parameter.	Object
		parseCSS(CSSText:String):void Parses the CSS in `CSSText` and loads the style sheet with it.	StyleSheet
		propertyIsEnumerable(name:String):Boolean Indicates whether the specified property exists and is enumerable.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Removes a listener from the EventDispatcher object.	EventDispatcher
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Sets the availability of a dynamic property for loop operations.	Object
		setStyle(styleName:String, styleObject:Object):void Adds a new style with the specified name to the style sheet object.	StyleSheet
		toString():String Returns the string representation of the specified object.	Object
		transform(formatObject:Object):TextFormat Extends the CSS parsing capability.	StyleSheet
		valueOf():Object Returns the primitive value of the specified object.	Object
		willTrigger(type:String):Boolean Checks whether an event listener is registered with this EventDispatcher object or any of its ancestors for the specified event type.	EventDispatcher

	Event	Summary	Defined by
		activate	Dispatched when Flash Player gains operating system focus and becomes active.	EventDispatcher
		deactivate	Dispatched when Flash Player loses operating system focus and is becoming inactive.	EventDispatcher

Property detail

styleNames

property

styleNames:Array [read-only]

An array that contains the names (as strings) of all of the styles registered in this style sheet.

Implementation
public function get styleNames():Array

Constructor detail

StyleSheet

()

constructor

public function StyleSheet()

Creates a new StyleSheet object.

See also

flash.text.StyleSheet.getStyle()

Method detail

clear

()

method

public function clear():void

Removes all styles from the style sheet object.

getStyle

()

method

public function getStyle(styleName:String):Object

Returns a copy of the style object associated with the style named styleName. If there is no style object associated with styleName, null is returned.

Parameters

styleName:String — A string that specifies the name of the style to retrieve.

Returns

Object — An object.

See also

flash.text.StyleSheet.setStyle()

parseCSS

()

method

public function parseCSS(CSSText:String):void

Parses the CSS in CSSText and loads the style sheet with it. If a style in CSSText is already in styleSheet, the properties in styleSheet are retained, and only the ones in CSSText are added or changed in styleSheet.

To extend the native CSS parsing capability, you can override this method by creating a subclass of the StyleSheet class.

Parameters

CSSText:String — The CSS text to parse (a string).

setStyle

()

method

public function setStyle(styleName:String, styleObject:Object):void

Adds a new style with the specified name to the style sheet object. If the named style does not already exist in the style sheet, it is added. If the named style already exists in the style sheet, it is replaced. If the styleObject parameter is null, the named style is removed.

Flash Player creates a copy of the style object that you pass to this method.

For a list of supported styles, see the table in the description for the StyleSheet class.

Parameters

	`styleName:String` — A string that specifies the name of the style to add to the style sheet.

	`styleObject:Object` — An object that describes the style, or `null`.

transform

()

method

public function transform(formatObject:Object):TextFormat

Extends the CSS parsing capability. Advanced developers can override this method by extending the StyleSheet class.

Parameters

formatObject:Object — An object that describes the style, containing style rules as properties of the object, or null.

Returns

TextFormat — A TextFormat object containing the result of the mapping of CSS rules to text format properties.

See also

flash.text.TextFormat

Examples

The following example creates a new style sheet and assigns bold and red font treatments to the heading style.

 
package {
    import flash.display.Sprite;
    import flash.text.StyleSheet;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;

    public class StyleSheetExample extends Sprite {

        public function StyleSheetExample() {
            var style:StyleSheet = new StyleSheet();

            var heading:Object = new Object();
            heading.fontWeight = "bold";
            heading.color = "#FF0000";

            var body:Object = new Object();
            body.fontStyle = "italic";

            style.setStyle(".heading", heading);
            style.setStyle("body", body);

            var label:TextField = new TextField();
            label.styleSheet = style;
            label.htmlText = "<body><span class='heading'>Hello </span>World...</body>";
            addChild(label);
        }
    }
}

Current page: http://livedocs.adobe.com/flex/201/langref/flash/text/StyleSheet.html

Adobe^® Flex™ 2.0.1 Language Reference		All Packages \| All Classes \| Language Elements \| Index \| Appendixes \| Conventions \| Frames No Frames
Class StyleSheet	Properties \| Methods \| Events \| Examples