FLVPlayback.visibleVideoPlayerIndex

my_FLVPlybk.visibleVideoPlayerIndex

説明

プロパティ。複数の FLV ファイルストリームを管理するのに使用する数値です。可視および可聴にするビデオプレーヤーインスタンスと、スキンまたは再生コントロールによって制御されるビデオプレーヤーインスタンスを設定します。他のビデオプレーヤーは非表示でミュートになります。デフォルトは 0 です。多数の API でビデオプレーヤーをターゲットにしないでください。代わりに、activeVideoPlayerIndex プロパティを使用します。

サイズを制御するメソッドとプロパティでは、このプロパティを使用します。ビデオプレーヤーのサイズを設定するメソッドとプロパティ (setScale()、setSize()、width、height、scaleX、scaleY) は、すべてのビデオプレーヤーに使用できます。ただし、ビデオプレーヤーで autoSize または maintaintAspectRatio が設定されているかどうかによって、サイズが異なる場合があります。width、height、scaleX、scaleY の各プロパティを使用してサイズを読み取ると、可視のビデオプレーヤーのサイズだけが取得できます。他のビデオプレーヤーのサイズが同じである場合もあれば、異なる場合もあります。

非表示のビデオプレーヤーのサイズを取得するには、resize イベントをリスンし、サイズ値を保存します。

このプロパティは、コンポーネントの可視性には影響しません。コンポーネントが可視である場合に、どのビデオプレーヤーを可視にするかを設定するだけです。コンポーネント全体の可視性を設定するには、visible プロパティを使用します。

例

次の例では、1 つの FLVPlayback インスタンスで 2 つの FLV ファイルを連続して再生する 2 つのビデオプレーヤーを作成します。ビデオプレーヤーと FLV ファイルを切り替えるように visibleVideoPlayerIndex プロパティを設定します。

FLVPlayback コンポーネントをステージにドラッグし、インスタンス名を my_FLVPlybk にします。続いて、次のコードをタイムラインのフレーム 1 の [アクション] パネルに追加します。

/**
 必須 :
  - my_FLVPlybk というインスタンス名の FLVPlayback コンポーネントがステージ上にあること
*/
import mx.video.*;
// デフォルトプレーヤー用の FLV の名前と場所を指定する
my_FLVPlybk.contentPath = "http://www.helpexamples.com/flash/video/clouds.flv"
var listenerObject:Object = new Object();
listenerObject.ready = function(eventObject:Object):Void {
    // 2 番目のビデオプレーヤーを追加し、その FLV の名前と場所を指定する
    my_FLVPlybk.activeVideoPlayerIndex = 1;
    my_FLVPlybk.contentPath = "http://www.helpexamples.com/flash/video/water.flv";
    // デフォルトビデオプレーヤーにリセットし、FLV を自動的に再生する
    my_FLVPlybk.activeVideoPlayerIndex = 0;
};
my_FLVPlybk.addEventListener("ready", listenerObject);
listenerObject.complete = function(eventObject:Object):Void {
    // complete の対象が 2 番目の FLV である場合、デフォルトをアクティブにし、表示する
    if (eventObject.vp == 1) {
        my_FLVPlybk.activeVideoPlayerIndex = 0;
        my_FLVPlybk.visibleVideoPlayerIndex = 0;
    } else { // 2 番目のプレーヤーをアクティブにし、表示し、FLV を再生する
        my_FLVPlybk.activeVideoPlayerIndex = 1;
        my_FLVPlybk.visibleVideoPlayerIndex = 1;
        my_FLVPlybk.play();
    }
};
// complete イベントのリスナーを追加する
my_FLVPlybk.addEventListener("complete", listenerObject);

FLVPlayback.visibleVideoPlayerIndex

使用できるバージョン

エディション

シンタックス

説明

例

関連項目