指定的 String 物件中用來指定字元數目的整數。

由於所有字串索引都是從零開始計算的，因此任何 x 字串的最後一個字元索引都是 x.length - 1。

請參閱

會建立初始化為指定之字串的新 String 物件。

注意：因為字串常值使用的額外資源比 String 物件少，而且通常比較容易使用，所以除非您有很好的理由要使用 String 物件而非字串常值，否則應該使用字串常值而非 String 類別。

請參閱

會傳回位於 index 參數所指定之位置中的字元。 如果 index 不是介於 0 和 string.length - 1 之間的數字，便會傳回空字串。

除了傳回的值是字元而非 16 位元整數字元碼以外，這個方法和 String.charCodeAt() 非常類似。

參數

請參閱

會傳回位於指定 index 之字元的數字 Unicode 字元碼。 如果 index 不是介於 0 和 string.length - 1 之間的數字，便會傳回 NaN。

除了傳回的值是 16 位元整數字元碼而非實際字元以外，這個方法與 String.charAt() 非常類似。

參數

請參閱

會將所提供的引數附加至 String 物件的結尾，在必要時將這些引數轉換成字串，並傳回產生的字串。 來源 String 物件的原始值會維持不變。

參數

請參閱

會傳回參數中 Unicode 字元碼代表之字元所組成的字串。

參數

請參閱

搜尋字串，並傳回在呼叫字串中 startIndex 處或之後找到之 val 第一次出現的位置。 這個索引是從零開始，表示字串的第一個字串會視為位於索引 0 而非索引 1。 如果找不到 val，此方法會傳回 -1。

參數

請參閱

會由右至左搜尋字串，並傳回在 startIndex 之前找到，最後出現之 val 的索引。 索引會從零開始，表示第一個字元會在索引 0，而最後一個字元則會在 string.length - 1。 如果找不到 val，此方法會傳回 -1。

參數

請參閱

會比較兩個或更多字串的排序順序，並以整數形式傳回比較的結果。 當此方法要以地區特定的方式處理比較作業時，ActionScript 3.0 實作並不會產生不同於其它字串比較的結果，例如相等 (==) 或不相等 (!=) 運算子。 如果這些字串都相等，傳回值就是 0。 如果原始字串值在 other 指定的字串值之前，傳回值便會是負整數，而其絕對值則代表分隔兩個字串值的字元數。 如果原始字串值在 other 之後，傳回值便會是正整數，而其絕對值則代表分隔兩個字串值的字元數。

參數

會比對指定的 pattern 與字串。

參數

請參閱

會針對指定的 pattern 與字串進行比對，並傳回新的字串，其中第一個符合的 pattern 會被 repl 指定的內容所取代。 pattern 參數可以是字串或規則運算式。 repl 參數可以是字串或函數；如果是函數，便會插入此函數傳回的字串來取代符合項目， 而原始的字串並不會遭到修改。

在下列範例中，只會取代 "sh" (區分大小寫) 的第一個實體：

 var myPattern:RegExp = /sh/;  
 var str:String = "She sells seashells by the seashore.";
 trace(str.replace(myPattern, "sch"));  
    // She sells seaschells by the seashore.

在下列範例中，由於在規則運算式中有設定 g (全域) 旗標，所以 "sh" (區分大小寫) 的所有實體都會遭到取代：

 var myPattern:RegExp = /sh/g;  
 var str:String = "She sells seashells by the seashore.";
 trace(str.replace(myPattern, "sch"));  
    // She sells seaschells by the seaschore.

在下列範例中，由於在規則運算式中有設定 g (全域) 旗標，所以 "sh" 的所有實體都會遭到取代；而且因為有設定 i (忽略大小寫) 旗標，所以相符項目便「不會」區分大小寫：

 var myPattern:RegExp = /sh/gi;  
 var str:String = "She sells seashells by the seashore.";
 trace(str.replace(myPattern, "sch"));  
    // sche sells seaschells by the seaschore.

參數

var str:String = "flip-flop";
 var pattern:RegExp = /(\w+)-(\w+)/g;
 trace(str.replace(pattern, "$2-$1")); // flop-flip

 var str1:String = "abc12 def34";
 var pattern:RegExp = /([a-z]+)([0-9]+)/g;
 var str2:String = str1.replace(pattern, replFN);
 trace(str2);   // 12abc 34def
 
 function replFN():String {
  return arguments[2] + arguments[1];
 }

 {"abc12", "abc", "12", 0, "abc12 def34"}

 {"def34", "def", "34", 6, "abc123 def34"}

請參閱

會搜尋指定的 pattern，並傳回第一個相符之子字串的索引。 如果沒有符合的子字串，此方法便會傳回 -1。

參數

請參閱

會傳回一個字串，其中包含 startIndex 字元以後，直到 endIndex 字元 (但不包含此字元) 之前的所有字元。 不會修改原始 String 物件。 如果沒有指定 endIndex 參數，子字串的結尾就會是字串的結尾。 如果以 startIndex 為索引的字元與以 endIndex 為索引的字元相同或是在其右邊，則此方法會傳回空字串。

參數

請參閱

會分割指定之 delimiter 參數出現的每個位置，將 String 物件分成子字串的陣列。

如果 delimiter 參數是規則運算式，就只會考慮在字串之指定位置的第一個符合項目，即使回溯便能在該位置找到符合的非空白子字串也一樣。 例如：

  var str:String = "ab";
  var results:Array = str.split(/a*?/); // results == ["","b"]
  
  results = str.split(/a*/); // results == ["","b"].)

如果 delimiter 參數是包含群組括號的規則運算式，則每次 delimiter 符合時，群組括號的結果 (包括任何未定義的結果) 都會接合到輸出陣列中。 例如：

  var str:String = "Thi5 is a tricky-66 example.";
  var re:RegExp = /(\d+)/;
  var results:Array = str.split(re);
      // results == ["Thi","5"," is a tricky-","66"," example."]

如果有指定 limit 參數，傳回的陣列便不會包含多於指定之數目的元素。

如果 delimiter 是空字串、空的規則運算式，或是能夠符合空字串的規則運算式，則字串中的每個單一字元都會輸出為陣列中的元素。

如果未定義 delimiter 參數，整個字串會放到傳回之陣列的第一個元素中。

參數

請參閱

會傳回子字串，它所組成的字元是從指定的 startIndex 開始，且長度為 len 所指定。 不會修改原始的字串。

參數

請參閱

會傳回字串，它是由 startIndex 所指定，一直到 endIndex - 1 的所有字元所組成。 如果未指定 endIndex，便會使用 String.length。 如果 startIndex 的值與 endIndex 的值相等，則此方法會傳回一個空字串。 如果 startIndex 的值大於 endIndex 的值，便會在函數執行之前自動替換參數。 不會修改原始的字串。

參數

請參閱

會傳回此字串的副本，其中所有大寫字元都會轉換成小寫字元。 不會修改原始的字串。 儘管此方法會以地區特定的方式處理轉換，ActionScript 3.0 實作卻不會產生與 toLowerCase() 方法不同的結果。

請參閱

會傳回此字串的副本，其中所有小寫字元都會轉換成大寫字元。 不會修改原始的字串。 儘管此方法會以地區特定的方式處理轉換，ActionScript 3.0 實作卻不會產生與 toUpperCase() 方法不同的結果。

請參閱

會傳回此字串的副本，其中所有大寫字元都會轉換成小寫字元。 不會修改原始的字串。

此方法會轉換具有與 Unicode 小寫字元對等的所有字元 (不僅只是 A-Z)：

  var str:String = " JOSÉ BARÇA";
  trace(str.toLowerCase()); // josé barça

請參閱

會傳回此字串的副本，其中所有小寫字元都會轉換成大寫字元。 不會修改原始的字串。

此方法會轉換具有 Unicode 大寫字元對等的所有字元 (不僅只是 a-z)：

  var str:String = "José Barça";
  trace(str.toUpperCase()); // JOSÉ BARÇA

請參閱

會傳回 String 實體的基本值。 此方法的設計目的，是要將 String 物件轉換成基本字串值。 由於 Flash Player 會自動在必要時呼叫 valueOf()，所以您幾乎不需要明確呼叫這個方法。

1. StringExample 的建構函式會宣告許多區域 String 實體，而這些實體是以各種字串和新的 StringHelper 物件來初始化。
2. StringHelper 類別具有下列方法：
   • replace()：呼叫 String 的 split() 和 join() 方法，移除搭配新字串傳入之字串的子字串。
   • trim()：使用傳入的字串呼叫 trimBack() 和 trimFront()，並傳回更新的字串。
   • trimFront()：以遞迴方式移除符合 char 參數的所有字元，從字串的前面開始處理到結尾，直到字串中的第一個字元不符合 char 為止，然後傳回更新的字串。
   • trimBack()：以遞迴方式移除符合 char 參數的所有字元，從字串的結尾開始往回處理，直到字串中的最後一個字元不符合 char 為止，然後傳回更新的字串。
   • stringToCharacter()：會傳回傳遞給此方法之字串中的第一個字元。
3. 然後會使用宣告的字串變數來產生三個字串，包含用來產生第二個字串的 replace() 方法呼叫以及用來產生第三個字串的 trim()。

package {
    import flash.display.Sprite;

    public class StringExample extends Sprite {
        public function StringExample() {
            var companyStr:String = new String("     Company X");
            var productStr:String = "Product Z Basic     ";
            var emptyStr:String = " ";
            var strHelper:StringHelper = new StringHelper();

            var companyProductStr:String = companyStr + emptyStr + productStr;
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Basic     '

            companyProductStr = strHelper.replace(companyProductStr, "Basic", "Professional");
            trace("'" + companyProductStr + "'");    // '     Company X Product Z Professional     '

            companyProductStr = strHelper.trim(companyProductStr, emptyStr);
            trace("'" + companyProductStr + "'");    // 'Company X Product Z Professional'
        }
    }
}

class StringHelper {
    public function StringHelper() {
    }

    public function replace(str:String, oldSubStr:String, newSubStr:String):String {
        return str.split(oldSubStr).join(newSubStr);
    }

    public function trim(str:String, char:String):String {
        return trimBack(trimFront(str, char), char);
    }

    public function trimFront(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(0) == char) {
            str = trimFront(str.substring(1), char);
        }
        return str;
    }

    public function trimBack(str:String, char:String):String {
        char = stringToCharacter(char);
        if (str.charAt(str.length - 1) == char) {
            str = trimBack(str.substring(0, str.length - 1), char);
        }
        return str;
    }

    public function stringToCharacter(str:String):String {
        if (str.length == 1) {
            return str;
        }
        return str.slice(0, 1);
    }
}