指出此 XMLSocket 物件目前是否已連線。 您也可以透過註冊 connect 事件和 ioError 事件，檢查連線是否成功。

請參閱

建立新的 XMLSocket 物件。 XMLSocket 物件在剛開始時並未與任何伺服器連線。 您必須呼叫 XMLSocket.connect() 方法，將物件連線至伺服器。

請參閱

會關閉 XMLSocket 物件所指定的連線。 只有當伺服器關閉連線時，才會傳送 close 事件。當您呼叫 close() 方法時，則不會傳送此事件。

請參閱

會使用指定的 TCP 連接埠，連線到指定的網際網路主機。 根據預設，除非您已使用原則檔，否則只能連線至埠號 1024 以上的連接埠。

如果您將 host 參數指定為 null，則聯繫的主機就是呼叫 XMLSocket.connect() 的 SWF 檔所在的機器。 例如，如果您是從 www.adobe.com 下載 SWF 檔，那麼將 host 參數指定為 null 就等於是輸入 www.adobe.com 的 IP 位址。

若 SWF 檔是在早於 Flash Player 7 版本的播放程式中執行，則該 SWF 檔中的 host 必須和發出這個呼叫的 SWF 檔位於相同的父網域中。 例如，位於 www.adobe.com 的 SWF 檔可以從位於 store.adobe.com 的 SWF 檔中傳送或接收變數，因為兩個檔案都位於相同的父網域 (adobe.com) 中。

在 Flash Player 7 或更新版本中執行的任何版本 SWF 檔中，其 host 必須位於完全相同的網域中。 例如，發行為 Flash Player 5 格式、位於 www.adobe.com 網域中、但在 Flash Player 7 或更新版本中執行的 SWF 檔，只能從同樣位於 www.adobe.com 的 SWF 檔傳送或接收變數。 若要傳送或接收來自不同網域的變數，可以在裝載您所要存取之 SWF 檔的伺服器上置入「跨網域原則檔案」。

您可以拒絕 SWF 檔使用這個方法，方式是在包含 SWF 內容的 HTML 網頁中，設定 object 和 embed 標籤的 allowNetworking 參數。

如需詳細資訊，請參閱下列章節：

• 「ActionScript 3.0 程式設計」一書中的「安全性章節」與 LiveDocs 上的最新註解
• Flash Player 9 安全性白皮書

參數

請參閱

將 object 參數中所指定的 XML 物件或資料轉換成字串，並在後面加上零 (0) 位元組後傳輸到伺服器。 如果 object 是 XML 物件，這個字串就是此 XML 物件的 XML 文字表示。 傳送作業並不是同步的。它雖然會立即傳回，但是可能要稍後才會傳輸資料。 XMLSocket.send() 方法並不會傳回值來表示資料是否已傳輸成功。

如果您並未使用 XMLSocket.connect()，將 XMLSocket 物件連線至伺服器，XMLSocket.send() 作業就會失敗。

參數

請參閱

會在伺服器關閉通訊端連線時傳送。 只有當伺服器關閉連線時，才會傳送 close 事件。當您呼叫 XMLSocket.close() 方法時，則不會傳送此事件。

這個事件具有下列屬性：

會在順利呼叫 XMLSocket.connect() 方法之後傳送。

這個事件具有下列屬性：

在傳送或收到原始資料之後傳送。

這個事件具有下列屬性：

發生輸入/輸出錯誤，因而導致傳送或接收作業失敗時傳送。

這個事件具有下列屬性：

會當 XMLSocket.connect() 方法的呼叫嘗試連線至呼叫者安全執行程序以外的伺服器，或小於 1024 的連接埠時傳送。

這個事件具有下列屬性：

請參閱

1. XMLSocketExample 建構函式會建立 XMLSocket 實體 socket，將 socket 傳遞給 ConfigureListeners() (將在下列範例中說明)，然後使用主機名稱 "localhost" 與 8080 的埠號，呼叫 XMLSocket 的 connect() 方法。
2. 接著呼叫 configureListeners() 方法，將偵聽程式加入每一個支援的 XMLSocket 事件：
   • closeHandler() 會偵聽 close 事件，並在網路連線中斷後將事件送出。
   • connectHandler() 會偵聽 connect 事件，並在建立網路連線後將事件送出。
   • dataHandler() 會偵聽 data 事件，並在每次 XMLSocket 收到新的資料後將事件送出。
   • progressHandler() 會偵聽 progress 事件，並在呼叫 send() 後及傳送作業進行時將事件送出。
   • securityErrorHandler() 會偵聽 securityError 事件，並在嘗試使用錯誤的本機播放安全性設定或小於 1024 的埠號存取 XMLSocket 時將事件送出。
   • ioErrorHandler() 會偵聽 ioError 事件，並只在傳送或接收資料失敗時將事件送出。

注意：

• 在編譯 SWF 檔時，您必須將「本機播放安全性」設定為「只存取網路」。
• 若要讓此範例正確運作，您需要能使用連接埠 8080 並且運作於 [yourDomain] 的伺服器。

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.XMLSocket;

    public class XMLSocketExample extends Sprite {
        private var hostName:String = "localhost";
        private var port:uint = 8080;
        private var socket:XMLSocket;

        public function XMLSocketExample() {
            socket = new XMLSocket();
            configureListeners(socket);
            socket.connect(hostName, port);
        }

        public function send(data:Object):void {
            socket.send(data);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CLOSE, closeHandler);
            dispatcher.addEventListener(Event.CONNECT, connectHandler);
            dispatcher.addEventListener(DataEvent.DATA, dataHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
        }

        private function dataHandler(event:DataEvent):void {
            trace("dataHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}