FLVPlayback.bringVideoPlayerToFront()

my_FLVPlybk.bringVideoPlayerToFront(index:Number)

パラメータ

index 前面に移動するビデオプレーヤーのインデックスを示す数値。

説明

メソッド。ビデオプレーヤーをビデオプレーヤーのスタックの一番上に移動します。ビデオプレーヤー間のカスタムトランジションに便利です。重ね順は、activeVideoPlayerIndex プロパティの場合と同じです。つまり、0 が一番下、1 がその上、2 が 1 の上、のようになります。

例

次の例では、2 つのビデオプレーヤーを使用して 2 つの FLV ファイルを再生します。最初の FLV ファイル (cuepoints.flv) でこれら 3 つの各キューポイントが発生すると、bringVideoPlayerToFront() メソッドを呼び出して、もう 1 つの FLV ファイルを最前面に移動します。この例では、ビデオプレーヤー 1 に対して _alpha プロパティに 75 を設定するので、そのプレーヤーで再生される FLV ファイル (plane_cuepoints) は透明になり、FLV ファイルが最前面にあるときは、両方の FLV ファイルが同時に表示されます。

FLVPlayback コンポーネントをステージにドラッグし、インスタンス名を my_FLVPlybk にします。続いて、次のコードをタイムラインのフレーム 1 の [アクション] パネルに追加します。

/**
 必須 :
  - my_FLVPlybk というインスタンス名の FLVPlayback コンポーネントがステージ上にあること
*/
my_FLVPlybk.load("http://www.helpexamples.com/flash/video/cuepoints.flv");
var listenerObject:Object = new Object();
listenerObject.ready = function(eventObject:Object) {
    if (eventObject.target.contentPath == "http://www.helpexamples.com/flash/video/cuepoints.flv") {
        // 最初の flv の準備ができた後にこれが発生する
        my_FLVPlybk.activeVideoPlayerIndex = 1;
        my_FLVPlybk.load("http://www.helpexamples.com/flash/video/plane_cuepoints.flv");
    } else {
        // 2 番目の flv の準備ができた後にこれが発生する
        eventObject.target.activeVideoPlayerIndex = 0;
        eventObject.target.play();
        eventObject.target.activeVideoPlayerIndex = 1;
        eventObject.target.play();
        var layerOnTop:MovieClip = eventObject.target.getVideoPlayer(1);
        layerOnTop._alpha = 75;
        layerOnTop._visible = true;
    }
}
my_FLVPlybk.addEventListener("ready", listenerObject);

var listenerObject:Object = new Object();
listenerObject.cuePoint = function(eventObject:Object) {
    
    // キュー名に基づいて、1 つまたはもう 1 つを最前面に移動する
    if (eventObject.info.name == "point1") {
        trace(eventObject.info.name + " : 0 to front");
        eventObject.target.bringVideoPlayerToFront(1);
    } else if (eventObject.info.name == "point2") {
        trace(eventObject.info.name + " : 1 to front");
        eventObject.target.bringVideoPlayerToFront(0);
    }else if (eventObject.info.name == "point3") {
        trace(eventObject.info.name + " : 0 to front");
        eventObject.target.bringVideoPlayerToFront(1);
    }
}
my_FLVPlybk.addEventListener("cuePoint", listenerObject);

FLVPlayback.bringVideoPlayerToFront()

使用できるバージョン

エディション

シンタックス

パラメータ

説明

例

関連項目