このセクションでは、予約するレストランを 4 つの場所から選択する新しい画面を作成します。この画面で選択した場所により、アプリケーションのホーム画面で [Reservations] を選択したときにダイヤルされる電話番号が決まります。

ユーザーがはじめてアプリケーションを開始して、ホーム画面の [Reservations] を選択すると、場所を選択することのできる場所の設定画面が表示されます。次に、[Reservations] を選択すると、アプリケーションはすぐにデフォルトのレストランの場所に電話をかけます。アプリケーションでは、セッション間で選択した場所を保存しておく共有オブジェクトが使用されます。

1. ビデオ画面の作成で完成させたファイルを Flash で開きます。
2. タイムラインで、Options Menu という名前のレイヤー上のフレーム 66 のキーフレームを選択します。
3. [ライブラリ] パネルを開き ([ウィンドウ]-[ライブラリ])、location_SF_button という名前のボタンをライブラリからステージにドラッグします。

   "Select your preferred locationﾉ" のテキストの下にボタンを配置します。

4. プロパティインスペクタで、[インスタンス名] テキストボックスに「sf_btn」と入力します。
5. location_SJ_button という名前のボタンをライブラリからステージにドラッグして、location_SF button ボタンの直下に配置します。
6. プロパティインスペクタで、[インスタンス名] テキストボックスに「sj_btn」と入力します。
7. 手順 6 を繰り返して、ライブラリの location_PA と location_BK の 2 つのボタンのインスタンス名を、それぞれ「pa_btn」、「bk_btn」にします。

   アプリケーションのステージは、次のようになります。

   

8. [アクション] パネル ([ウィンドウ]-[アクション]) に次のコードを入力します。

   stop ();
   fscommand2 ("SetSoftKeys", "Save", "Cancel");
   showCurrentLocation();
   //
   // ソフトキーのイベントハンドラコード
   //
   Key.removeListener (myListener);
   var myListener:Object = new Object ();
   myListener.onKeyDown = function () {
       var keyCode = Key.getCode ();
       if (keyCode == ExtendedKey.SOFT1) {
           // 場所を保存します
           saveNewLocation ();
           gotoAndPlay ("home");
       }
       else if (keyCode == ExtendedKey.SOFT2) {
           // 操作をキャンセルして、ホーム画面に戻ります
           gotoAndPlay ("home");
       }
   };
   Key.addListener (myListener);
   //
   // 関数 : saveNewLocation()
   //
   function saveNewLocation () {
       // どのボタン (場所) をユーザーが選択したか決定します
       var selectedButton = Selection.getFocus ();
       switch (selectedButton._name) {
       case "_level0.sf_btn" :
           // サンフランシスコを選択
           location_so.data.phoneNumber = "415-555-1212";
           break;
       case "_level0.sj_btn" :
           // サンノゼを選択
           location_so.data.phoneNumber = "408-555-1212";
           break;
       case "_level0.bk_btn" :
           // バークレーを選択
           location_so.data.phoneNumber = "510-555-1212";
           break;
       case "_level0.pa_btn" :
           // パロアルトを選択
           location_so.data.phoneNumber = "650-555-1212";
           break;
       }
   }
   //
   //     関数 : showCurrentLocation()
   //
   function showCurrentLocation() {
       // 共有オブジェクトに保存されている電話番号を取得します
       var phoneNumber:String = location_so.data.phoneNumber;
       // 電話番号からエリアコードを取り出します
       var areaCode:String = phoneNumber.substring (0, 3);
       // エリアコードに応じて、対応するボタンアイテムの
       // 場所にフォーカスを設定します
       switch (areaCode) {
       case "415" :
           Selection.setFocus (_level0.sf_btn);
           break;
       case "408" :
           Selection.setFocus (_level0.sj_btn);
           break;
       case "510" :
           Selection.setFocus (_level0.bk_btn);
           break;
       case "650" :
           Selection.setFocus (_level0.pa_btn);
           break;
       }
   }