FLVPlayback.findCuePoint()

my_FLVplybk.findCuePoint(time:Number[, type:String]):Object
my_FLVplybk.findCuePoint(name:String[, type:String]):Object
my_FLVplybk.findCuePoint(cuePoint:Object[, type:String]):Object

パラメータ

time 検索するキューポイントの時間を秒単位で示す数値。小数点以下 3 桁まで使用され、それ以下の桁を指定した場合は四捨五入されます。この時間に一致するキューポイントを返します。複数の ActionScript キューポイントの時間が同じである場合は、アルファベット順で最初のキューポイントの名前のみを返します。一致しなかった場合は null を返します。

name 検索するキューポイントの名前を表すストリング。この名前に一致する最初のキューポイントを返します。一致しなかった場合は null を返します。

cuePoint 検索対象の time プロパティおよび name プロパティを含むキューポイントオブジェクト。name プロパティに値を指定しないか null を指定した場合、パラメータは検索対象の時間を表す数値であるものとして検索が実行されます。time プロパティに値を指定しないか null または負の値を指定した場合、パラメータは検索対象の名前を含むストリングであるものとして検索が実行されます。time および name の両方のプロパティを指定した場合、それらの値に一致するキューポイントが存在すれば、一致するキューポイントを返します。それ以外の場合は、null を返します。

type オプション。検索するキューポイントのタイプを示すストリング。このパラメータに指定できる値は、"actionscript"、"all"、"event"、"flv"、または "navigation" です。これらの値は、FLVPlayback.ACTIONSCRIPT、FLVPlayback.ALL、FLVPlayback.EVENT、FLVPlayback.FLV、FLVPlayback.NAVIGATION の各クラスプロパティを使用して指定できます。このパラメータを指定しない場合のデフォルトは "all" で、すべてのキューポイントタイプを検索することを意味します。

戻り値

見つかったキューポイントオブジェクトのコピーであるオブジェクト。次に示すプロパティも返します。

array 検索されたキューポイントの配列。この配列内でオブジェクトを追加、削除、編集するとキューポイントが正常に動作しないので、この配列は読み取り専用として扱う必要があります。

説明

メソッド。type パラメータで指定されたタイプで、パラメータで指定した時間、名前、または時間と名前の組み合わせを持つキューポイントを検索します。

キューポイントの時間または名前の値を指定しない場合、または時間が null、undefined、あるいは負の値で、かつ名前が null または undefined の場合は、VideoError エラー 1002 をスローします。詳細については、VideoError クラスを参照してください。

検索には無効にされているキューポイントも含まれます。キューポイントが無効であるかどうかを判断するには、isFLVCuePointEnabled() メソッドを使用します。

例

次の例では、FLV ファイルに 2 つの ActionScript キューポイントを追加し、findCuePoint() メソッドを 3 回呼び出します。最初の呼び出しでは、時間が 7.748 であるナビゲーションキューポイントを検索します。2 回目の呼び出しでは、名前の値のみを使用してキューポイント "ASCue1" を検索します。3 回目の呼び出しでは、時間 10、および名前 "ASCue2" のキューポイントを使用します。3 回目の呼び出しの後に、返されたキューポイントオブジェクトのコンテンツを表示します。これには、検索されたキューポイントの配列も含まれますが、この例では ActionScript キューポイントになります。

FLVPlayback コンポーネントをステージにドラッグし、インスタンス名を my_FLVPlybk にします。続いて、次のコードをタイムラインのフレーム 1 の [アクション] パネルに追加します。

/**
 必須 :
  - my_FLVPlybk というインスタンス名の FLVPlayback コンポーネントがステージ上にあること
*/
// キューポイントオブジェクトを作成する
import mx.video.*;
my_FLVPlybk.contentPath = "http://www.helpexamples.com/flash/video/cuepoints.flv";
var cuePt:Object = new Object(); 
var rtn_cuePt:Object = new Object(); // 戻り値のオブジェクトを作成する
cuePt.time = 4.444;
cuePt.name = "AScue1";
my_FLVPlybk.addASCuePoint(cuePt);  // AS キューポイントを追加する
// time パラメータと name パラメータを使用して 2 番目の AS キューポイントを追加する
my_FLVPlybk.addASCuePoint(10, "AScue2");
// 時間を使用してナビゲーションキューポイントを検索する
rtn_cuePt = my_FLVPlybk.findCuePoint(7.748, FLVPlayback.NAVIGATION);
// 名前のみを使用して actionscript キューポイントを検索する
rtn_cuePt = my_FLVPlybk.findCuePoint("AScue1");
// キューポイントオブジェクトを使用して actionscript キューポイントを検索する
cuePt.time = 10;
cuePt.name = "AScue2";
rtn_cuePt = my_FLVPlybk.findCuePoint(cuePt, FLVPlayback.ACTIONSCRIPT);
// 返されたキューポイントオブジェクトのコンテンツを表示する
for (i in rtn_cuePt) {
    // 配列オブジェクトの場合は、開いてコンテンツをトレースする
    if (typeof rtn_cuePt[i] == "object") {
        tracer(rtn_cuePt[i]);
    // それ以外の場合は名前 (i) と値 (rtn_cuePt[i]) のペアをトレースする
    } else {
        trace(i+ " " + rtn_cuePt[i]);
    }
}
// キューポイントの配列をトレースする
function tracer(cuepts:Array) {
    for (i in cuepts) {
        if (typeof cuepts[i] == "object") { // オブジェクト内にオブジェクトがある場合
            tracer(cuepts[i]); // オブジェクトをトレースする
        } else {
            // 名前と値のペアをトレースする
            trace(i + " " + cuepts[i]);
        }
    }
}

FLVPlayback.findCuePoint()

使用できるバージョン

エディション

シンタックス

パラメータ

戻り値

説明

例

関連項目