FLVPlayback.addASCuePoint()

my_FLVplybk.addASCuePoint(cuePoint:Object)
my_FLVplybk.addASCuePoint(time:Number, name:String[, parameters:Object])

パラメータ

cuePoint キューポイントを指定するための name:String プロパティと time:Number (秒単位) プロパティを持つオブジェクト。名前と値のペアを含む parameters:Object プロパティを持つ場合もあります。type:String には "actionscript" を設定できます。type が指定されていない場合、または他の値に設定されている場合は、自動的に設定されます。これらの規則にオブジェクトが準拠していない場合は、VideoError がスローされます。

time 新規キューポイントを追加する時間を示す数値。time パラメータを使用する場合は、続いて name パラメータも指定する必要があります。

name CuePoint オブジェクトの代わりに time パラメータを送信する場合に、キューポイントの名前を指定するストリング。

戻り値

次の追加のプロパティと共に追加された、キューポイントオブジェクトのコピー。

説明

メソッド。ActionScript キューポイントを追加します。また、[キューポイント] ダイアログボックスを使用して ActionScript キューポイントを追加するのと同じ効果があります。ただし、アプリケーション開発中ではなく、アプリケーションの実行時に発生します。

contentPath プロパティが設定されると、キューポイント情報が削除されます。次にロードする FLV ファイルのキューポイント情報を設定するには、最初に contentPath プロパティを設定します。

名前と時間が同じである複数の ActionScript キューポイントを追加することができます。removeASCuePoint() メソッド内で ActionScript キューポイントを削除すると、名前と時間が同じであるすべてのキューポイントが削除されます。

例

次の例では、2 つの ActionScript キューポイントを FLV ファイルに追加します。最初のキューポイントは CuePoint パラメータを使用して追加し、2 番目のキューポイントは time パラメータと name パラメータを使用して追加します。再生中にキューポイントが発生すると、cuePoint イベントのリスナーにより playheadTime プロパティの値がテキスト領域に表示されます。

FLVPlayback コンポーネントをステージにドラッグし、インスタンス名を my_FLVPlybk にします。TextArea コンポーネントを FLVPlayback インスタンスの下のステージまでドラッグし、インスタンス名を my_ta にします。続いて、次のコードをタイムラインのフレーム 1 の [アクション] パネルに追加します。

/**
 必須 :
  - my_FLVPlybk というインスタンス名の FLVPlayback コンポーネントがステージ上にあること
  - my_ta というインスタンス名の TextArea コンポーネントがステージ上にあること
*/
import mx.video.*;
my_FLVPlybk.contentPath = "http://www.helpexamples.com/flash/video/water.flv";
my_ta.visible = false;
// キューポイントオブジェクトを作成する
var cuePt:Object = new Object(); // キューポイントオブジェクトを作成する
cuePt.time = 2.444;
cuePt.name = "ASCuePt1";
cuePt.type = "actionscript";
my_FLVPlybk.addASCuePoint(cuePt);  // AS キューポイントを追加する
// time パラメータと name パラメータを使用して 2 番目の AS キューポイントを追加する
my_FLVPlybk.addASCuePoint(5, "ASCuePt2"); 
var listenerObject:Object = new Object();
listenerObject.cuePoint = function(eventObject:Object):Void {
        my_ta.text = "Elapsed time in seconds: " + my_FLVPlybk.playheadTime;
        my_ta.visible = true;
};
my_FLVPlybk.addEventListener("cuePoint", listenerObject);

FLVPlayback.addASCuePoint()

使用できるバージョン

エディション

シンタックス

パラメータ

戻り値

説明

例

関連項目