flash.events.Event (ActionScript 3.0)

	속성	다음에 의해 정의됨
		bubbles : Boolean [read-only] 이벤트가 버블링 이벤트인지 여부를 나타냅니다.	Event
		cancelable : Boolean [read-only] 해당 이벤트와 연관된 비헤이비어를 차단할 수 있는지 여부를 나타냅니다.	Event
		constructor : Object 지정된 객체 인스턴스의 클래스 객체 또는 생성자 함수에 대한 참조입니다.	Object
		currentTarget : Object [read-only] 현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.	Event
		eventPhase : uint [read-only] 이벤트 흐름에서 현재 단계입니다.	Event
		prototype : Object [static] 클래스 또는 함수 객체의 프로토타입 객체에 대한 참조입니다.	Object
		target : Object [read-only] 이벤트 대상입니다.	Event
		type : String [read-only] 이벤트 유형입니다.	Event

	메서드	다음에 의해 정의됨
		Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false) 이벤트 리스너에 매개 변수로 전달할 Event 객체를 만듭니다.	Event
		clone():Event Event 하위 클래스의 인스턴스를 복제합니다.	Event
		formatToString(className:String, ... arguments):String 사용자 정의 Event 클래스에서 toString() 메서드를 구현하기 위한 유틸리티 함수입니다.	Event
		hasOwnProperty(name:String):Boolean 지정된 속성이 객체에 정의되어 있는지 여부를 나타냅니다.	Object
		isDefaultPrevented():Boolean 이벤트에서 preventDefault()가 호출되었는지 여부를 확인합니다.	Event
		isPrototypeOf(theClass:Object):Boolean Object 클래스의 인스턴스가 매개 변수로 지정된 객체의 프로토타입 체인에 있는지 여부를 나타냅니다.	Object
		preventDefault():void 이벤트의 기본 비헤이비어를 취소할 수 있는 경우, 그 비헤이비어를 취소합니다.	Event
		propertyIsEnumerable(name:String):Boolean 지정된 속성이 존재하고 열거 가능한지 여부를 나타냅니다.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 루프 작업에서 동적 속성을 사용할 수 있는지 여부를 설정합니다.	Object
		stopImmediatePropagation():void 이벤트 흐름에서 현재 노드 및 그 후속 노드에 있는 모든 이벤트 리스너가 처리되지 않도록 합니다.	Event
		stopPropagation():void 이벤트 흐름에서 현재 노드의 후속 노드에 있는 모든 이벤트 리스너가 처리되지 않도록 합니다.	Event
		toString():String Event 객체의 속성이 모두 포함된 문자열을 반환합니다.	Event
		valueOf():Object 지정된 객체의 프리미티브 값을 반환합니다.	Object

	상수	다음에 의해 정의됨
		ACTIVATE : String = "activate" [static] activate 이벤트 객체의 type 속성 값을 정의합니다.	Event
		ADDED : String = "added" [static] added 이벤트 객체의 type 속성 값을 정의합니다.	Event
		ADDED_TO_STAGE : String = "addedToStage" [static] addedToStage 이벤트 객체의 type 속성 값을 정의합니다.	Event
		CANCEL : String = "cancel" [static] cancel 이벤트 객체의 type 속성 값을 정의합니다.	Event
		CHANGE : String = "change" [static] change 이벤트 객체의 type 속성 값을 정의합니다.	Event
		CLOSE : String = "close" [static] close 이벤트 객체의 type 속성 값을 정의합니다.	Event
		COMPLETE : String = "complete" [static] complete 이벤트 객체의 type 속성 값을 정의합니다.	Event
		CONNECT : String = "connect" [static] connect 이벤트 객체의 type 속성 값을 정의합니다.	Event
		DEACTIVATE : String = "deactivate" [static] deactivate 이벤트 객체의 type 속성 값을 정의합니다.	Event
		ENTER_FRAME : String = "enterFrame" [static] enterFrame 이벤트 객체의 type 속성 값을 정의합니다.	Event
		FULLSCREEN : String = "fullScreen" [static] fullScreen 이벤트 객체의 type 속성 값을 정의합니다.	Event
		ID3 : String = "id3" [static] id3 이벤트 객체의 type 속성 값을 정의합니다.	Event
		INIT : String = "init" [static] init 이벤트 객체의 type 속성 값을 정의합니다.	Event
		MOUSE_LEAVE : String = "mouseLeave" [static] mouseLeave 이벤트 객체의 type 속성 값을 정의합니다.	Event
		OPEN : String = "open" [static] open 이벤트 객체의 type 속성 값을 정의합니다.	Event
		REMOVED : String = "removed" [static] removed 이벤트 객체의 type 속성 값을 정의합니다.	Event
		REMOVED_FROM_STAGE : String = "removedFromStage" [static] removedFromStage 이벤트 객체의 type 속성 값을 정의합니다.	Event
		RENDER : String = "render" [static] render 이벤트 객체의 type 속성 값을 정의합니다.	Event
		RESIZE : String = "resize" [static] resize 이벤트 객체의 type 속성 값을 정의합니다.	Event
		SCROLL : String = "scroll" [static] scroll 이벤트 객체의 type 속성 값을 정의합니다.	Event
		SELECT : String = "select" [static] select 이벤트 객체의 type 속성 값을 정의합니다.	Event
		SOUND_COMPLETE : String = "soundComplete" [static] soundComplete 이벤트 객체의 type 속성 값을 정의합니다.	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] tabChildrenChange 이벤트 객체의 type 속성 값을 정의합니다.	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] tabEnabledChange 이벤트 객체의 type 속성 값을 정의합니다.	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [static] tabIndexChange 이벤트 객체의 type 속성 값을 정의합니다.	Event
		UNLOAD : String = "unload" [static] unload 이벤트 객체의 type 속성 값을 정의합니다.	Event

속성 정보

bubbles

속성

bubbles:Boolean [read-only]

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

이벤트가 버블링 이벤트인지 여부를 나타냅니다. 이 값은 이벤트가 버블링 가능한 경우 true이고, 그렇지 않으면 false입니다.

이벤트가 발생하면 이벤트 흐름의 세 가지 단계를 거쳐 이동합니다. 캡처 단계는 표시 목록 계층 구조의 맨 위에서부터 대상 노드 바로 전 노드까지 이동하는 단계이고, 대상 단계는 대상 노드로만 구성되며, 버블링 단계는 표시 목록 계층 구조에서 대상 노드 위쪽 노드부터 맨 위로 거슬러 올라가는 단계입니다.

activate 및 unload 이벤트와 같은 일부 이벤트에는 버블링 단계가 없습니다. bubbles 속성은 버블링 단계가 없는 이벤트에 대해 false 값입니다.

구현
public function get bubbles():Boolean

참고 사항

이벤트 객체

cancelable

속성

cancelable:Boolean [read-only]

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

해당 이벤트와 연관된 비헤이비어를 차단할 수 있는지 여부를 나타냅니다. 이 값은 비헤이비어를 취소할 수 있는 경우 true이고, 그렇지 않으면 false입니다.

구현
public function get cancelable():Boolean

참고 사항

Event.preventDefault()
이벤트 객체

currentTarget

속성

currentTarget:Object [read-only]

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다. 예를 들어, 확인 버튼을 클릭하는 경우 현재 대상 노드는 이 버튼을 포함하는 노드 또는 해당 이벤트에 대한 이벤트 리스너를 등록한 조상 노드 중 하나가 될 수 있습니다.

구현
public function get currentTarget():Object

참고 사항

이벤트 객체

eventPhase

속성

eventPhase:uint [read-only]

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

이벤트 흐름에서 현재 단계입니다. 이 속성은 다음 숫자 값을 포함할 수 있습니다.

1 캡처 단계(EventPhase.CAPTURING_PHASE)
2 대상 단계(EventPhase.AT_TARGET)
3 버블링 단계(EventPhase.BUBBLING_PHASE)

구현
public function get eventPhase():uint

참고 사항

이벤트 객체

target

속성

target:Object [read-only]

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

이벤트 대상입니다. 이 속성에는 대상 노드가 포함됩니다. 예를 들어, 확인 버튼을 클릭하는 경우 대상 노드는 이 버튼을 포함하는 표시 목록 노드입니다.

구현
public function get target():Object

참고 사항

이벤트 객체

type

속성

type:String [read-only]

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

이벤트 유형입니다. 유형은 대소문자를 구분합니다.

구현
public function get type():String

참고 사항

이벤트 객체

생성자 정보

Event

()

생성자

public function Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false)

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

이벤트 리스너에 매개 변수로 전달할 Event 객체를 만듭니다.

매개 변수

	`type:String` — 이벤트 유형으로, `Event.type`으로 액세스할 수 있습니다.

	`bubbles:Boolean` (default = `false`) — Event 객체가 이벤트 흐름의 버블링 단계에 참여하는지 여부를 결정합니다. 기본값은 `false`입니다.

	`cancelable:Boolean` (default = `false`) — Event 객체를 취소할 수 있는지 여부를 결정합니다. 기본값은 `false`입니다.

메서드 정보

clone

()

메서드

public function clone():Event

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

Event 하위 클래스의 인스턴스를 복제합니다.

Event 객체의 원본 인스턴스 복사본인 새 Event 객체를 반환합니다. 보통은 clone()을 호출하지 않지만 이벤트를 재전달할 때는(즉, event를 처리 중인 핸들러에서 dispatchEvent(event)를 호출할 때) EventDispatcher 클래스에서 이를 자동으로 호출합니다.

원본의 모든 속성을 포함하는 새 Event 객체입니다.

사용자 지정 Event 클래스를 만드는 경우, 이 사용자 지정 클래스의 속성을 복제하도록 상속된 Event.clone() 메서드를 재정의해야 합니다. 이벤트 하위 클래스에 추가하는 속성 중 일부 속성만 설정하면, 설정하지 않은 속성은 리스너가 재전달된 이벤트를 처리할 때 올바른 값을 갖지 않게 됩니다.

이 예제에서, PingEvent는 Event의 하위 클래스이므로 고유한 clone()을 구현합니다.

  class PingEvent extends Event { var URL:String; public override function clone():Event { return new PingEvent(type, bubbles, cancelable, URL); } }

반환값

Event — 원본과 동일한 새 Event 객체입니다.

참고 사항

이벤트 객체

formatToString

()

메서드

public function formatToString(className:String, ... arguments):String

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

사용자 정의 Event 클래스에서 toString() 메서드를 구현하기 위한 유틸리티 함수입니다. toString() 메서드를 재정의하는 것이 좋으나 반드시 필요한 것은 아닙니다.

  class PingEvent extends Event { var URL:String; public override function toString():String { return formatToString("PingEvent", "type", "bubbles", "cancelable", "eventPhase", "URL"); } }

매개 변수

	`className:String` — 사용자 지정 Event 클래스의 이름입니다. 이전 예제에서 `className` 매개 변수는 `PingEvent`입니다.

	`... arguments` — Event 클래스의 속성 및 사용자 지정 Event 클래스에 추가하는 속성입니다. 이전 예제에서 `...arguments` 매개 변수에는 `type`, `bubbles`, `cancelable`, `eventPhase` 및 `URL`이 포함됩니다.

반환값

String — 사용자 지정 Event 클래스의 이름 및 ...arguments 매개 변수의 문자열 값입니다.

isDefaultPrevented

()

메서드

public function isDefaultPrevented():Boolean

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

이벤트에서 preventDefault()가 호출되었는지 여부를 확인합니다. preventDefault()가 취소된 경우에는 true를 반환하고, 취소되지 않은 경우에는 false를 반환합니다.

반환값

Boolean — preventDefault()가 취소된 경우에는 true를 반환하고, 취소되지 않은 경우에는 false를 반환합니다.

참고 사항

flash.events.Event.preventDefault()
이벤트 객체

preventDefault

()

메서드

public function preventDefault():void

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

이벤트의 기본 비헤이비어를 취소할 수 있는 경우, 그 비헤이비어를 취소합니다.

많은 이벤트에 Flash Player에서 기본적으로 수행하는 연관된 비헤이비어가 있습니다. 예를 들어, 문자를 텍스트 필드에 입력하는 경우 기본 비헤이비어는 문자를 텍스트 필드에 표시하는 것입니다. TextEvent.TEXT_INPUT 이벤트의 기본 비헤이비어는 취소할 수 있으므로 preventDefault() 메서드를 사용하여 문자가 표시되지 않도록 할 수 있습니다.

취소할 수 없는 비헤이비어의 예로, Flash Player가 표시 목록에서 표시 객체를 제거하려고 할 때마다 생성되는 Event.REMOVED 이벤트와 연관된 기본 비헤이비어가 있습니다. 요소를 제거하는 기본 비헤이비어는 취소할 수 없으므로 preventDefault() 메서드가 이 기본 비헤이비어에 영향을 주지 못합니다.

Event.cancelable 속성을 사용하면 특정 이벤트와 연관된 기본 비헤이비어를 차단할 수 있는지 여부를 확인할 수 있습니다. Event.cancelable 값이 true인 경우에는 preventDefault()를 사용하여 이벤트를 취소할 수 있지만, 그렇지 않은 경우 preventDefault()는 효과가 없습니다.

참고 사항

flash.events.Event.isDefaultPrevented()
Event.cancelable
이벤트 객체

stopImmediatePropagation

()

메서드

public function stopImmediatePropagation():void

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

이벤트 흐름에서 현재 노드 및 그 후속 노드에 있는 모든 이벤트 리스너가 처리되지 않도록 합니다. 이 메서드는 즉시 적용되어 현재 노드에 있는 이벤트 리스너에 영향을 줍니다. 반면에 stopPropagation() 메서드는 현재 노드에 있는 모든 이벤트 리스너에서 처리를 완료할 때까지 적용되지 않습니다.

참고: 이 메서드는 이 이벤트와 연관된 비헤이비어를 취소하지 않습니다. 해당 기능에 대해서는 preventDefault()를 참조하십시오.

참고 사항

flash.events.Event.stopPropagation()
flash.events.Event.preventDefault()
이벤트 객체

stopPropagation

()

메서드

public function stopPropagation():void

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

이벤트 흐름에서 현재 노드의 후속 노드에 있는 모든 이벤트 리스너가 처리되지 않도록 합니다. 이 메서드는 현재 노드(currentTarget)에 있는 이벤트 리스너에는 아무런 영향을 주지 않습니다. 이와 달리 stopImmediatePropagation() 메서드는 현재 노드 및 그 후속 노드에 있는 이벤트 리스너가 모두 처리되지 않도록 합니다. 메서드를 다시 한 번 호출해도 마찬가지입니다. 이벤트 흐름의 모든 단계에서 이 메서드를 호출할 수 있습니다.

참고: 이 메서드는 이 이벤트와 연관된 비헤이비어를 취소하지 않습니다. 해당 기능에 대해서는 preventDefault()를 참조하십시오.

참고 사항

flash.events.Event.stopImmediatePropagation()
flash.events.Event.preventDefault()

toString

()

메서드

public function toString():String

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

Event 객체의 속성이 모두 포함된 문자열을 반환합니다. 문자열의 형식은 다음과 같습니다.

[Event type=value bubbles=value cancelable=value]

반환값

String — Event 객체의 속성이 모두 포함된 문자열입니다.

참고 사항

이벤트 객체

상수 정보

ACTIVATE

상수

public static const ACTIVATE:String = "activate"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

activate 이벤트 객체의 type 속성 값을 정의합니다.

참고: 이 이벤트는 "캡처 단계"를 통과하지 않으며 대상이 표시 목록에 있는지 여부에 관계없이 대상으로 직접 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	ACTIVATE 이벤트에 대한 리스너가 등록되어 있는 모든 DisplayObject 인스턴스입니다.

참고 사항

flash.events.EventDispatcher.activate
DEACTIVATE

ADDED

상수

public static const ADDED:String = "added"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

added 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`true`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	표시 목록에 추가할 DisplayObject 인스턴스입니다. `target`은 표시 목록에서 이벤트 리스너를 등록한 객체가 아닐 수도 있습니다. 표시 목록에서 현재 이벤트를 처리 중인 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

flash.display.DisplayObject.added
ADDED_TO_STAGE
REMOVED
REMOVED_FROM_STAGE

ADDED_TO_STAGE

상수

public static const ADDED_TO_STAGE:String = "addedToStage"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

addedToStage 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	DisplayObject 인스턴스가 포함된 하위 트리 추가를 통해 또는 직접, 스테이지 표시 목록에 추가되는 DisplayObject 인스턴스입니다. DisplayObject 인스턴스가 직접 추가되는 경우에는 이 이벤트 전에 `added` 이벤트가 발생합니다.

참고 사항

flash.display.DisplayObject.addedToStage
ADDED
REMOVED
REMOVED_FROM_STAGE

CANCEL

상수

public static const CANCEL:String = "cancel"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

cancel 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	작업이 취소된 객체에 대한 참조입니다.

참고 사항

flash.net.FileReference.cancel

CHANGE

상수

public static const CHANGE:String = "change"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

change 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`true`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	값이 수정된 객체입니다. `target`은 표시 목록에서 이벤트 리스너를 등록한 객체가 아닐 수도 있습니다. 표시 목록에서 현재 이벤트를 처리 중인 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

flash.text.TextField.change
flash.events.TextEvent.TEXT_INPUT

상수

public static const CLOSE:String = "close"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

close 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	연결이 종료된 객체입니다.

참고 사항

flash.net.Socket.close
flash.net.XMLSocket.close

COMPLETE

상수

public static const COMPLETE:String = "complete"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

complete 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	로드가 완료된 네트워크 객체입니다.

참고 사항

flash.display.LoaderInfo.complete
flash.media.Sound.complete
flash.net.FileReference.complete
flash.net.URLLoader.complete
flash.net.URLStream.complete
외부 데이터를 사용한 작업

CONNECT

상수

public static const CONNECT:String = "connect"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

connect 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	네트워크 연결을 설정한 Socket 또는 XMLSocket 객체입니다.

참고 사항

flash.net.Socket.connect
flash.net.XMLSocket.connect

DEACTIVATE

상수

public static const DEACTIVATE:String = "deactivate"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

deactivate 이벤트 객체의 type 속성 값을 정의합니다.

참고: 이 이벤트는 "캡처 단계"를 통과하지 않으며 대상이 표시 목록에 있는지 여부에 관계없이 대상으로 직접 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	DEACTIVATE 이벤트에 대한 리스너가 등록되어 있는 모든 DisplayObject 인스턴스입니다.

참고 사항

flash.events.EventDispatcher.deactivate
ACTIVATE

ENTER_FRAME

상수

public static const ENTER_FRAME:String = "enterFrame"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

enterFrame 이벤트 객체의 type 속성 값을 정의합니다.

참고: 이 이벤트는 "캡처 단계"를 통과하지 않으며 대상이 표시 목록에 있는지 여부에 관계없이 대상으로 직접 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	ENTER_FRAME 이벤트에 대한 리스너가 등록되어 있는 모든 DisplayObject 인스턴스입니다.

참고 사항

flash.display.DisplayObject.enterFrame

FULLSCREEN

상수

public static const FULLSCREEN:String = "fullScreen"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

fullScreen 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	Stage 객체입니다.

참고 사항

flash.display.Stage.fullScreen

ID3

상수

public static const ID3:String = "id3"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

id3 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	현재 이용 가능한 ID3 데이터가 있는 MP3를 로드하는 Sound 객체입니다. `target`은 표시 목록에서 이벤트 리스너를 등록한 객체가 아닐 수도 있습니다. 표시 목록에서 현재 이벤트를 처리 중인 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

flash.media.Sound.id3

INIT

상수

public static const INIT:String = "init"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

init 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	로드 중인 SWF 파일과 연관된 LoaderInfo 객체입니다.

참고 사항

flash.display.LoaderInfo.init

MOUSE_LEAVE

상수

public static const MOUSE_LEAVE:String = "mouseLeave"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

mouseLeave 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	Stage 객체입니다. `target`은 표시 목록에서 이벤트 리스너를 등록한 객체가 아닐 수도 있습니다. 표시 목록에서 현재 이벤트를 처리 중인 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

flash.display.Stage.mouseLeave
flash.events.MouseEvent

OPEN

상수

public static const OPEN:String = "open"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

open 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	연결을 설정한 네트워크 객체입니다.

참고 사항

flash.display.LoaderInfo.open
flash.media.Sound.open
flash.net.FileReference.open
flash.net.URLLoader.open
flash.net.URLStream.open

REMOVED

상수

public static const REMOVED:String = "removed"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

removed 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`true`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	표시 목록에서 제거할 DisplayObject 인스턴스입니다. `target`은 표시 목록에서 이벤트 리스너를 등록한 객체가 아닐 수도 있습니다. 표시 목록에서 현재 이벤트를 처리 중인 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

flash.display.DisplayObject.removed
ADDED
ADDED_TO_STAGE
REMOVED_FROM_STAGE

REMOVED_FROM_STAGE

상수

public static const REMOVED_FROM_STAGE:String = "removedFromStage"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

removedFromStage 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	DisplayObject 인스턴스가 포함된 하위 트리의 제거를 통해 또는 직접, 스테이지 표시 목록에서 제거되는 DisplayObject 인스턴스입니다. DisplayObject 인스턴스가 직접 추가되는 경우에는 이 이벤트 전에 `removed` 이벤트가 발생합니다.

참고 사항

flash.display.DisplayObject.removedFromStage
ADDED
REMOVED
ADDED_TO_STAGE

RENDER

상수

public static const RENDER:String = "render"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

render 이벤트 객체의 type 속성 값을 정의합니다.

참고: 이 이벤트는 "캡처 단계"를 통과하지 않으며 대상이 표시 목록에 있는지 여부에 관계없이 대상으로 직접 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`: 기본 비헤이비어를 취소할 수 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	RENDER 이벤트에 대한 리스너가 등록되어 있는 모든 DisplayObject 인스턴스입니다.

참고 사항

flash.display.DisplayObject.render
flash.display.Stage.invalidate()

RESIZE

상수

public static const RESIZE:String = "resize"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

resize 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	Stage 객체입니다.

참고 사항

flash.display.Stage.resize

SCROLL

상수

public static const SCROLL:String = "scroll"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

scroll 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	스크롤한 TextField 객체입니다. `target`은 표시 목록에서 이벤트 리스너를 등록한 객체가 아닐 수도 있습니다. 표시 목록에서 현재 이벤트를 처리 중인 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

flash.text.TextField.scroll

SELECT

상수

public static const SELECT:String = "select"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

select 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	항목이 선택된 FileReference 객체입니다.

참고 사항

flash.net.FileReference.select

SOUND_COMPLETE

상수

public static const SOUND_COMPLETE:String = "soundComplete"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

soundComplete 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	사운드 재생이 완료된 Sound 객체입니다.

참고 사항

flash.media.SoundChannel.soundComplete

TAB_CHILDREN_CHANGE

상수

public static const TAB_CHILDREN_CHANGE:String = "tabChildrenChange"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

tabChildrenChange 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`true`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	tabChildren 플래그가 변경된 객체입니다. `target`은 표시 목록에서 이벤트 리스너를 등록한 객체가 아닐 수도 있습니다. 표시 목록에서 현재 이벤트를 처리 중인 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

flash.display.InteractiveObject.tabChildrenChange

TAB_ENABLED_CHANGE

상수

public static const TAB_ENABLED_CHANGE:String = "tabEnabledChange"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

tabEnabledChange 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`true`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	tabEnabled 플래그가 변경된 InteractiveObject입니다. `target`은 표시 목록에서 이벤트 리스너를 등록한 객체가 아닐 수도 있습니다. 표시 목록에서 현재 이벤트를 처리 중인 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

flash.display.InteractiveObject.tabEnabledChange

TAB_INDEX_CHANGE

상수

public static const TAB_INDEX_CHANGE:String = "tabIndexChange"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

tabIndexChange 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`true`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	tabIndex가 변경된 객체입니다. `target`은 표시 목록에서 이벤트 리스너를 등록한 객체가 아닐 수도 있습니다. 표시 목록에서 현재 이벤트를 처리 중인 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

flash.display.InteractiveObject.tabIndexChange

UNLOAD

상수

public static const UNLOAD:String = "unload"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9

unload 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`currentTarget`	현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.
`target`	언로드하거나 교체할 SWF 파일과 연관된 LoaderInfo 객체입니다.

참고 사항

flash.display.LoaderInfo.unload

예제 예제 사용 방법

EventExample.as

다음 예제에서는 EventExample 클래스 및 Square 사용자 정의 클래스를 사용하여 이벤트 버블링을 관리하는 방법을 보여 줍니다.

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;

    public class EventExample extends Sprite {
        
        public function EventExample() {
            var square_0:Square = new Square(300, 0x336633);
            addChild(square_0);
            
            var square_1:Square = new Square(250, 0x669966);
            square_0.addChild(square_1);

            var square_2:Square = new Square(200, 0x66CC66);
            square_1.addChild(square_2);

            var square_3:Square = new Square(150, 0xAA0000);
            square_3.shouldBubble = false;
            square_2.addChild(square_3);

            var square_4:Square = new Square(100, 0x66FF66);
            square_3.addChild(square_4);

            var square_5:Square = new Square(50, 0xCC0000);
            square_5.shouldBubble = false;
            square_4.addChild(square_5);

            this.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(e:Event):void {
            trace(">> stage: " + e.type + " event from " + e.target.name + " called on " + this.name);
            trace(">> --------------------------------------------");
        }
    }
}

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

class Square extends Sprite {
    private var sideLen:int;
    private var color:Number;
    public var shouldBubble:Boolean = true;

    public function Square(sideLen:int, color:Number) {
        this.sideLen = sideLen;
        this.color = color;
        init();
        draw();
    }
        
    private function init():void {
        buttonMode = true;
        this.addEventListener(MouseEvent.CLICK, firstClickHandler);
        this.addEventListener(MouseEvent.CLICK, secondClickHandler);
        this.addEventListener(MouseEvent.CLICK, thirdClickHandler);
    }
        
    private function draw():void {
        this.graphics.beginFill(color);
        this.graphics.drawRect(0, 0, sideLen, sideLen);
    }
        
    private function firstClickHandler(e:Event):void {
        trace(">> 1e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopPropagation();
        }
    }

    private function secondClickHandler(e:Event):void {
        trace(">> 2e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopImmediatePropagation();
            trace(">> --------------------------------------------");
        }
    }

    private function thirdClickHandler(e:Event):void {
        trace(">> 3e: " + e.type + " event from " + e.target.name + " called on " + this.name);
    }
}

EventExample2.as

다음 예제에서는 ADDED와 ADDED_TO_STAGE 이벤트의 차이 및 REMOVED와 REMOVED_FROM_STAGE 이벤트의 차이를 보여 주는 대화형 데모를 만듭니다 . 스프라이트를 클릭하면 스테이지에서 스프라이트와 스프라이트 내에 중첩된 모든 것을 제거합니다. 예를 들어 가장 큰 스프라이트를 클릭하면 REMOVED 이벤트와 세 번의 REMOVED_FROM_STAGE 이벤트가 발생합니다.

 package {
    import flash.display.Sprite;
    import flash.events.*;

    public class EventExample2 extends Sprite {
        public function EventExample2():void {
            var parentSprite:Sprite = createSprite("parentSprite",200);
            var childSprite:Sprite = createSprite("childSprite",100);
            var childOfChildSprite:Sprite = createSprite("childOfChildSprite",50);
            
            trace(":: Adding to Stage ::");
            this.addChild(parentSprite);
            trace(":: Adding to Stage ::");
            parentSprite.addChild(childSprite);
            trace(":: Adding to Stage ::");
            childSprite.addChild(childOfChildSprite);
        }
        private function createSprite(name:String,size:uint):Sprite {
            trace(":: Creating Sprite ::");
            var newSprite:Sprite = new Sprite();
            newSprite.name = name;
            newSprite.graphics.beginFill(0xFFFFFF * Math.random(),1);
            newSprite.graphics.drawRect(0,0,size,size);
            newSprite.graphics.endFill();
            newSprite.addEventListener(Event.ADDED, spriteAdded);
            newSprite.addEventListener(Event.ADDED_TO_STAGE, spriteAddedToStage);
            newSprite.addEventListener(Event.REMOVED, spriteRemoved);
            newSprite.addEventListener(Event.REMOVED_FROM_STAGE, spriteRemovedFromStage);
            newSprite.addEventListener(MouseEvent.CLICK, remove);
            return newSprite;
        }
        private function remove(event:Event) {
            if(event.target == event.currentTarget) {
                trace(":: Removing Clicked Sprite ::");
                var target:Sprite = Sprite(event.target);
                target.parent.removeChild(target);
            }
        }
        private function spriteRemovedFromStage(event:Event):void {
            trace("REMOVED_FROM_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteRemoved(event:Event):void {
            trace("REMOVED: " + event.target.name + " from " + event.currentTarget.name);
        }
        private function spriteAddedToStage(event:Event):void {
            trace("ADDED_TO_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteAdded(event:Event):void {
            trace("ADDED: " + event.target.name + " within " + event.currentTarget.name);
        }
    }
}

현재 페이지: http://livedocs.adobe.com/flash/9.0_kr/ActionScriptLangRefV3/flash/events/Event.html

ActionScript 3.0 언어 및 구성 요소 참조 설명서		모든 패키지 \| 모든 클래스 \| 언어 요소 \| 색인 \| 부록 \| 규칙 \| 프레임 비프레임
Event	속성 \| 메서드 \| 상수 \| 예제

패키지	flash.events
클래스	public class Event
상속	Event Object
하위 클래스	ActivityEvent, CaptionChangeEvent, CaptionTargetEvent, ColorPickerEvent, ComponentEvent, ContextMenuEvent, DataChangeEvent, FocusEvent, HTTPStatusEvent, KeyboardEvent, LayoutEvent, ListEvent, MetadataEvent, MotionEvent, MouseEvent, NetStatusEvent, ProgressEvent, ScrollEvent, SliderEvent, SoundEvent, StatusEvent, SyncEvent, TextEvent, TimerEvent, TweenEvent, VideoEvent