위치 변경

myShape.x = 17;
myShape.y = 212;

// 부모의 위치에 관계없이 스테이지의 왼쪽 위 모서리에 
// 모양을 배치합니다.

// 위치가 x:200 및 y:200인 Sprite를 만듭니다.
var mySprite:Sprite = new Sprite();
mySprite.x = 200;
mySprite.y = 200;
this.addChild(mySprite);

// Sprite의 0,0 좌표에 점을 참조용으로 그립니다.
mySprite.graphics.lineStyle(1, 0x000000);
mySprite.graphics.beginFill(0x000000);
mySprite.graphics.moveTo(0, 0);
mySprite.graphics.lineTo(1, 0);
mySprite.graphics.lineTo(1, 1);
mySprite.graphics.lineTo(0, 1);
mySprite.graphics.endFill();

// 원 Shape 인스턴스를 만듭니다.
var circle:Shape = new Shape();
mySprite.addChild(circle);

// Shape에 반경이 50이며 중심점이 x:50, y:50에 있는 원을 그립니다.
circle.graphics.lineStyle(1, 0x000000);
circle.graphics.beginFill(0xff0000);
circle.graphics.drawCircle(50, 50, 50);
circle.graphics.endFill();

// Shape의 왼쪽 위 모서리가 스테이지의 0, 0 좌표에 위치하도록 Shape를 이동합니다.
var stagePoint:Point = new Point(0, 0);
var targetPoint:Point = mySprite.globalToLocal(stagePoint);
circle.x = targetPoint.x;
circle.y = targetPoint.y;

// 이 코드는 startDrag() 기술을 사용하여 드래그 앤 드롭 상호 작용을 만듭니다.
// 사각형은 DisplayObject(예: MovieClip 또는 Sprite 인스턴스)입니다.

import flash.events.MouseEvent;

// 마우스 버튼을 누르면 이 함수가 호출됩니다.
function startDragging(event:MouseEvent):void
{
    square.startDrag();
}

// 마우스 버튼을 놓으면 이 함수가 호출됩니다.
function stopDragging(event:MouseEvent):void
{
    square.stopDrag();
}

square.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
square.addEventListener(MouseEvent.MOUSE_UP, stopDragging);

function startDragging(event:MouseEvent):void
{
    square.startDrag();
    circle.startDrag();
}

// 이 코드는 mouse-following 기술을 사용하여 드래그 앤 드롭 상호 작용을 만듭니다.
// 원은 DisplayObject(예: MovieClip 또는 Sprite 인스턴스)입니다.

import flash.events.MouseEvent;

var offsetX:Number;
var offsetY:Number;

// 마우스 버튼을 누르면 이 함수가 호출됩니다.
function startDragging(event:MouseEvent):void
{
    // 마우스 버튼을 눌렀을 때 커서 위치와 마우스
    // 버튼을 놓았을 때 원의 x, y 좌표 간의 차이(오프셋)를
    // 기록합니다.
    offsetX = event.stageX - circle.x;
    offsetY = event.stageY - circle.y;
    
    // mouseMove 이벤트 수신을 시작하도록 Flash Player에 지시합니다.
    stage.addEventListener(MouseEvent.MOUSE_MOVE, dragCircle);
}

// 마우스 버튼을 놓으면 이 함수가 호출됩니다.
function stopDragging(event:MouseEvent):void
{
    // mouseMove 이벤트 수신을 중지하도록 Flash Player에 지시합니다.
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, dragCircle);
}

// 마우스 버튼을 누른 상태에서 마우스를 움직일 때마다 이 함수가 호출됩니다.
function dragCircle(event:MouseEvent):void
{
    // 커서 위치와 드래그된 객체 위치 간의 오프셋을 유지하면서 커서 위치로
    // 원을 이동합니다.
    circle.x = event.stageX - offsetX;
    circle.y = event.stageY - offsetY;

    // 이 이벤트 후 화면을 새로 고치도록 Flash Player에 지시합니다.
    event.updateAfterEvent();
}

circle.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
circle.addEventListener(MouseEvent.MOUSE_UP, stopDragging);

// 이 코드는 mouse-following 기술을 사용하여 드래그 앤 드롭 상호 작용을 만듭니다.
// 원과 사각형은 DisplayObjects(예: MovieClip 또는 Sprite 인스턴스)입니다.

import flash.display.DisplayObject;
import flash.events.MouseEvent;

var offsetX:Number;
var offsetY:Number;
var draggedObject:DisplayObject;

// 마우스 버튼을 누르면 이 함수가 호출됩니다.
function startDragging(event:MouseEvent):void
{
    // 드래그하고 있는 객체를 기억합니다.
    draggedObject = DisplayObject(event.target);
    
    // 마우스 버튼을 눌렀을 때 커서 위치와 마우스 버튼을 놓았을 때 드래그된 객체의
    // x, y 좌표 간의 차이(오프셋)를 기록합니다.
    offsetX = event.stageX - draggedObject.x;
    offsetY = event.stageY - draggedObject.y;
    
    // 선택한 객체를 표시 목록의 맨 위로 이동합니다.
    stage.addChild(draggedObject);
    
    // TmouseMove 이벤트 수신을 시작하도록 Flash Player에 지시합니다.
    stage.addEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}

// 마우스 버튼을 놓으면 이 함수가 호출됩니다.
function stopDragging(event:MouseEvent):void
{
    // mouseMove 이벤트 수신을 중지하도록 Flash Player에 지시합니다.
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}

// 마우스 버튼을 누른 상태에서 마우스를 움직일 때마다 이 함수가 호출됩니다.
function dragObject(event:MouseEvent):void
{
    // 커서 위치와 드래그된 객체 위치 간의 오프셋을 유지하면서 커서 위치로
    // 드래그된 객체를 이동합니다.
    draggedObject.x = event.stageX - offsetX;
    draggedObject.y = event.stageY - offsetY;
    
    // 이 이벤트 후 화면을 새로 고치도록 Flash Player에 지시합니다.
    event.updateAfterEvent();
}

circle.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
circle.addEventListener(MouseEvent.MOUSE_UP, stopDragging);

square.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
square.addEventListener(MouseEvent.MOUSE_UP, stopDragging);