| 부록 | 규칙 | 프레임
| 패키지 | fl.managers |
| 클래스 | public class StyleManager |
| 상속 | StyleManager  Object |
| 언어 버전 : | ActionScript 3.0 |
| Player 버전 : | Flash Player 9.0.28.0 |
| 메서드 | 다음에 의해 정의됨 | ||
|---|---|---|---|
|
새 StyleManager 객체를 만듭니다.
| StyleManager | ||
|
[static]
지정된 구성 요소에서 스타일을 제거합니다.
| StyleManager | ||
|
[static]
문서의 모든 사용자 인터페이스 구성 요소에서 전역 스타일을 제거합니다.
| StyleManager | ||
|
[static]
특정 구성 요소에 적용된 스타일을 가져옵니다.
| StyleManager | ||
|
[static]
이름을 기준으로 전역 스타일을 가져옵니다.
| StyleManager | ||
 |
지정된 속성이 객체에 정의되어 있는지 여부를 나타냅니다.
| Object | |
|
Object 클래스의 인스턴스가 매개 변수로 지정된 객체의 프로토타입 체인에 있는지 여부를 나타냅니다.
| Object | |
|
지정된 속성이 존재하고 열거 가능한지 여부를 나타냅니다.
| Object | |
|
[static]
스타일 관리자를 사용하여 구성 요소 인스턴스를 등록합니다.
| StyleManager | ||
|
[static]
구성 요소 유형별 모든 인스턴스(예: Button 구성 요소의 모든 인스턴스, ComboBox 구성 요소의 모든 인스턴스 등)에 스타일을 설정합니다.
| StyleManager | ||
|
루프 작업에서 동적 속성을 사용할 수 있는지 여부를 설정합니다.
| Object | |
|
[static]
문서에서 모든 사용자 인터페이스 구성 요소에 전역 스타일을 설정합니다.
| StyleManager | ||
|
지정된 객체의 문자열 표현을 반환합니다.
| Object | |
|
지정된 객체의 프리미티브 값을 반환합니다.
| Object | |
| StyleManager | () | 생성자 |
상속되는 Public 속성 숨기기
상속되는 Public 속성 표시public function StyleManager()
| 언어 버전 : | ActionScript 3.0 |
| Player 버전 : | Flash Player 9.0.28.0 |
새 StyleManager 객체를 만듭니다.
| clearComponentStyle | () | 메서드 |
public static function clearComponentStyle(component:Object, name:String):void
| 언어 버전 : | ActionScript 3.0 |
| Player 버전 : | Flash Player 9.0.28.0 |
지정된 구성 요소에서 스타일을 제거합니다.
매개 변수
component:Object — 스타일을 제거할 구성 요소의 이름입니다.
|
|
name:String — 제거할 스타일의 이름입니다.
|
참고 사항
| clearStyle | () | 메서드 |
public static function clearStyle(name:String):void
| 언어 버전 : | ActionScript 3.0 |
| Player 버전 : | Flash Player 9.0.28.0 |
문서의 모든 사용자 인터페이스 구성 요소에서 전역 스타일을 제거합니다.
매개 변수
name:String — 제거할 전역 스타일의 이름입니다.
|
참고 사항
| getComponentStyle | () | 메서드 |
public static function getComponentStyle(component:Object, name:String):Object
| 언어 버전 : | ActionScript 3.0 |
| Player 버전 : | Flash Player 9.0.28.0 |
특정 구성 요소에 적용된 스타일을 가져옵니다.
매개 변수
component:Object — 요청된 스타일을 찾을 구성 요소 인스턴스의 이름입니다.
|
|
name:String — 검색할 스타일의 이름입니다.
|
Object — 지정된 구성 요소의 필수 스타일입니다. 이 함수는 지정된 스타일이 없으면 null을 반환합니다.
|
참고 사항
| getStyle | () | 메서드 |
public static function getStyle(name:String):Object
| 언어 버전 : | ActionScript 3.0 |
| Player 버전 : | Flash Player 9.0.28.0 |
이름을 기준으로 전역 스타일을 가져옵니다.
매개 변수
name:String — 검색할 스타일의 이름입니다.
|
Object — 검색한 전역 스타일의 값입니다.
|
참고 사항
| registerInstance | () | 메서드 |
public static function registerInstance(instance:UIComponent):void
| 언어 버전 : | ActionScript 3.0 |
| Player 버전 : | Flash Player 9.0.28.0 |
스타일 관리자를 사용하여 구성 요소 인스턴스를 등록합니다. 구성 요소 인스턴스를 인스턴스화하면 스타일 변경에 대한 알림을 받도록 스타일 관리자를 사용하여 등록할 수 있습니다. 스타일이 구성 요소별로 또는 전체적으로 변경되면 알림을 받도록 구성 요소 인스턴스를 등록할 수 있습니다.
매개 변수
instance:UIComponent — 스타일 관리를 위해 등록할 구성 요소 인스턴스입니다.
|
| setComponentStyle | () | 메서드 |
public static function setComponentStyle(component:Object, name:String, style:Object):void
| 언어 버전 : | ActionScript 3.0 |
| Player 버전 : | Flash Player 9.0.28.0 |
구성 요소 유형별 모든 인스턴스(예: Button 구성 요소의 모든 인스턴스, ComboBox 구성 요소의 모든 인스턴스 등)에 스타일을 설정합니다.
매개 변수
component:Object — Button 또는 ComboBox 등 구성 요소의 유형입니다. 이 매개 변수에는 구성 요소 유형의 모든 인스턴스를 식별하는 데 사용할 수 있는 구성 요소 인스턴스 또는 클래스도 사용할 수 있습니다.
|
|
name:String — 설정할 스타일의 이름입니다.
|
|
style:Object — 설정할 스타일을 설명하는 style 객체입니다.
|
참고 사항
| setStyle | () | 메서드 |
public static function setStyle(name:String, style:Object):void
| 언어 버전 : | ActionScript 3.0 |
| Player 버전 : | Flash Player 9.0.28.0 |
문서에서 모든 사용자 인터페이스 구성 요소에 전역 스타일을 설정합니다.
매개 변수
name:String — 설정할 스타일의 이름을 지정하는 String 값입니다.
|
|
style:Object — 설정할 style 객체입니다. 이 속성의 값은 사용자가 설정하는 스타일에 따라 달라집니다. 예를 들어 스타일을 "textFormat"으로 설정하면 style 속성은 TextFormat 객체로 설정되어야 합니다. 스타일 이름과 style 속성의 값이 일치하지 않으면 구성 요소가 잘못 동작할 수 있습니다.
|
참고 사항
예제를 실행하려면 다음 단계를 수행합니다.
package
{
import fl.controls.Button;
import fl.controls.DataGrid;
import fl.controls.Label;
import fl.controls.TextArea;
import fl.core.UIComponent;
import fl.managers.FocusManager;
import fl.managers.StyleManager;
import flash.display.InteractiveObject;
import flash.display.Sprite;
import flash.events.MouseEvent;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.text.TextFormat;
public class StyleManagerExample extends Sprite
{
private var btn:Button;
private var ta1:TextArea;
private var ta2:TextArea;
private var ta3:TextArea;
private var ta4:TextArea;
private var description:Label;
private var dg:DataGrid;
private var formatForInstance:TextFormat;
private var formatForGlobal:TextFormat;
private var testStringHTML:String = "<body><span class='heading'>Hello </span>World...</body>";
private var testString:String = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Fusce vitae turpis id nibh suscipit tincidunt. Quisque nulla dui, elementum eget, rutrum in, ultricies nec, erat. Donec ante turpis, lacinia eget, semper ac, consequat eget, neque. Maecenas eleifend pharetra quam. Quisque suscipit nibh a ipsum. Donec sit amet mi eu ligula volutpat imperdiet. Ut quis velit quis lectus laoreet eleifend. Aliquam pulvinar lorem. Cras ultrices felis sit amet urna. Cras viverra porttitor est. Nulla justo. Sed scelerisque."
public function StyleManagerExample() {
setupComponents();
setupUI();
setupStyles();
}
private function setupUI():void {
var setInstanceStyleBtn:Button = new Button();
var clearInstanceStyleBtn:Button = new Button();
var setClassStyleBtn:Button = new Button();
var clearClassStyleBtn:Button = new Button();
var setGlobalStyleBtn:Button = new Button();
var clearGlobalStyleBtn:Button = new Button();
setInstanceStyleBtn.label = "Set Instance Style";
clearInstanceStyleBtn.label = "Clear Instance Style";
setClassStyleBtn.label = "Set Class Style";
clearClassStyleBtn.label = "Clear Class Style";
setGlobalStyleBtn.label = "Set Global Style";
clearGlobalStyleBtn.label = "Clear Global Style";
setInstanceStyleBtn.focusEnabled = false;
clearInstanceStyleBtn.focusEnabled = false;
setClassStyleBtn.focusEnabled = false;
clearClassStyleBtn.focusEnabled = false;
setGlobalStyleBtn.focusEnabled = false;
clearGlobalStyleBtn.focusEnabled = false;
setInstanceStyleBtn.move(10,310);
clearInstanceStyleBtn.move(10,340);
setClassStyleBtn.move(140,310);
clearClassStyleBtn.move(140,340);
setGlobalStyleBtn.move(270,310);
clearGlobalStyleBtn.move(270,340);
setInstanceStyleBtn.setSize(120,24);
clearInstanceStyleBtn.setSize(120,24);
setClassStyleBtn.setSize(120,24);
clearClassStyleBtn.setSize(120,24);
setGlobalStyleBtn.setSize(120,24);
clearGlobalStyleBtn.setSize(120,24);
setInstanceStyleBtn.addEventListener(MouseEvent.CLICK,setInstanceStyle);
clearInstanceStyleBtn.addEventListener(MouseEvent.CLICK,clearInstanceStyle);
setClassStyleBtn.addEventListener(MouseEvent.CLICK,setClassStyle);
clearClassStyleBtn.addEventListener(MouseEvent.CLICK,clearClassStyle);
setGlobalStyleBtn.addEventListener(MouseEvent.CLICK,setGlobalStyle);
clearGlobalStyleBtn.addEventListener(MouseEvent.CLICK,clearGlobalStyle);
description = new Label();
description.move(10, 370);
description.autoSize = TextFieldAutoSize.LEFT;
description.text = "";
addChild(setInstanceStyleBtn);
addChild(clearInstanceStyleBtn);
addChild(setClassStyleBtn);
addChild(clearClassStyleBtn);
addChild(setGlobalStyleBtn);
addChild(clearGlobalStyleBtn);
addChild(description);
}
private function setupComponents():void {
dg = new DataGrid();
dg.addItem( { Name:"John Alpha", Number:"555-123-0101" } );
dg.addItem( { Name:"Mary Bravo", Number:"555-372-3322" } );
dg.addItem( { Name:"Trevor Gamma", Number:"555-485-1212" } );
dg.addItem( { Name:"Susan Delta", Number:"555-987-3434" } );
dg.move(10,10);
dg.setSize(200,290);
dg.columns = ["Name","Number"];
addChild(dg);
ta1 = new TextArea();
ta1.move(220,10);
ta1.setSize(150,140);
ta1.text = testString;
ta1.tabEnabled = true;
addChild(ta1);
ta2 = new TextArea();
ta2.move(380,10);
ta2.setSize(150,140);
ta2.text = testString;
ta2.tabEnabled = true;
addChild(ta2);
ta3 = new TextArea();
ta3.move(220,160);
ta3.setSize(150,140);
ta3.text = testString;
ta3.tabEnabled = true;
addChild(ta3);
ta4 = new TextArea();
ta4.move(380,160);
ta4.setSize(150,140);
ta4.text = testString;
ta4.tabEnabled = true;
addChild(ta4);
}
private function setupStyles():void {
formatForGlobal = new TextFormat();
formatForGlobal.font = "Georgia";
formatForGlobal.size = 10;
formatForInstance = new TextFormat();
formatForInstance.underline = true;
}
private function setInstanceStyle(e:MouseEvent):void {
var fm:FocusManager = new FocusManager(this);
var uiComponent:UIComponent = fm.getFocus() as UIComponent;
if(uiComponent is TextArea) {
uiComponent.setStyle("textFormat",formatForInstance);
description.text = "The TextArea object with focus is now underlined.";
}
}
private function clearInstanceStyle(e:MouseEvent):void {
var fm:FocusManager = new FocusManager(this);
var uiComponent:UIComponent = fm.getFocus() as UIComponent;
if(uiComponent is TextArea) {
uiComponent.clearStyle("textFormat");
description.text = "The TextArea object with focus is no longer underlined.";
}
}
private function setClassStyle(e:MouseEvent):void {
var c:Class = TextArea;
var styleName:String = "textPadding";
var value:Number = 10;
StyleManager.setComponentStyle(c,styleName,value);
description.text = "Padding for all TextArea instances is now 10.";
}
private function clearClassStyle(e:MouseEvent):void {
var styleName:String = "textPadding";
var c:Class = TextArea;
StyleManager.clearComponentStyle(c,styleName);
description.text = "TextArea padding has been reset to the default.";
}
private function setGlobalStyle(e:MouseEvent):void {
var styleName:String = "textFormat";
var value:Object = formatForGlobal;
StyleManager.setStyle(styleName,value);
description.text = "All components now use font Georgia size 10.";
}
private function clearGlobalStyle(e:MouseEvent):void {
var styleName:String = "textFormat";
StyleManager.clearStyle(styleName);
description.text = "Font style for all components has been cleared.";
}
}
}
이 페이지에 의견 추가되면 전자 메일 알림 받기 | 의견 보고서
현재 페이지: http://livedocs.adobe.com/flash/9.0_kr/ActionScriptLangRefV3/fl/managers/StyleManager.html