public appendChild(newChild:XMLNode) : Void

指定されたノードを XML オブジェクトの子リストに追加します。このメソッドは、パラメータ childNode で参照されるノードに直接実行されます。ノードのコピーが追加されるわけではありません。追加するノードが別のツリー構造内に既に存在している場合は、ノードを新しい場所に追加すると現在の場所からノードが削除されます。パラメータ childNode が、別の XML ツリー構造内に既に存在しているノードを参照している場合、追加される子ノードは、今までの親ノードから削除された後で新しいツリー構造に置かれます。

パラメータ

newChild:XMLNode - 現在の場所から my_xml オブジェクトの子リストに移動されるノードを表す XMLNode。

例

この例では、次の処理を記載されている順序で実行します。

• 2 つの空の XML ドキュメント、doc1 および doc2 を作成します。
• createElement() メソッドを使用して新しいノードを作成し、appendChild() メソッドを使用してそのノードを XML ドキュメント doc1 に追加します。
• ルートノードを doc1 から doc2 に移動して、appendChild() メソッドを使用してノードを移動する方法を示します。
• doc2 からルートノードを複製し、そのノードを doc1 に追加します。
• 新しいノードを作成し、それを XML ドキュメント doc1 のルートノードに追加します。

var doc1:XML = new XML();
var doc2:XML = new XML();

// ルートノードを作成し、それを doc1 に追加します
var rootnode:XMLNode = doc1.createElement("root");
doc1.appendChild(rootnode);
trace ("doc1: " + doc1); // 出力 : doc1: <root />
trace ("doc2: " + doc2); // 出力 : doc2:

// ルートノードを doc2 に移動します
doc2.appendChild(rootnode);
trace ("doc1: " + doc1); // 出力 : doc1:
trace ("doc2: " + doc2); // 出力 : doc2: <root />

// ルートノードのクローンを作成し、それを doc1 に追加します
var clone:XMLNode = doc2.firstChild.cloneNode(true);
doc1.appendChild(clone);
trace ("doc1: " + doc1); // 出力 : doc1: <root />
trace ("doc2: " + doc2); // 出力 : doc2: <root />

// 新しいノードを作成し、doc1 のルートノード clone に追加します
var newNode:XMLNode = doc1.createElement("newbie");
clone.appendChild(newNode);
trace ("doc1: " + doc1); // 出力 : doc1: <root><newbie /></root>