FLVPlayback.activeVideoPlayerIndex

my_FLVPlybk.activeVideoPlayerIndex

説明

プロパティ。他の API によって影響を受けるビデオプレーヤーインスタンスを指定する数値です。このプロパティを使用して複数の FLV ファイルストリームを管理します。デフォルト値は 0 です。

このプロパティにより、ビデオプレーヤーは表示されません。ビデオプレーヤーを表示するには visibleVideoPlayerIndex プロパティを使用します。

初めて activeVideoPlayerIndex に数値を設定したときに新しいビデオプレーヤーが作成されます。新しいビデオプレーヤーが作成されると、プロパティがデフォルトビデオプレーヤー (activeVideoPlayer == 0) の値に設定されますが、contentPath、totalTime および isLive は常にデフォルト値 (それぞれ空のストリング、0、および false) に設定され、autoPlay は常に false (デフォルトは、デフォルトビデオプレーヤー 0 に対してのみ true) に設定されます。cuePoints プロパティには効果がなく、デフォルトビデオプレーヤーへのそれ以降のロードには無効です。

ボリューム、位置、サイズ、可視性、および UI コントロールを制御する API は常にグローバルであり、そのビヘイビアは activeVideoPlayerIndex の設定による影響を受けません。具体的には、activeVideoPlayerIndex プロパティを設定しても、次のプロパティとメソッドには影響はありません。

activeVideoPlayerIndex によって影響を受けないプロパティとメソッド
`backButton`	`playPauseButton`	`skin`	`width`
`bufferingBar`	`scaleX`	`stopButton`	`x`
`bufferingBarHidesAndDisablesOthers`	`transform`	`y`
`forwardButton`	`scaleY`	`visible`	`setSize()`
`height`	`seekBar`	`volume`	`setScale()`
`muteButton`	`seekBarInterval`	`volumeBar`
`pauseButton`	`seekBarScrubTolerance`	`volumeBarInterval`
`playButton`	`seekToPrevOffset`	`volumeBarScrubTolerance`

ただし、サイズを制御する API は visibleVideoPlayerIndex プロパティを使用します。詳細については、FLVPlayback.visibleVideoPlayerIndexを参照してください。

その他の API は、activeVideoPlayerIndex の設定に基づいて特定のビデオプレーヤーをターゲットにします。

イベントをリスンするときは、すべてのビデオプレーヤー用のすべてのイベントを取得します。イベントが対応するビデオプレーヤーを識別するには、イベントの vp プロパティ、activeVideoPlayerIndex に設定されている数値に対応する数値、および visibleVideoPlayerIndex を使用します。このプロパティはすべてのイベントにありますが、resize と volume はビデオプレーヤー固有のプロパティではなく、FLVPlayback インスタンスに対してグローバルです。

たとえば、2 番目の FLV ファイルをバックグラウンドでロードするには、activeVideoPlayerIndex に 1 を設定し、load() メソッドを呼び出します。この FLV ファイルを表示し、最初のファイルを非表示にするには、visibleVideoPlayer に 1 を設定します。

例

次の例では、1 つの FLV ファイルインスタンスで 2 つの FLV ファイルを連続して再生する 2 つのビデオプレーヤーを作成します。ビデオプレーヤーとそれぞれの FLV ファイルを切り替えるように activeVideoPlayerIndex プロパティを設定します。

FLVPlayback コンポーネントをステージにドラッグし、インスタンス名を my_FLVPlybk にします。続いて、次のコードをタイムラインのフレーム 1 の [アクション] パネルに追加します。

/**
 必須 :
  - my_FLVPlybk というインスタンス名の FLVPlayback コンポーネントがステージ上にあること
*/
import mx.video.*;
// デフォルトプレーヤー用の FLV の名前と場所を指定する
my_FLVPlybk.contentPath = "http://www.helpexamples.com/flash/video/clouds.flv";
var listenerObject:Object = new Object();
listenerObject.ready = function(eventObject:Object):Void {
    // 2 番目のビデオプレーヤーを追加し、その FLV の名前と場所を指定する
    my_FLVPlybk.activeVideoPlayerIndex = 1;
    my_FLVPlybk.contentPath = "http://www.helpexamples.com/flash/video/water.flv";
    // デフォルトビデオプレーヤーにリセットし、FLV を自動的に再生する
    my_FLVPlybk.activeVideoPlayerIndex = 0;
};
my_FLVPlybk.addEventListener("ready", listenerObject);
listenerObject.complete = function(eventObject:Object):Void {
    // complete の対象が 2 番目の FLV である場合、デフォルトをアクティブにし、表示する
    if (eventObject.vp == 1) {
        my_FLVPlybk.activeVideoPlayerIndex = 0;
        my_FLVPlybk.visibleVideoPlayerIndex = 0;
    }
    else { // 2 番目のプレーヤーをアクティブにし、表示し、FLV を再生する
        my_FLVPlybk.activeVideoPlayerIndex = 1;
        my_FLVPlybk.visibleVideoPlayerIndex = 1;
        my_FLVPlybk.play();
    }
};
// complete イベントのリスナーを追加する
my_FLVPlybk.addEventListener("complete", listenerObject);

FLVPlayback.activeVideoPlayerIndex

使用できるバージョン

エディション

シンタックス

説明

例

関連項目