경사의 각도입니다. 유효 값은 0 ~ 360°입니다. 기본값은 45°입니다.

각도 값은 객체에 해당하는 가상 광원의 각도를 나타내며 이 값으로 해당 객체를 기준으로 효과의 배치를 결정합니다. distance 속성을 0으로 설정하면 효과가 객체로부터 오프셋되지 않으므로 angle 속성은 아무런 영향을 주지 않습니다.

수평 흐림 효과의 정도(픽셀 단위)입니다. 유효 값은 0부터 255(부동 소수점)까지입니다. 기본값은 4입니다. 2의 거듭제곱 값(예: 2, 4, 8, 16, 32 등)은 다른 값보다 빠르게 렌더링하도록 최적화되었습니다.

수직 흐림 효과의 정도(픽셀 단위)입니다. 유효 값은 0부터 255(부동 소수점)까지입니다. 기본값은 4입니다. 2의 거듭제곱 값(예: 2, 4, 8, 16, 32 등)은 다른 값보다 빠르게 렌더링하도록 최적화되었습니다.

경사의 오프셋 거리입니다. 유효한 값의 단위는 픽셀(부동 소수점)입니다. 기본값은 4입니다.

강조 표시 색상의 알파 투명도 값입니다. 값은 0부터 1까지의 정규화된 값이 지정됩니다. 예를 들어, .25는 투명도 값을 25%로 설정합니다. 기본값은 1입니다.

경사에 대한 강조 표시 색상입니다. 유효 값은 16진수 형식인 0xRRGGBB로 표시됩니다. 기본값은 0xFFFFFF입니다.

효과적으로 객체를 투명하게 채우고 문서의 배경색을 나타낼 수 있는 녹아웃 효과를 적용(true)합니다. 기본값은 false(녹아웃 효과 사용 안 함)입니다.

필터 적용 횟수입니다. 기본값은 BitmapFilterQuality.LOW로서 필터를 1회 적용하는 것과 동일합니다. 값 BitmapFilterQuality.MEDIUM은 필터를 2회 적용하고 값 BitmapFilterQuality.HIGH는 3회 적용합니다. 낮은 값을 가진 필터가 보다 빠르게 렌더링됩니다.

대부분의 응용 프로그램의 경우 quality 값을 낮음, 중간, 높음으로 설정하면 충분합니다. 15까지의 추가적인 숫자 값을 사용하여 다른 효과를 얻을 수 있으나 값이 높을수록 렌더링 속도가 느려집니다. quality 값을 올리는 대신 간단히 blurX 및 blurY 속성의 값을 올려도 보다 빠른 렌더링으로 유사한 효과를 얻을 수 있습니다.

다음과 같은 BitmapFilterQuality 상수를 사용하여 quality 속성의 값을 지정할 수 있습니다.

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

그림자 색상의 알파 투명도 값입니다. 이 값은 0부터 1까지의 정규화된 값이 지정됩니다. 예를 들어, .25는 투명도 값을 25%로 설정합니다. 기본값은 1입니다.

경사에 대한 그림자 색상입니다. 유효 값은 16진수 형식인 0xRRGGBB로 표시됩니다. 기본값은 0x000000입니다.

인쇄나 분사 강도를 나타냅니다. 유효 값은 0부터 255까지입니다. 값이 클수록 보다 많은 색상이 인쇄되고 경사와 배경 사이의 대비가 보다 뚜렷해집니다. 기본값은 1입니다.

객체에서 경사 효과의 배치를 나타냅니다. 내부 및 외부 경사는 내부 또는 외부 가장자리에 경사 효과를 적용하고, 전체 경사는 객체 전체에 경사 효과를 적용합니다. 유효 값은 다음과 같은 BitmapFilterType 상수입니다.

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

새로운 BevelFilter 인스턴스를 지정된 매개 변수로 초기화합니다.

참고 사항

이 필터 객체의 복사본을 반환합니다.

1. 필요한 클래스를 가져옵니다.
2. draw() 함수에서 사용할 세 가지 속성을 선언합니다. 이 함수는 경사 필터를 적용할 객체를 그립니다.
3. 다음과 같은 기능을 하는 BevelFilterExample() 생성자 함수를 만듭니다.
   • 나중에 선언될 draw() 함수를 호출합니다.
   • filter 변수를 BitmapFilter 객체로 선언하고, 이 객체를 getBitmapFilter() 호출의 반환 값에 할당합니다.
   • 새 Array 객체 myFilters를 만들고 filter를 배열에 추가한 다음 myFilters를 BevelFilterExample 객체의 filters 속성에 할당합니다. 이것은 myFilters의 모든 필터에 적용되며, 이 경우에는 filter뿐입니다.
4. 필터의 속성을 만들고 설정하는 getBitmapFilter 함수를 만듭니다.
5. draw() 함수를 만듭니다. 이 함수는 Sprite 클래스의 graphics 속성을 통해 액세스되는 Graphics 클래스의 메서드를 사용하여 사각형을 그립니다.

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}