FLVPlayback.findNextCuePointWithName()

my_FLVplybk.findNextCuePointWithName(my_cuePoint:Object)

パラメータ

my_cuePoint findCuePoint() メソッド、findNearestCuePoint() メソッド、またはこのメソッドの前回の呼び出しによって返されたキューポイントオブジェクト。

戻り値

見つかったキューポイントオブジェクトのコピーであるオブジェクト。次に示すプロパティも返します。

array 検索されたキューポイントの配列。この配列内でオブジェクトを追加、削除、編集するとキューポイントが正常に動作しないので、この配列は読み取り専用として扱う必要があります。

説明

メソッド。my_cuePoint.array で、my_cuePoint.name と同じ名前を持つ次のキューポイントを検索します。my_cuePoint オブジェクトは、findCuePoint() メソッド、findNearestCuePoint() メソッド、またはこのメソッドの前回の呼び出しによって返されたキューポイントオブジェクトである必要があります。このメソッドは、これらのメソッドがキューポイントオブジェクトに追加する array プロパティを使用します。

検索には無効にされているキューポイントも含まれます。キューポイントが無効であるかどうかを判断するには、isFLVCuePointEnabled() メソッドを使用します。

一致する名前のキューポイントが配列内にそれ以上なくなると、null を返します。

例

次の例では、名前が "transition" である 3 つの ActionScript キューポイントを作成します。ready イベントが発生すると、イベントハンドラは findCuePoint() メソッドを呼び出して、この名前を持つ最初のキューポイントを検索します。一致した場合は、findNextName() 関数を呼び出します。この関数は findNextCuePointWithName() メソッドを呼び出し、返されたキューポイントオブジェクト (rtn_obj) を渡して、同じ名前の追加のキューポイントを検索します。

FLVPlayback コンポーネントをステージにドラッグし、インスタンス名を my_FLVPlybk にします。続いて、次のコードをタイムラインのフレーム 1 の [アクション] パネルに追加します。

/**
 必須 :
  - my_FLVPlybk というインスタンス名の FLVPlayback コンポーネントがステージ上にあること
*/
import mx.video.*;
my_FLVPlybk.contentPath = "http://www.helpexamples.com/flash/video/cuepoints.flv";
var cuePt:Object = new Object(); // キューポイントオブジェクトを作成する
cuePt.time = 6.27;
cuePt.name = "transition";
cuePt.type = "actionscript";
my_FLVPlybk.addASCuePoint(cuePt);  // AS キューポイントを追加する
cuePt.time = 7.06;
my_FLVPlybk.addASCuePoint(cuePt);  // AS キューポイントを追加する
cuePt.time = 11.13;
my_FLVPlybk.addASCuePoint(cuePt);  // AS キューポイントを追加する
var listenerObject:Object = new Object();
listenerObject.ready = function():Void {        
    var rtn_obj:Object = new Object();
// 名前ストリングを使用してキューポイントを検索する
    if (rtn_obj = my_FLVPlybk.findCuePoint("transition")) {
        trace("Cue point name is: " + rtn_obj.name);
        trace("Cue point time is: " + rtn_obj.time);
        trace("Cue point type is: " + rtn_obj.type);
        findNextName(rtn_obj);
    }
}
my_FLVPlybk.addEventListener("ready", listenerObject);
// 同じ名前の追加のキューポイントを検索する
function findNextName(cuePt:Object):Void {
    while(cuePt = my_FLVPlybk.findNextCuePointWithName(cuePt)) {
            trace("Cue point name is: " + cuePt.name);
            trace("Cue point time is: " + cuePt.time);
            trace("Cue point type is: " + cuePt.type);
    }
}

FLVPlayback.findNextCuePointWithName()

使用できるバージョン

エディション

シンタックス

パラメータ

戻り値

説明

例

関連項目