fl.events.DataGridEvent (ActionScript 3.0)

	속성	다음에 의해 정의됨
		bubbles : Boolean [read-only] 이벤트가 버블링 이벤트인지 여부를 나타냅니다.	Event
		cancelable : Boolean [read-only] 해당 이벤트와 연관된 비헤이비어를 차단할 수 있는지 여부를 나타냅니다.	Event
		columnIndex : int [read-only] 이 이벤트와 연관된 항목의 열 인덱스를 가져옵니다.	ListEvent
		constructor : Object 지정된 객체 인스턴스의 클래스 객체 또는 생성자 함수에 대한 참조입니다.	Object
		currentTarget : Object [read-only] 현재 이벤트 리스너를 통해 Event 객체를 처리하고 있는 객체입니다.	Event
		dataField : String 열과 연결된 데이터의 필드 또는 속성 이름을 가져오거나 설정합니다.	DataGridEvent
		eventPhase : uint [read-only] 이벤트 흐름에서 현재 단계입니다.	Event
		index : int [read-only] 렌더러가 포함된 셀의 인덱스(0부터 시작)를 가져옵니다.	ListEvent
		item : Object [read-only] 현재 셀 렌더러에 속한 데이터를 가져옵니다.	ListEvent
		itemRenderer : Object [read-only] 편집할 항목의 항목 렌더러 또는 클릭하거나 크기를 조절할 머리글 렌더러를 가져옵니다.	DataGridEvent
		prototype : Object [static] 클래스 또는 함수 객체의 프로토타입 객체에 대한 참조입니다.	Object
		reason : String [read-only] itemEditEnd 이벤트가 전달된 이유를 가져옵니다.	DataGridEvent
		rowIndex : Object [read-only] 이 이벤트와 연관된 항목의 행 인덱스를 가져옵니다.	ListEvent
		target : Object [read-only] 이벤트 대상입니다.	Event
		type : String [read-only] 이벤트 유형입니다.	Event

	메서드	다음에 의해 정의됨
		DataGridEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, columnIndex:int = -1, rowIndex:int = -1, itemRenderer:Object = null, dataField:String = null, reason:String = null) 지정된 매개 변수를 사용하여 새 DataGridEvent 객체를 만듭니다.	DataGridEvent
		clone():Event DataGridEvent 객체의 복사본을 만들고 각 속성의 값을 원본과 동일하게 설정합니다.	DataGridEvent
		formatToString(className:String, ... arguments):String 사용자 정의 Event 클래스에서 toString() 메서드를 구현하기 위한 유틸리티 함수입니다.	Event
		hasOwnProperty(name:String):Boolean 지정된 속성이 객체에 정의되어 있는지 여부를 나타냅니다.	Object
		isDefaultPrevented():Boolean 이벤트에서 preventDefault()가 호출되었는지 여부를 확인합니다.	Event
		isPrototypeOf(theClass:Object):Boolean Object 클래스의 인스턴스가 매개 변수로 지정된 객체의 프로토타입 체인에 있는지 여부를 나타냅니다.	Object
		preventDefault():void 이벤트의 기본 비헤이비어를 취소할 수 있는 경우, 그 비헤이비어를 취소합니다.	Event
		propertyIsEnumerable(name:String):Boolean 지정된 속성이 존재하고 열거 가능한지 여부를 나타냅니다.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 루프 작업에서 동적 속성을 사용할 수 있는지 여부를 설정합니다.	Object
		stopImmediatePropagation():void 이벤트 흐름에서 현재 노드 및 그 후속 노드에 있는 모든 이벤트 리스너가 처리되지 않도록 합니다.	Event
		stopPropagation():void 이벤트 흐름에서 현재 노드의 후속 노드에 있는 모든 이벤트 리스너가 처리되지 않도록 합니다.	Event
		toString():String DataGridEvent 객체의 속성이 모두 포함된 문자열을 반환합니다.	DataGridEvent
		valueOf():Object 지정된 객체의 프리미티브 값을 반환합니다.	Object

	상수	다음에 의해 정의됨
		ACTIVATE : String = "activate" [static] activate 이벤트 객체의 type 속성 값을 정의합니다.	Event
		ADDED : String = "added" [static] added 이벤트 객체의 type 속성 값을 정의합니다.	Event
		ADDED_TO_STAGE : String = "addedToStage" [static] addedToStage 이벤트 객체의 type 속성 값을 정의합니다.	Event
		CANCEL : String = "cancel" [static] cancel 이벤트 객체의 type 속성 값을 정의합니다.	Event
		CHANGE : String = "change" [static] change 이벤트 객체의 type 속성 값을 정의합니다.	Event
		CLOSE : String = "close" [static] close 이벤트 객체의 type 속성 값을 정의합니다.	Event
		COLUMN_STRETCH : String = "columnStretch" [static] DataGridEvent.COLUMN_STRETCH 상수는 columnStretch 이벤트 객체의 type 속성 값을 정의합니다.	DataGridEvent
		COMPLETE : String = "complete" [static] complete 이벤트 객체의 type 속성 값을 정의합니다.	Event
		CONNECT : String = "connect" [static] connect 이벤트 객체의 type 속성 값을 정의합니다.	Event
		DEACTIVATE : String = "deactivate" [static] deactivate 이벤트 객체의 type 속성 값을 정의합니다.	Event
		ENTER_FRAME : String = "enterFrame" [static] enterFrame 이벤트 객체의 type 속성 값을 정의합니다.	Event
		FULLSCREEN : String = "fullScreen" [static] fullScreen 이벤트 객체의 type 속성 값을 정의합니다.	Event
		HEADER_RELEASE : String = "headerRelease" [static] DataGridEvent.HEADER_RELEASE 상수는 headerRelease 이벤트 객체의 type 속성 값을 정의합니다.	DataGridEvent
		ID3 : String = "id3" [static] id3 이벤트 객체의 type 속성 값을 정의합니다.	Event
		INIT : String = "init" [static] init 이벤트 객체의 type 속성 값을 정의합니다.	Event
		ITEM_CLICK : String = "itemClick" [static] itemClick 이벤트 객체의 type 속성 값을 정의합니다.	ListEvent
		ITEM_DOUBLE_CLICK : String = "itemDoubleClick" [static] itemDoubleClick 이벤트 객체의 type 속성 값을 정의합니다.	ListEvent
		ITEM_EDIT_BEGIN : String = "itemEditBegin" [static] DataGridEvent.ITEM_EDIT_BEGIN 상수는 itemEditBegin 이벤트 객체의 type 속성 값을 정의합니다.	DataGridEvent
		ITEM_EDIT_BEGINNING : String = "itemEditBeginning" [static] DataGridEvent.ITEM__EDIT_BEGINNING 상수는 itemEditBeginning 이벤트 객체의 type 속성 값을 정의합니다.	DataGridEvent
		ITEM_EDIT_END : String = "itemEditEnd" [static] DataGridEvent.ITEM_EDIT_END 상수는 itemEditEnd 이벤트 객체의 type 속성 값을 정의합니다.	DataGridEvent
		ITEM_FOCUS_IN : String = "itemFocusIn" [static] DataGridEvent.ITEM_FOCUS_IN 상수는 itemFocusIn 이벤트 객체의 type 속성 값을 정의합니다.	DataGridEvent
		ITEM_FOCUS_OUT : String = "itemFocusOut" [static] DataGridEvent.ITEM_FOCUS_OUT 상수는 itemFocusOut 이벤트 객체의 type 속성 값을 정의합니다.	DataGridEvent
		ITEM_ROLL_OUT : String = "itemRollOut" [static] itemRollOut 이벤트 객체의 type 속성 값을 정의합니다.	ListEvent
		ITEM_ROLL_OVER : String = "itemRollOver" [static] itemRollOver 이벤트 객체의 type 속성 값을 정의합니다.	ListEvent
		MOUSE_LEAVE : String = "mouseLeave" [static] mouseLeave 이벤트 객체의 type 속성 값을 정의합니다.	Event
		OPEN : String = "open" [static] open 이벤트 객체의 type 속성 값을 정의합니다.	Event
		REMOVED : String = "removed" [static] removed 이벤트 객체의 type 속성 값을 정의합니다.	Event
		REMOVED_FROM_STAGE : String = "removedFromStage" [static] removedFromStage 이벤트 객체의 type 속성 값을 정의합니다.	Event
		RENDER : String = "render" [static] render 이벤트 객체의 type 속성 값을 정의합니다.	Event
		RESIZE : String = "resize" [static] resize 이벤트 객체의 type 속성 값을 정의합니다.	Event
		SCROLL : String = "scroll" [static] scroll 이벤트 객체의 type 속성 값을 정의합니다.	Event
		SELECT : String = "select" [static] select 이벤트 객체의 type 속성 값을 정의합니다.	Event
		SOUND_COMPLETE : String = "soundComplete" [static] soundComplete 이벤트 객체의 type 속성 값을 정의합니다.	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] tabChildrenChange 이벤트 객체의 type 속성 값을 정의합니다.	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] tabEnabledChange 이벤트 객체의 type 속성 값을 정의합니다.	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [static] tabIndexChange 이벤트 객체의 type 속성 값을 정의합니다.	Event
		UNLOAD : String = "unload" [static] unload 이벤트 객체의 type 속성 값을 정의합니다.	Event

속성 정보

dataField

속성

dataField:String [read-write]

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

열과 연결된 데이터의 필드 또는 속성 이름을 가져오거나 설정합니다.

구현
public function get dataField():String
public function set dataField(value:String):void

itemRenderer

속성

itemRenderer:Object [read-only]

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

편집할 항목의 항목 렌더러 또는 클릭하거나 크기를 조절할 머리글 렌더러를 가져옵니다.

구현
public function get itemRenderer():Object

reason

속성

reason:String [read-only]

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

itemEditEnd 이벤트가 전달된 이유를 가져옵니다. 이 속성은 DataGridEvent.ITEM_EDIT_END 유형의 이벤트에만 유효합니다.

사용 가능한 값은 DataGridEventReason 클래스에 정의되어 있습니다.

구현
public function get reason():String

참고 사항

fl.controls.DataGrid.itemEditEnd
DataGridEventReason

생성자 정보

DataGridEvent

()

생성자

public function DataGridEvent(type:String, bubbles:Boolean = false, cancelable:Boolean = false, columnIndex:int = -1, rowIndex:int = -1, itemRenderer:Object = null, dataField:String = null, reason:String = null)

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

지정된 매개 변수를 사용하여 새 DataGridEvent 객체를 만듭니다.

매개 변수

	`type:String` — 이벤트 유형으로, 이 값은 이 이벤트를 유발하는 액션을 나타냅니다.

	`bubbles:Boolean` (default = `false`) — 이벤트가 표시 목록 계층을 버블링할 수 있는지 여부를 나타냅니다.

	`cancelable:Boolean` (default = `false`) — 해당 이벤트와 연관된 비헤이비어를 차단할 수 있는지 여부를 나타냅니다.

	`columnIndex:int` (default = `-1`) — 렌더러가 포함된 열의 인덱스(0부터 시작)입니다.

	`rowIndex:int` (default = `-1`) — 렌더러가 포함된 행의 인덱스(0부터 시작)입니다.

	`itemRenderer:Object` (default = `null`) — 편집 중인 항목에 사용되는 항목 렌더러 또는 클릭하거나 확장 중인 머리글 렌더러입니다.

	`dataField:String` (default = `null`) — 열과 연관된 데이터의 필드 이름 또는 속성 이름입니다.

	`reason:String` (default = `null`) — `itemEditEnd` 이벤트가 전달된 이유입니다.

참고 사항

DataGridEventReason

메서드 정보

clone

()

메서드

public override function clone():Event

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

DataGridEvent 객체의 복사본을 만들고 각 속성의 값을 원본과 동일하게 설정합니다.

반환값

Event — 원본과 매개 변수 값이 동일한 새 DataGridEvent 객체입니다.

toString

()

메서드

public override function toString():String

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

DataGridEvent 객체의 속성이 모두 포함된 문자열을 반환합니다. 문자열의 형식은 다음과 같습니다.

[ DataGridEvent type= value bubbles= value cancelable= value columnIndex= value rowIndex= value itemRenderer= value dataField= value reason= value ]

반환값

String — DataGridEvent 객체의 속성이 모두 포함된 문자열입니다.

상수 정보

COLUMN_STRETCH

상수

public static const COLUMN_STRETCH:String = "columnStretch"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

DataGridEvent.COLUMN_STRETCH 상수는 columnStretch 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`columnIndex`	DataGrid 객체의 `columns` 배열에 있는 머리글 열의 인덱스(0부터 시작)입니다.
`currentTarget`	이벤트 리스너를 통해 이벤트 객체를 처리하고 있는 객체입니다.
`dataField`	항목의 열과 연관된 데이터의 필드 이름 또는 속성 이름입니다.
`itemRenderer`	확장된 열의 머리글 렌더러입니다.
`reason`	`null`
`rowIndex`	데이터 공급자에 있는 항목의 인덱스(0부터 시작)입니다.
`target`	이벤트를 전달한 객체입니다. 이벤트를 수신하는 객체와는 다를 수도 있습니다. 이벤트를 수신하는 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

예제

다음 예제에서는 DataGrid 구성 요소를 만들고 해당 columnStretch 이벤트를 수신합니다.


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);

function columnStretchHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    var column:DataGridColumn;
    var columnArray:Array = dg.columns;
    var dgColWidth:String;
    trace("resized column:", event.dataField);
    trace("columnIndex:", event.columnIndex);
    for each (column in columnArray) {
        dgColWidth = Number(column.width / dg.width * 100).toFixed(1);
        trace(column.dataField + ".width:", column.width + " pixels (" + dgColWidth + "%)");
    }
    trace("----------");
}

HEADER_RELEASE

상수

public static const HEADER_RELEASE:String = "headerRelease"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

DataGridEvent.HEADER_RELEASE 상수는 headerRelease 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`columnIndex`	DataGrid 객체의 `columns` 배열에 있는 머리글 열의 인덱스(0부터 시작)입니다.
`currentTarget`	이벤트 리스너를 통해 이벤트 객체를 처리하고 있는 객체입니다.
`dataField`	항목의 열과 연관된 데이터의 필드 이름 또는 속성 이름입니다.
`itemRenderer`	클릭한 머리글 렌더러입니다.
`reason`	`null`
`rowIndex`	`-1`
`target`	이벤트를 전달한 객체입니다. 이벤트를 수신하는 객체와는 다를 수도 있습니다. 이벤트를 수신하는 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

예제

다음 예제에서는 DataGrid 구성 요소 인스턴스를 만들고 해당 headerRelease 이벤트를 수신합니다.


import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;

var dp:DataProvider = new DataProvider();
dp.addItem({col1:"item 1.A", col2:"item 1.B", col3:"item 1.C"});
dp.addItem({col1:"item 2.A", col2:"item 2.B", col3:"item 2.C"});
dp.addItem({col1:"item 3.A", col2:"item 3.B", col3:"item 3.C"});
dp.addItem({col1:"item 4.A", col2:"item 4.B", col3:"item 4.C"});

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn("col1");
myDataGrid.addColumn("col2");
myDataGrid.addColumn("col3");
myDataGrid.dataProvider = dp;
myDataGrid.setSize(300, 200);
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);

function headerReleaseHandler(event:DataGridEvent):void {
    var dg:DataGrid = event.target as DataGrid;
    trace("dataField:", event.dataField, "(columnIndex:" + event.columnIndex + ")");
    trace("sortIndex:", dg.sortIndex);
    trace("sortDescending:", dg.sortDescending);
    trace("----------");
}

ITEM_EDIT_BEGIN

상수

public static const ITEM_EDIT_BEGIN:String = "itemEditBegin"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

DataGridEvent.ITEM_EDIT_BEGIN 상수는 itemEditBegin 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`columnIndex`	DataGrid 객체의 `columns` 배열에 있는 머리글 열의 인덱스(0부터 시작)입니다.
`currentTarget`	이벤트 리스너를 통해 이벤트 객체를 처리하고 있는 객체입니다.
`dataField`	`null`
`itemRenderer`	편집할 항목의 항목 렌더러입니다.
`reason`	`null`
`rowIndex`	데이터 공급자에 있는 항목의 인덱스(0부터 시작)입니다.
`target`	이벤트를 전달한 객체입니다. 이벤트를 수신하는 객체와는 다를 수도 있습니다. 이벤트를 수신하는 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

ITEM_EDIT_BEGINNING
ITEM_EDIT_END

ITEM_EDIT_BEGINNING

상수

public static const ITEM_EDIT_BEGINNING:String = "itemEditBeginning"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

DataGridEvent.ITEM__EDIT_BEGINNING 상수는 itemEditBeginning 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`columnIndex`	DataGrid 객체의 `columns` 배열에 있는 머리글 열의 인덱스(0부터 시작)입니다.
`currentTarget`	이벤트 리스너를 통해 이벤트 객체를 처리하고 있는 객체입니다.
`dataField`	항목의 열과 연관된 데이터의 필드 이름 또는 속성 이름입니다.
`itemRenderer`	편집할 항목의 항목 렌더러입니다.
`reason`	`null`
`rowIndex`	데이터 공급자에 있는 항목의 인덱스(0부터 시작)입니다.
`target`	이벤트를 전달한 객체입니다. 이벤트를 수신하는 객체와는 다를 수도 있습니다. 이벤트를 수신하는 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

ITEM_EDIT_BEGIN
ITEM_EDIT_END

ITEM_EDIT_END

상수

public static const ITEM_EDIT_END:String = "itemEditEnd"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

DataGridEvent.ITEM_EDIT_END 상수는 itemEditEnd 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`columnIndex`	DataGrid 객체의 `columns` 배열에 있는 머리글 열의 인덱스(0부터 시작)입니다.
`currentTarget`	이벤트 리스너를 통해 이벤트 객체를 처리하고 있는 객체입니다.
`dataField`	항목의 열과 연관된 데이터의 필드 이름 또는 속성 이름입니다.
`itemRenderer`	편집할 항목의 항목 렌더러입니다.
`reason`	이벤트의 이유를 정의하는 상수입니다. 값은 `DataGridEventReason` 클래스의 멤버여야 합니다.
`rowIndex`	데이터 공급자에 있는 항목의 인덱스(0부터 시작)입니다.
`target`	이벤트를 전달한 객체입니다. 이벤트를 수신하는 객체와는 다를 수도 있습니다. 이벤트를 수신하는 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

ITEM_EDIT_BEGIN
ITEM_EDIT_BEGINNING

ITEM_FOCUS_IN

상수

public static const ITEM_FOCUS_IN:String = "itemFocusIn"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

DataGridEvent.ITEM_FOCUS_IN 상수는 itemFocusIn 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`columnIndex`	DataGrid 객체의 `columns` 배열에 있는 머리글 열의 인덱스(0부터 시작)입니다.
`currentTarget`	이벤트 리스너를 통해 이벤트 객체를 처리하고 있는 객체입니다.
`dataField`	`null`
`itemRenderer`	편집할 항목의 항목 렌더러입니다.
`reason`	`null`
`rowIndex`	데이터 공급자에 있는 항목의 인덱스(0부터 시작)입니다.
`target`	이벤트를 전달한 객체입니다. 이벤트를 수신하는 객체와는 다를 수도 있습니다. 이벤트를 수신하는 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

ITEM_FOCUS_OUT

상수

public static const ITEM_FOCUS_OUT:String = "itemFocusOut"

언어 버전 :

ActionScript 3.0

Player 버전 :

Flash Player 9.0.28.0

DataGridEvent.ITEM_FOCUS_OUT 상수는 itemFocusOut 이벤트 객체의 type 속성 값을 정의합니다.

이 이벤트에는 다음과 같은 속성이 있습니다.

속성	값
`bubbles`	`false`
`cancelable`	`false`; 취소할 기본 비헤이비어가 없습니다.
`columnIndex`	DataGrid 객체의 `columns` 배열에 있는 머리글 열의 인덱스(0부터 시작)입니다.
`currentTarget`	이벤트 리스너를 통해 이벤트 객체를 처리하고 있는 객체입니다.
`dataField`	`null`
`itemRenderer`	편집할 항목의 항목 렌더러입니다.
`reason`	`null`
`rowIndex`	데이터 공급자에 있는 항목의 인덱스(0부터 시작)입니다.
`target`	이벤트를 전달한 객체입니다. 이벤트를 수신하는 객체와는 다를 수도 있습니다. 이벤트를 수신하는 객체에 액세스하려면 `currentTarget` 속성을 사용합니다.

참고 사항

ITEM_FOCUS_IN

예제 예제 사용 방법

DataGridEventExample.as

이 예제에서는 DataGrid에서 전달된 이벤트에 응답하는 방법을 보여 줍니다.

예제를 실행하려면 다음 단계를 수행합니다.

DataGrid 구성 요소를 라이브러리에 추가합니다.
이 코드를 FLA 파일과 같은 디렉토리에 DataGridEventExample.as로 저장합니다.
FLA 파일의 Document 클래스를 DataGridEventExample로 설정합니다.

package
{
    import fl.controls.DataGrid;
    import fl.data.DataProvider;
    import fl.events.DataGridEvent;
    import fl.events.DataGridEventReason;
    import flash.display.Sprite;
    
    public class DataGridEventExample extends Sprite
    {
        private var dg:DataGrid;
        
        public function DataGridEventExample() {
            createDataGrid();
        }
        private function createDataGrid():void {
            dg = new DataGrid();
            addChild(dg);
            dg.setSize(200,300);
            dg.editable = true;
            
            var dp:DataProvider = new DataProvider();
            var i:uint;
            var totalRows:uint = 42;
            for(i=0; i<totalRows; i++) {
                dp.addItem( {     col1:getRandomNumber(),
                                   col2:getRandomNumber(),
                                col3:getRandomNumber() } );
            }
            dg.dataProvider = dp;
            dg.addEventListener(DataGridEvent.ITEM_EDIT_BEGIN, announceEditBegin);
            dg.addEventListener(DataGridEvent.ITEM_EDIT_END, announceEditEnd);
        }
        private function announceEditBegin(e:DataGridEvent):void {
            trace("Edit Begin on row: " + e.rowIndex + " col: " + e.columnIndex);    
        }
        private function announceEditEnd(e:DataGridEvent):void {
            var reason:String;
            switch(e.reason) {
                case DataGridEventReason.CANCELLED:
                    reason = "User cancelled edit";
                    break;
                case DataGridEventReason.NEW_ROW:
                    reason = "User focused to another row";
                    break;
                case DataGridEventReason.NEW_COLUMN:
                    reason = "User focused to another column";
                    break;
                case DataGridEventReason.OTHER:
                default:
                    reason = "Edit ended for other reason";
                    reason = e.reason;
                    break;                
            }
            trace("Edit End on row: " + e.rowIndex + " col: " + e.columnIndex);
            trace("Reason: " + reason.toString());    
        }
        private function getRandomNumber():uint {
            return Math.round(Math.random()*100);
        }
    }
}

현재 페이지: http://livedocs.adobe.com/flash/9.0_kr/ActionScriptLangRefV3/fl/events/DataGridEvent.html

ActionScript 3.0 언어 및 구성 요소 참조 설명서		모든 패키지 \| 모든 클래스 \| 언어 요소 \| 색인 \| 부록 \| 규칙 \| 프레임 비프레임
DataGridEvent	속성 \| 메서드 \| 상수 \| 예제

패키지	fl.events
클래스	public class DataGridEvent
상속	DataGridEvent ListEvent Event Object