이 XMLSocket 객체가 현재 연결되어 있는지 여부를 나타냅니다. 또한 connect 이벤트 및 ioError 이벤트에 등록하여 연결 성공 여부를 확인할 수 있습니다.

참고 사항

새 XMLSocket 객체를 만듭니다. XMLSocket 객체는 처음에 어떠한 서버에도 연결되어 있지 않습니다. 객체를 서버에 연결하려면 XMLSocket.connect() 메서드를 호출해야 합니다.

참고 사항

XMLSocket 객체에 의해 지정된 연결을 종료합니다. close 이벤트는 서버가 연결을 종료할 때만 전달됩니다. close() 메서드를 호출할 때는 전달되지 않습니다.

참고 사항

지정된 TCP 포트를 사용하여 지정된 인터넷 호스트에 연결합니다. 정책 파일을 사용 중이 아니라면, 기본적으로 포트 1024 이상에만 연결할 수 있습니다.

host 매개 변수에 대해 null을 지정하면 연결된 호스트는 XMLSocket.connect()를 호출하는 SWF 파일이 있는 호스트입니다. 예를 들어, SWF 파일이 www.adobe.com에서 다운로드된 경우 호스트 매개 변수로 null을 지정하면 www.adobe.com의 IP 주소를 입력하는 것과 같습니다.

SWF 파일이 실행되고 있는 Flash Player의 버전이 7보다 낮은 경우, host는 이 호출을 수행한 SWF 파일과 동일한 수퍼 도메인에 있어야 합니다. 예를 들어, www.adobe.com의 SWF 파일은 store.adobe.com의 SWF 파일로부터 변수를 받거나 보낼 수 있습니다. 두 파일 모두 adobe.com이라는 동일한 수퍼 도메인에 위치하기 때문입니다.

SWF 파일이 실행되고 있는 Flash Player의 버전이 7 이상인 경우, host는 정확하게 동일한 도메인에 있어야 합니다. 예를 들어, www.adobe.com에 있는 어떤 SWF 파일이 Flash Player 5용으로 제작되었지만 Flash Player 7 이상에서 실행 중인 경우, 이 SWF 파일은 www.adobe.com에 있는 SWF 파일에서만 변수를 받거나 보낼 수 있습니다. 다른 도메인에서 변수를 받거나 보내려면 액세스하려는 SWF 파일을 호스팅하는 서버에 크로스 도메인 정책 파일이 존재해야 합니다.

SWF 내용을 포함하는 HTML 페이지에서 object 및 embed 태그의 allowNetworking 매개 변수를 설정하여 SWF 파일에서 이 메서드를 사용하지 못하도록 할 수 있습니다.

자세한 내용은 다음을 참조하십시오.

• 보안 장(ActionScript 3.0 프로그래밍 설명서) 및 LiveDocs의 최신 의견
• Flash Player 9 보안 백서

매개 변수

참고 사항

object 매개 변수에 지정된 XML 객체 또는 데이터를 문자열로 변환하여 서버로 전송하고, 끝에 0바이트를 붙입니다. object가 XML 객체인 경우 문자열은 XML 객체의 XML 텍스트 표현입니다. 보내기 작업은 비동기적입니다. 따라서 즉시 반환하지만 데이터는 나중에 전송될 수 있습니다. XMLSocket.send() 메서드는 데이터가 성공적으로 전송되었는지 여부를 나타내는 값을 반환하지 않습니다.

XMLSocket.connect()를 사용하여 XMLSocket 객체를 서버에 연결하지 않는 경우, XMLSocket.send() 작업에 실패합니다.

매개 변수

참고 사항

서버가 소켓 연결을 종료할 때 전달됩니다. close 이벤트는 서버가 연결을 종료할 때만 전달됩니다. XMLSocket.close() 메서드를 호출할 때는 전달되지 않습니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

XMLSocket.connect() 메서드에 대한 호출이 성공하면 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

원시 데이터를 전송하거나 수신한 후에 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

전송 또는 수신 작업의 실패를 유발하는 입력/출력 오류가 발생할 때 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

XMLSocket.connect() 메서드 호출로 호출자의 보안 샌드박스 외부에 있는 서버 또는 1024 미만의 포트에 대한 연결을 시도하면 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

참고 사항

1. XMLSocketExample 생성자는 socket이라는 이름의 XMLSocket 인스턴스를 만들고 socket을 ConfigureListeners()에 전달한 다음(아래 참조) 호스트 이름 "localhost"와 포트 번호 8080을 사용하여 XMLSocket의 connect() 메서드를 호출합니다.
2. configureListeners() 메서드가 호출되어 지원되는 각 XMLSocket 이벤트에 대해 리스너를 추가합니다.
   • closeHandler(): close 이벤트를 수신합니다. 이 이벤트는 네트워크 연결이 종료된 후 전달됩니다.
   • connectHandler(): connect 이벤트를 수신합니다. 이 이벤트는 네트워크 연결이 설정되면 전달됩니다.
   • dataHandler(): data 이벤트를 수신합니다. 이 이벤트는 XMLSocket이 새 데이터를 받을 때마다 전달됩니다.
   • progressHandler(): progress 이벤트를 수신합니다. 이 이벤트는 send()를 호출하여 전송이 진행되는 동안에 전달됩니다.
   • securityErrorHandler(): securityError 이벤트를 수신합니다. 이 이벤트는 잘못된 로컬 재생 보안 설정으로 또는 1024 미만의 포트 번호를 사용하여 XMLSocket에 액세스하려고 할 때 전달됩니다.
   • ioErrorHandler(): ioError 이벤트를 수신합니다. 이 이벤트는 데이터 전송 또는 수신 작업에 실패했을 때만 전달됩니다.

참고:

• "로컬 재생 보안"을 "네트워크에만 액세스"로 설정하여 SWF 파일을 컴파일해야 합니다.
• 이 예제가 실행되려면 [yourDomain]에서 포트 8080을 사용하여 서버가 실행 중이어야 합니다.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.XMLSocket;

    public class XMLSocketExample extends Sprite {
        private var hostName:String = "localhost";
        private var port:uint = 8080;
        private var socket:XMLSocket;

        public function XMLSocketExample() {
            socket = new XMLSocket();
            configureListeners(socket);
            socket.connect(hostName, port);
        }

        public function send(data:Object):void {
            socket.send(data);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CLOSE, closeHandler);
            dispatcher.addEventListener(Event.CONNECT, connectHandler);
            dispatcher.addEventListener(DataEvent.DATA, dataHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
        }

        private function dataHandler(event:DataEvent):void {
            trace("dataHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}