임의의 POST 데이터의 MIME 내용 유형입니다.

참고: FileReference.upload() 및 FileReference.download() 메서드는 URLRequest.contentType 매개 변수를 지원하지 않습니다.

URL 요청과 함께 전송될 데이터를 포함하는 객체입니다.

이 속성은 method 속성과 함께 사용됩니다. URLRequest.method 값이 POST인 경우 데이터는 HTTP POST 메서드 및 URLRequest 객체와 함께 전송됩니다.

URLRequest.method 값이 GET인 경우 데이터는 HTTP GET 메서드 및 URLRequest 객체와 함께 전송될 변수를 정의합니다.

URLRequest API는 문자열뿐 아니라, 이진 POST 데이터 및 URL 인코딩된 변수도 지원합니다. 데이터 객체는 ByteArray, URLVariables 또는 String 유형일 수 있습니다.

데이터의 사용 방법은 다음과 같이 사용하는 객체의 유형에 따라 달라집니다.

• 객체가 ByteArray 객체인 경우 ByteArray 객체의 이진 데이터가 POST 데이터로 사용됩니다. GET에는 ByteArray 유형의 데이터가 지원되지 않습니다. 또한 FileReference.upload() 및 FileReference.download()에 대해서도 ByteArray 유형의 데이터가 지원되지 않습니다.
• 객체가 URLVariables 객체이고 메서드가 POST인 경우 변수는 x-www-form-urlencoded 형식을 사용하여 인코딩되고 결과 문자열은 POST 데이터로 사용됩니다. 예외적인 경우로 FileReference.upload() 호출 시에는 multipart/form-data 포스트의 개별 필드로 변수가 전송됩니다.
• 객체가 URLVariables 객체이고 메서드가 GET인 경우 URLVariables 객체는 URLRequest 객체와 함께 전송될 변수를 정의합니다.
• 그렇지 않으면 객체는 문자열로 변환되고 이 문자열은 POST 또는 GET 데이터로 사용됩니다.

이 데이터는 navigateToURL() 또는 FileReference.upload() 같은 메서드에서 URLRequest 객체를 사용해야만 전송됩니다.

참고 사항

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

HTTP 양식 제출 메서드가 GET인지 POST인지를 제어합니다. 유효 값은 URLRequestMethod.GET 또는 URLRequestMethod.POST입니다.

기본값은 URLRequestMethod.GET.

참고 사항

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

HTTP 요청에 추가할 HTTP 요청 헤더의 배열입니다. 이 배열은 URLRequestHeader 객체로 구성됩니다. 배열의 각 객체는 다음과 같이 이름 문자열과 값 문자열을 포함하는 URLRequestHeader 객체여야 합니다.

  var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
  

Flash Player에서는 헤더 요청에 특정 제한 사항을 두고 있습니다. 자세한 내용은 URLRequestHeader 클래스 설명을 참조하십시오.

FileReference.upload() 및 FileReference.download() 메서드는 URLRequest.requestHeaders 매개 변수를 지원하지 않습니다.

참고 사항

요청할 URL입니다. 기본적으로 URL은 하위 도메인을 포함하여 호출하는 SWF 파일과 동일한 도메인에 있어야 합니다. 예를 들어, www.adobe.com 및 store.adobe.com에 있는 SWF 파일들은 다른 도메인에 있는 것입니다. 다른 도메인에서 데이터를 로드하려면 해당 데이터를 호스팅하는 서버에 크로스 도메인 정책 파일을 배치합니다. 자세한 내용은 URLRequest 클래스 설명에 기술된 보안 설명서를 참조하십시오.

참고: Flash Player 업데이트 3 및 이후 버전은 IPv6(인터넷 프로토콜 버전 6)를 지원합니다. IPv6은 128비트 주소를 지원하는 인터넷 프로토콜입니다(이전에 32비트 주소 체계를 지원하는 IPv4를 개선한 새 버전). 네트워크 인터페이스에서 IPv6를 활성화시켜야 합니다. 자세한 내용은 데이터를 호스팅하는 운영 체제의 도움말을 참조하십시오. 호스팅 시스템이 IPv6를 지원하면 다음과 같이 대괄호([])로 묶은 URL에 IPv6 리터럴 주소를 지정할 수 있습니다.

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

URLRequest 객체를 만듭니다. System.useCodePage가 true인 경우 해당 요청은 유니코드가 아닌 시스템 코드 페이지를 사용하여 인코딩됩니다. System.useCodePage가 false인 경우 해당 요청은 시스템 코드 페이지가 아닌 유니코드를 사용하여 인코딩됩니다.

참고 사항

이 예제를 실행하려면 XMLFile.xml이라는 이름의 파일을 사용자의 SWF 파일과 동일한 디렉토리에 넣습니다.

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {

        public function URLRequestExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}