Flash Player 또는 브라우저에서 스테이지 정렬을 지정하는 StageAlign 클래스 값입니다. 유효 값은 다음과 같습니다.

align 속성은 스테이지 소유자(기본 SWF 파일)와 동일한 보안 샌드박스에 있는 객체에만 사용할 수 있습니다. 스테이지 소유자는 이와 같은 상황을 피하기 위해 Security.allowDomain() 메서드 또는 Security.alowInsecureDomain() 메서드를 호출하여 호출하는 객체의 도메인에 권한을 부여할 수 있습니다. 자세한 내용은 ActionScript 3.0 프로그래밍의 "보안" 장을 참조하십시오.

참고 사항

사용할 표시 상태를 지정하는 StageDisplayState 클래스의 값입니다. 유효 값은 다음과 같습니다.

• StageDisplayState.FULL_SCREEN Flash Player에서 전체 화면에 걸쳐 Stage를 확장하도록 설정합니다.
• StageDisplayState.NORMAL 플레이어를 표준 Stage 표시 모드로 되돌리도록 설정합니다.

전체 화면 모드에서 동영상의 크기 조절 비헤이비어는 scaleMode 설정으로 결정됩니다(HTML 파일에서 Stage.scaleMode 속성 또는 SWF 파일의 embed 태그 설정을 사용하여 설정함). Flash Player가 전체 화면 모드로 전환되었을 때 scaleMode 속성이 noScale로 설정되면 Stage width 및 height 속성이 업데이트되고, Flash Player에서 Stage.resize 이벤트를 전달합니다.

HTML 페이지에서 실행되는 SWF 파일(독립 실행형 Flash Player를 사용하지 않음)에는 다음과 같은 제한 사항이 있습니다.

• 전체 화면 모드를 활성화하려면 다음 예제와 같이 SWF 파일이 포함된 HTML 페이지에서 object 및 embed 태그에 allowFullScreen 매개 변수를 추가하고 allowFullScreen을 "true"로 설정합니다.

  <param name="allowFullScreen" value="true" />
           ...
    <embed src="example.swf" allowFullScreen="true" ... >

  또한 HTML 페이지에서 스크립트를 사용하여 SWF 포함 태그를 생성할 수 있습니다. 적절한 allowFullScreen 설정을 삽입하도록 해당 스크립트를 변경해야 합니다. Flash 및 Flex Builder에서 생성된 HTML 페이지는 AC_FL_RunContent() 함수를 사용하여 SWF 파일에 대한 참조를 포함하며 사용자가 다음과 같이 allowFullScreen 매개 변수 설정을 추가해야 합니다.

  AC_FL_RunContent( ... "allowFullScreen", "true", ... )

• 전체 화면 모드는 마우스 클릭이나 키 누르기에 대한 응답으로 시작되며, 동영상은 사용자 입력 없이 Stage.displayState를 변경할 수 없습니다. Flash Player가 전체 화면 모드로 실행되는 동안에는 모든 키보드 입력이 비활성화됩니다(전체 화면 모드 상태를 벗어나는 키보드 단축키 제외). 전체 화면 모드가 되면 Flash Player 대화 상자가 표시되어 전체 화면 모드로 전환되며 Esc 키를 눌러 전체 화면 모드를 끝낼 수 있다고 알립니다.
• Flash Player 업데이트 3 이후부터는 전체 화면이 윈도우 없음 모드에서도 윈도우 모드와 같은 방식으로 작동합니다. 윈도우 모드(HTML에서 wmode)를 불투명 윈도우 없음(opaque) 또는 투명 윈도우 없음(transparent)로 설정하면 전체 화면이 시작될 수 있지만 전체 화면 창은 항상 불투명하게 됩니다.

참고 사항

package {
    import flash.display.Sprite;
    import flash.display.Stage;
    import flash.events.*;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.media.Video;
    
    public class FullScreenExample extends Sprite
    {
        private var videoURL:String = "testVideo.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var video:Video;        
        
        public function FullScreenExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
            
            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK,toggleFullScreen);
        }        
        
        private function toggleFullScreen(event:MouseEvent):void {
            switch(stage.displayState) {
                case "normal":
                    stage.displayState = "fullScreen";    
                    break;
                case "fullScreen":
                default:
                    stage.displayState = "normal";    
                    break;
            }
        }    
        
        // Video related:
        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }
        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);

            video = new Video(stage.stageWidth,stage.stageHeight);
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }            
    }
}

키보드 포커스가 있는 대화형 객체입니다. 포커스가 설정되어 있지 않거나 포커스 객체가 호출하는 객체에서 액세스할 수 없는 보안 샌드박스에 속한 경우에는 null입니다.

스테이지의 프레임 속도를 확인하고 설정합니다. 프레임 속도는 초당 프레임으로 정의됩니다. 기본적으로 이 속도는 로드된 첫 번째 SWF 파일의 프레임 속도로 설정됩니다. 유효한 프레임 속도 범위는 초당 0.01 ~ 1000프레임입니다.

Note: 대상 플랫폼이 충분히 빠르지 않거나 플레이어가 표시 장치의 수직 귀선소거 타이밍(보통 LCD 장치에서 60Hz)에 동기화된 경우 Flash Player는 높은 속도의 프레임 설정을 따라가지 못할 수 있습니다. 대상 플랫폼에서 높은 CPU 사용량이 예상되는 경우에는 최대 프레임 속도를 낮출 수도 있습니다.

전체 화면 크기로 진입할 때 사용할 모니터의 높이를 반환합니다(즉시 해당 상태로 진입하는 경우). 사용자가 여러 모니터를 가진 경우 사용되는 모니터는 해당 시점에서 스테이지의 대부분이 있는 모니터입니다.

참고: 사용자가 값을 검색하는 도중에 한 모니터에서 다른 모니터로 브라우저를 이동하고 전체 화면 크기로 진입하면 값이 잘못될 수 있습니다. Stage.displayState를 StageDisplayState.FULL_SCREEN으로 설정하는 이벤트 핸들러에서 값을 검색하면 정확한 값을 얻을 수 있습니다.

이 값은 모니터의 픽셀 높이이며 Stage.align이 StageAlign.TOP_LEFT로 설정되고 Stage.scaleMode가 StageScaleMode.NO_SCALE로 설정된 경우 스테이지 높이와 동일합니다.

플레이어 버전: Flash Player 9 업데이트 3.

참고 사항

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

스테이지의 특정 영역을 전체 화면 모드로 확장하도록 Flash Player를 설정합니다. 가능한 경우, Flash Player는 하드웨어를 통해 크기를 조절합니다. 이 경우 사용자의 컴퓨터에 장착된 그래픽 및 비디오 카드를 사용하며 일반적으로 소프트웨어로 크기를 조절할 때보다 더욱 빠르게 내용을 표시합니다.

이 속성이 유효한 사각형으로 설정되고 displayState 속성이 전체 화면 모드로 설정된 경우 Flash Player가 지정된 영역의 크기를 조절합니다. ActionScript 내에서 픽셀 단위의 실제 스테이지 크기는 변경되지 않습니다. Flash Player는 "전체 화면 모드를 종료하려면 Esc를 누르십시오"라는 표준 메시지를 수용하도록 사각형의 크기에 대해 최소 제한을 적용합니다. 이 제한은 대개 약 260 x 30픽셀이지만 플랫폼과 Flash Player 버전에 따라 다를 수 있습니다.

이 속성은 Flash Player가 전체 화면 모드가 아닌 경우에만 설정할 수 있습니다. 이 속성을 정확히 사용하려면 코드 예제에 나오는 것처럼 먼저 이 속성을 설정한 다음 displayState 속성을 전체 화면 모드로 설정합니다.

크기 조절을 활성화하려면 fullScreenSourceRect 속성을 rectangle 객체로 설정합니다.

  
  // valid, will enable hardware scaling
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240); 
  

크기 조절을 비활성화하려면 ActionScript 3.0에서는 fullScreenSourceRect=null로 설정하고 ActionScript 2.0에서는 undefined로 설정합니다.

  stage.fullScreenSourceRect = null;
  

또한 최종 사용자가 Flash Player 디스플레이 설정 내에서 기본적으로 활성화된 하드웨어적인 크기 조절을 비활성화하도록 선택할 수도 있습니다. 자세한 내용은 www.adobe.com/go/display_settings_kr을 참조하십시오.

플레이어 버전: Flash Player 9 업데이트 3.

참고 사항

 
import flash.geom.*; 
{
  stage.fullScreenSourceRect = new Rectangle(0,0,320,240);
  stage.displayState = StageDisplayState.FULL_SCREEN;
}

package {
    import flash.display.Sprite;
    import flash.display.StageDisplayState;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.NetStatusEvent;
    import flash.events.AsyncErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.events.MouseEvent;
    import flash.events.Event;
    import flash.geom.Rectangle;
    
    public class Stage_fullScreenSourceRectExample2 extends Sprite {
        private var videoURL:String = "testVideo1.flv";
        private var connection:NetConnection;
        private var stream:NetStream;
        private var myVideo:Video;        
        private    var savedWidth:uint;
        private    var savedHeight:uint;
 
        public function Stage_fullScreenSourceRectExample2() {
    
            connection = new NetConnection();
             connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);    
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);

            loaderInfo.addEventListener(Event.INIT, createMouseListener);            
        }

        private function createMouseListener(event:Event):void {
            stage.addEventListener(MouseEvent.CLICK, toggleFullScreen);
        }        

        private function toggleFullScreen(event:MouseEvent):void {

            if(stage.displayState == StageDisplayState.NORMAL) {
                myVideo.width = myVideo.videoWidth;
                  myVideo.height = myVideo.videoHeight;

                try {
                    stage.fullScreenSourceRect = new Rectangle(myVideo.x, myVideo.y, 
                                                           myVideo.width, myVideo.height);
                     stage.displayState = StageDisplayState.FULL_SCREEN;

                 } catch (e:SecurityError) {
                     trace ("A security error occurred while switching to full screen: " + event);
                    myVideo.width = savedWidth;
                    myVideo.height = savedHeight;
                 }

            }else {
                myVideo.width = savedWidth;
                myVideo.height = savedHeight;
                stage.displayState = StageDisplayState.NORMAL;
            }
        }    

       private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace ("Unable to locate video: " + videoURL);
                    break;
            }
        }

       private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);     

             myVideo = new Video();
            myVideo.attachNetStream(stream);
            stream.play(videoURL);

            savedWidth = myVideo.width;
            savedHeight = myVideo.height;

            addChild(myVideo);
        }
       
        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);    
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            
        }            
    }
}

전체 화면 크기로 진입할 때 사용할 모니터의 폭을 반환합니다(즉시 해당 상태로 진입하는 경우). 사용자가 여러 모니터를 가진 경우 사용되는 모니터는 해당 시점에서 스테이지의 대부분이 있는 모니터입니다.

참고: 사용자가 값을 검색하는 도중에 한 모니터에서 다른 모니터로 브라우저를 이동하고 전체 화면 크기로 진입하면 값이 잘못될 수 있습니다. Stage.displayState를 StageDisplayState.FULL_SCREEN으로 설정하는 이벤트 핸들러에서 값을 검색하면 정확한 값을 얻을 수 있습니다.

이 값은 모니터의 픽셀 폭이며 Stage.align이 StageAlign.TOP_LEFT로 설정되고 Stage.scaleMode가 StageScaleMode.NO_SCALE로 설정된 경우의 스테이지 폭과 동일합니다.

플레이어 버전: Flash Player 9 업데이트 3.

참고 사항

import flash.display.Sprite;
import flash.display.Stage;
import flash.display.StageDisplayState;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
 
// cover the stage with a green rectangle
var greenRect:Sprite = new Sprite();
greenRect.graphics.beginFill(0x00FF00);
greenRect.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
addChild(greenRect);
 
// create red square on stage, turn it into a button for going to full screen
var redSquare:Sprite = new Sprite();
redSquare.graphics.beginFill(0xFF0000);
redSquare.graphics.drawRect(0, 0, 300, 300);
redSquare.x = 50;
redSquare.y = 50;
redSquare.addEventListener(MouseEvent.CLICK, enterFullScreen);
redSquare.buttonMode = true;
addChild(redSquare);
 
function enterFullScreen(e:MouseEvent):void
{
    // we will go to full screen zoomed in on the red square
    var redSquare:Sprite = e.target as Sprite;
    var fullScreenRect:Rectangle = new Rectangle(redSquare.x, redSquare.y, redSquare.width, redSquare.height);
 
    // calculate aspect ratio of the red square
    var rectAspectRatio:Number = fullScreenRect.width / fullScreenRect.height;
 
    // calculate aspect ratio of the screen
    var screenAspectRatio:Number = stage.fullScreenWidth / stage.fullScreenHeight;
  
    // change the fullScreenRect so that it covers the entire screen, keeping it centered on the redSquare
    // try commenting out this section to see what happens if you do not fix the aspect ratio.
    if (rectAspectRatio > screenAspectRatio) {
         var newHeight:Number = fullScreenRect.width / screenAspectRatio;
         fullScreenRect.y -= ((newHeight - fullScreenRect.height) / 2);
        fullScreenRect.height = newHeight;
    } else if (rectAspectRatio < screenAspectRatio) {
        var newWidth:Number = fullScreenRect.height * screenAspectRatio;
        fullScreenRect.x -= ((newWidth - fullScreenRect.width) / 2);
        fullScreenRect.width = newWidth;
    }
 
    // go to full screen
    stage.fullScreenSourceRect = fullScreenRect;
    stage.displayState = StageDisplayState.FULL_SCREEN;
}

표시 객체의 높이를 픽셀 단위로 나타냅니다. 높이는 표시 객체 내용의 경계에 따라 계산됩니다. 다음 코드와 같이 height 속성을 설정하면 그에 따라 scaleY 속성이 조절됩니다.

 var rect:Shape = new Shape();
 rect.graphics.beginFill(0xFF0000);
 rect.graphics.drawRect(0, 0, 100, 100);
 trace(rect.scaleY) // 1;
 rect.height = 200;
 trace(rect.scaleY) // 2;

TextField 및 Video 객체를 제외하고 빈 스프라이트처럼 내용이 없는 표시 객체는 height를 다른 값으로 설정하려고 해도 높이가 0입니다.

해당 객체의 자식에서 마우스 기능을 사용할 수 있는지 여부를 결정합니다. 마우스 기능을 사용할 수 있는 객체는 마우스로 조작할 수 있습니다. 기본값은 true입니다.

이 속성은 SimpleButton 클래스 대신 Sprite 클래스의 인스턴스를 사용하여 버튼을 만들 때 유용합니다. Sprite 인스턴스를 사용하여 버튼을 만들 때는 addChild() 메서드를 사용하여 별도의 Sprite 인스턴스를 추가함으로써 버튼을 꾸밀 수 있습니다. 이 프로세스는 마우스 이벤트의 예기치 못한 비헤이비어를 초래할 수 있습니다. 부모 인스턴스가 마우스 이벤트의 대상 객체가 될 것으로 생각하고 Sprite 인스턴스를 자식으로 추가했는데 Sprite 인스턴스가 대상 객체가 될 수 있기 때문입니다. 부모 인스턴스가 마우스 이벤트의 대상 객체가 되도록 하려면 부모 인스턴스의 mouseChildren 속성을 false로 설정합니다.

이 속성을 설정할 때 전달되는 이벤트는 없습니다. 대화형 기능을 만들려면 addEventListener() 메서드를 사용해야 합니다.

이 객체의 자식 수를 반환합니다.

Flash Player에서 사용할 렌더링 품질을 지정하는 StageQuality 클래스 값입니다. 유효 값은 다음과 같습니다.

• StageQuality.LOW - 낮은 렌더링 품질입니다. 그래픽이 앤티앨리어싱되지 않고 비트맵이 다듬어지지 않습니다.
• StageQuality.MEDIUM - 중간 렌더링 품질입니다. 2 x 2 픽셀 격자를 사용하여 그래픽이 앤티앨리어싱되고 비트맵이 매끄럽게 다듬어지지 않습니다. 이 설정은 텍스트가 포함되지 않은 무비에 적합합니다.
• StageQuality.HIGH - 높은 렌더링 품질입니다. 4 x 4 픽셀 격자를 사용하여 그래픽이 앤티앨리어싱되고 무비가 정적일 때 비트맵이 매끄럽게 다듬어집니다. Flash Player에서 사용하는 기본 렌더링 품질 설정입니다.
• StageQuality.BEST - 가장 높은 렌더링 품질입니다. 4 x 4픽셀 격자를 사용하여 그래픽이 앤티앨리어싱되고 비트맵은 항상 매끄럽게 처리됩니다.

참고 사항

사용할 크기 조절 모드를 지정하는 StageScaleMode 클래스 값입니다. 유효 값은 다음과 같습니다.

• StageScaleMode.EXACT_FIT - 응용 프로그램의 원래 종횡비를 유지하면서 왜곡 없이 전체 Flash 응용 프로그램을 지정된 영역에 표시합니다. 응용 프로그램의 두 면에 테두리가 표시될 수 있습니다.
• StageScaleMode.SHOW_ALL - 원래 종횡비를 유지하지 않고 전체 Flash 응용 프로그램을 지정된 영역에 표시합니다. 내용이 찌그러질 수 있습니다.
• StageScaleMode.NO_BORDER - 응용 프로그램의 원래 종횡비를 유지하면서 왜곡 없이(일부는 잘릴 수 있음) 전체 Flash 응용 프로그램이 지정된 영역을 채웁니다.
• StageScaleMode.NO_SCALE - 플레이어 창의 크기가 변경되는 경우에도 전체 Flash 응용 프로그램이 변경되지 않고 유지되도록 고정합니다. 플레이어 윈도우가 내용보다 작으면 내용이 잘릴 수 있습니다.

참고 사항

Flash Player 컨텍스트 메뉴에서 기본 항목의 표시 또는 숨김을 지정합니다.

showDefaultContextMenu 속성이 true(기본값)로 설정된 경우 모든 컨텍스트 메뉴 항목이 나타납니다. showDefaultContextMenu 속성이 false로 설정된 경우 설정 메뉴 항목 및 Adobe Flash Player 정보 메뉴 항목만 나타납니다.

포커스를 받은 객체의 경계선을 광선으로 표시할지 여부를 지정합니다.

Stage의 현재 높이를 픽셀 단위로 지정합니다.

Stage.scaleMode 속성 값이 StageScaleMode.NO_SCALE로 설정된 경우 stageHeight 속성은 Flash Player 창의 높이를 나타냅니다. Stage.scaleMode 값이 StageScaleMode.NO_SCALE로 설정되지 않은 경우 stageHeight는 SWF 파일의 높이를 나타냅니다. 이 속성은 설정할 수 없습니다.

참고 사항

Stage의 현재 폭을 픽셀 단위로 지정합니다.

scaleMode 속성 값이 StageScaleMode.NO_SCALE로 설정된 경우 stageWidth 속성은 Flash Player의 폭을 나타냅니다. 이것은 Flash Player 창의 크기를 조절할 때 stageWidth 속성이 변경된다는 것을 의미합니다. scaleMode 속성 값이 StageScaleMode.NO_SCALE로 설정되지 않은 경우 stageWidth 속성은 문서 속성 대화 상자에서 작성할 때 설정된 SWF 파일의 폭을 나타냅니다. 이것은 Flash Player 창의 크기를 조절할 때 stageWidth 속성 값이 그대로 유지된다는 것을 의미합니다. 이 속성은 설정할 수 없습니다.

참고 사항

객체의 자식에서 탭 기능을 사용할 수 있는지 여부를 결정합니다. 객체의 자식에 대한 탭 기능을 활성화하거나 비활성화합니다. 기본값은 true입니다.

이 DisplayObjectContainer 인스턴스에 대한 TextSnapshot 객체를 반환합니다.

표시 객체의 폭을 픽셀 단위로 나타냅니다. 폭은 표시 객체 내용의 경계에 따라 계산됩니다. 다음 코드와 같이 width 속성을 설정하면 그에 따라 scaleX 속성이 조절됩니다.

 var rect:Shape = new Shape();
 rect.graphics.beginFill(0xFF0000);
 rect.graphics.drawRect(0, 0, 100, 100);
 trace(rect.scaleX) // 1;
 rect.width = 200;
 trace(rect.scaleX) // 2;

TextField 및 Video 객체를 제외하고 빈 스프라이트처럼 내용이 없는 표시 객체는 width를 다른 값으로 설정하려고 해도 폭이 0입니다.

이미 다른 표시 객체 컨테이너를 부모로 삼고 있는 자식 객체를 추가하는 경우, 그 객체는 다른 표시 객체 컨테이너의 자식 목록에서 제거됩니다.

매개 변수

참고 사항

예를 들어, 다음 예제에서는 인덱스 위치가 각각 0, 1, 2인 세 개의 표시 객체 a, b, c를 보여 줍니다.

이미 다른 표시 객체 컨테이너를 부모로 삼고 있는 자식 객체를 추가하는 경우, 그 객체는 다른 표시 객체 컨테이너의 자식 목록에서 제거됩니다.

매개 변수

참고 사항

이벤트 리스너의 등록을 마친 뒤에는 addEventListener()를 추가로 호출하여 그 우선 순위를 변경할 수 없습니다. 리스너의 우선 순위를 변경하려면 먼저 removeListener()를 호출해야 합니다. 그런 다음 해당 리스너를 새로운 우선 순위 레벨로 다시 등록할 수 있습니다.

일단 리스너가 등록된 뒤에 type 또는 useCapture 값을 달리하여 addEventListener()를 이어서 호출하면 별도의 리스너 등록이 생성된다는 것에 유의합니다. 예를 들어, useCapture가 true로 설정된 리스너를 등록하면 이 리스너는 캡처 단계 동안에만 수신합니다. 그러나 useCapture를 false로 설정하고 동일한 리스너 객체를 사용하여 addEventListener()를 다시 호출하면 별도로 두 개의 리스너가 등록되어, 한 리스너는 캡처 단계 동안 수신하고 다른 하나는 대상 및 버블링 단계 동안 수신합니다.

대상 단계 또는 버블링 단계 전용의 이벤트 리스너를 등록할 수는 없습니다. 버블링은 대상 노드의 조상에만 적용되기 때문에 이들 단계는 등록 과정에서 하나로 통합됩니다.

사용하지 않는 이벤트 리스너는 removeEventListener()를 호출하여 제거하도록 합니다. 이렇게 하지 않으면 메모리 문제가 발생할 수 있습니다. 가비지 수집기는 참조가 남아 있는 객체를 제거하지 않으므로, 등록된 이벤트 리스너가 있는 객체는 메모리에서 자동으로 제거되지 않습니다.

EventDispatcher 인스턴스를 복사해도 연결된 이벤트 리스너는 복사되지 않습니다. 새로 만든 노드에 이벤트 리스너가 필요한 경우, 먼저 해당 노드를 만들고 리스너를 연결해야 합니다. 그러나 EventDispatcher 인스턴스를 이동할 때에는 연결된 이벤트 리스너도 함께 이동됩니다.

이벤트를 처리 중인 노드에서 이벤트 리스너를 등록하는 경우, 그 이벤트 리스너는 현재 단계 동안에는 트리거되지 않지만 이벤트 흐름에서 이후 단계(예: 버블링 단계) 동안에는 트리거될 수 있습니다.

이벤트를 처리 중인 노드에서 이벤트 리스너를 제거하는 경우, 그 리스너는 현재 액션에 의해 트리거됩니다. 일단 제거된 이벤트 리스너는 이후의 처리를 위해 재등록하지 않는 한 다시는 호출되지 않습니다.

매개 변수

참고 사항

매개 변수

hasEventListener()와 willTrigger() 간의 차이점은 hasEventListener()가 자신이 속한 객체만 검사하는 반면 willTrigger()는 type 매개 변수에 의해 지정된 이벤트의 전체 흐름을 검사한다는 점입니다.

LoaderInfo 객체로부터 hasEventListener()가 호출된 경우에는 해당 호출자가 액세스할 수 있는 리스너만 고려의 대상이 됩니다.

매개 변수

invalidate() 메서드를 호출하면 Flash Player에 신호를 보내 다음 번(예: 재생 헤드가 새 프레임으로 넘어갈 때)에는 표시 객체에게 표시 목록을 렌더링해야 한다고 알리도록 합니다. invalidate() 메서드를 호출한 후 다음에 표시 목록이 렌더링될 때 Flash Player는 render 이벤트를 수신하도록 등록된 각 표시 객체에 render 이벤트를 보냅니다. Flash Player에서 render 이벤트를 보내려면 매번 invalidate() 메서드를 호출해야 합니다.

render 이벤트를 사용하면 표시 목록이 실제로 렌더링되기 직전에 표시 목록을 변경할 수 있습니다. 즉, 최신 변경을 적용할 때까지 표시 목록 업데이트를 연기할 수 있습니다. 이를 통해 불필요한 화면 업데이트를 제거하므로 성능이 향상될 수 있습니다.

render 이벤트는 stage.invalidate() 메서드를 호출하는 코드와 동일한 보안 도메인에 있는 표시 객체 또는 Security.allowDomain() 메서드를 통해 권한을 부여받은 보안 도메인의 표시 객체에만 전달됩니다.

참고 사항

Stage.focus 속성이 보안상의 이유로 null을 반환하는지 여부를 결정합니다. 즉, 포커스가 있는 객체가 SWF 파일이 액세스할 수 없는 보안 샌드박스에 속한 경우 isFocusInaccessible은 true를 반환합니다.

가비지 수집기는 Flash Player에서 미사용 메모리 공간을 재할당하는 프로세스입니다. 현재 변수 또는 객체가 더 이상 다른 곳에 저장되거나 참조되지 않을 때 그에 대한 다른 참조가 없으면 가비지 수집기는 해당 변수 또는 객체가 차지하는 메모리 공간을 분석하고 정리합니다.

매개 변수

setChildIndex() 메서드를 사용하여 이미 점유된 인덱스 위치를 지정할 경우, 자식 목록에서 해당 위치에 있는 자식부터 그 위쪽의 모든 객체가 한 자리씩 위로 이동합니다. 예를 들어, 이전 예제에서 다룬 표시 객체 컨테이너의 이름이 container라면 다음 코드를 호출하여 a 표시 객체와 b 표시 객체의 위치를 맞바꿀 수 있습니다.

container.setChildIndex(container.getChildAt(1), 0);

이 코드는 객체를 다음과 같이 배열합니다.

매개 변수

매개 변수

hasEventListener()와 willTrigger() 메서드 간의 차이점은 hasEventListener()가 자신이 속한 객체만 검사하는 반면 willTrigger() 메서드는 type 매개 변수에 의해 지정된 이벤트의 전체 이벤트 흐름을 검사한다는 점입니다.

LoaderInfo 객체로부터 willTrigger()가 호출된 경우에는 해당 호출자가 액세스할 수 있는 리스너만 고려의 대상이 됩니다.

매개 변수

Stage 객체가 전체 화면 모드를 시작하거나 전체 화면 모드에서 벗어날 때 Flash Player에 의해 전달됩니다. 전체 화면 모드 변경은 ActionScript나 키보드 단축키를 호출하는 사용자에 의해, 또는 현재 포커스가 전체 화면 윈도우 밖으로 벗어나는 경우에 시작됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

마우스 포인터가 Flash Player 윈도우 영역 밖으로 이동할 때 Stage 객체에 의해 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

Stage 객체의 scaleMode 속성이 StageScaleMode.NO_SCALE로 설정된 상태에서 SWF 파일의 크기가 조정될 때 전달됩니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

1. 먼저 클래스 생성자가 Flash Player 창 크기와 관계없이 응용 프로그램이 고정되도록 설정한 후 activateHandler() 및 resizeHandler() 메서드를 사용하여 두 개의 이벤트 리스너를 추가합니다.
2. 마우스 왼쪽 버튼을 클릭하면 activateHandler() 메서드가 실행됩니다.
3. 스테이지 크기를 조절하면 resizeHandler() 메서드가 실행됩니다.

package {
    import flash.display.Sprite;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.events.Event;

    public class StageExample extends Sprite {

        public function StageExample() {
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            stage.addEventListener(Event.ACTIVATE, activateHandler);
            stage.addEventListener(Event.RESIZE, resizeHandler);
        }

        private function activateHandler(event:Event):void {
            trace("activateHandler: " + event);
        }

        private function resizeHandler(event:Event):void {
            trace("resizeHandler: " + event);
            trace("stageWidth: " + stage.stageWidth + " stageHeight: " + stage.stageHeight);
        }
    }
}