ビデオ画面の作成

このセクションでは、アプリケーションにビデオと、右ソフトキーで再生コントロール (再生、一時停止、もう一度再生) を可能にする ActionScript コードを追加します。

デバイスのファイルシステムまたはネットワークアドレスから外部ビデオファイルをロードすることもできますが、このチュートリアルでは、SWF ファイルのライブラリにデバイスのビデオファイルをバンドルします。

おすすめ料理画面の作成で完成させたファイルを Flash で開きます。
まだ開いていない場合には、[ライブラリ] パネルを開きます ([ウィンドウ]-[ライブラリ])。
[ライブラリ] パネルを開き、パネルの右上隅にあるオプションメニューから [新規ビデオ] を選択します。
[ビデオのプロパティ] ダイアログボックスが表示されます。
[シンボル] テキストボックスにビデオシンボルの名前を入力します (たとえば「cafe Video」など)。
[ビデオのプロパティ] ダイアログボックスで、SWF ファイルにソースビデオをバンドルするオプションを選択し、[読み込み] をクリックします。
www.adobe.com/go/learn_flt_samples_and_tutorials_jp にある "cafe_townsend_chef.3gp" という名前のファイルを開きます。「サンプルとチュートリアル」ページで、Flash Lite 3.0 バージョンの .zip ファイルを探してダウンロードおよび解凍し、"Tutorial Assets" フォルダを選択してファイルにアクセスします。
[ファイルを開く] ダイアログボックスにビデオファイルがリストされない (または表示されるが選択できない) 場合は、[ファイルの種類] ポップアップメニューから [すべてのファイル] (Windows) または [使用可能] ポップアップメニューから [すべての形式] (Macintosh) を選択します。この操作は、Flash オーサリングツールが多くのデバイスのビデオフォーマットを認識しないため必要です。

次の図のように [ビデオのプロパティ] ダイアログボックスが表示されます。
[OK] をクリックして、[ビデオのプロパティ] ダイアログボックスを閉じます。
ドキュメントの [ライブラリ] パネルに、デバイスのビデオファイルに関連付けられた新しいビデオシンボルが表示されます。

Flash Lite でのデバイスビデオの操作の詳細については、『Flash Lite 2.x および 3.0 アプリケーションの開発』を参照してください。
ステージにビデオオブジェクトを追加するには、次に示すように、タイムラインで、Video という名前のレイヤー上のフレーム 51 のキーフレームを選択します。
[ライブラリ] パネルから、レストランの Video オブジェクトをステージにドラッグします。
プロパティインスペクタで、[インスタンス名] テキストボックスに「cafeVideo」と入力し、
オブジェクトの x 座標を 0、y 座標を 45、幅を 176、高さを 144 に設定します。
タイムラインで、ActionScript という名前のレイヤー上のフレーム 51 のキーフレームを選択します。

[アクション] パネルを開き ([ウィンドウ]-[アクション])、次のコードを入力、またはコピー & ペーストします。

// タイムラインを停止し、ソフトキーを登録してビデオを開始します
stop ();
fscommand2 ("SetSoftKeys", "Home", "Pause");
caféVideo.play ();
var playing:Boolean = true;
// ソフトキーのイベントハンドラコード
Key.removeListener (myListener);
var myListener:Object = new Object ();
myListener.onKeyDown = function () {
    var keyCode = Key.getCode ();
    if (keyCode == ExtendedKey.SOFT1) {
        gotoAndPlay ("home");
    }
    else if (keyCode == ExtendedKey.SOFT2) {
        if (playing) {
            // ビデオを再生している場合は、一時停止して、
            // ステータス変数 (playing) を false に設定します
            // 右ソフトキーのラベルに 'Play' を設定します
            caféVideo.pause ();
            playing = false;
            rightSoftKeyLabel.text = "Play";
        }
        else {
            // ビデオを一時停止している場合は、もう一度再生します
            // ステータス変数 (playing) を true に設定します
            // 右ソフトキーのラベルに 'Pause' を設定します
            caféVideo.resume ();
            playing = true;
            righttSoftKeyLabel.text = "Pause";
        }
    }
};
// リスナーオブジェクトを登録します
Key.addListener (myListener);
//
// ビデオのステータスハンドラコード 
//
caféVideo.onStatus = function (infoObject:Object) {
    var code = infoObject.code;
    if (code == "completed") {
        // ビデオの再生が終了したら、playing=false に設定します
        // 右ソフトキーのラベルに "Replay" を設定します
        playing = false;
        rightSoftKeyLabel.text = "Replay";
    }
};

ここまで行った変更を保存して、エミュレータでアプリケーションをテストします。
アプリケーションのホーム画面で [View Video] オプションを選択して、ビデオを表示します。
右ソフトキーを押してビデオを一時停止してみます。もう一度押して、もう一度再生してみます。ビデオが終了したら、再度右ソフトキーを押して、もう一度ビデオを再生します。

このページに新しいコメントが追加された場合に、電子メールでの通知を希望する。 | コメントレポート

Flash Lite 2.x および 3.0 ヘルプ

ビデオ画面の作成