_url (MovieClip._url プロパティ)

ムービークリップのダウンロード元である SWF、JPEG、GIF、または PNG の各ファイルの URL を取得します。

対応バージョン : ActionScript 1.0、Flash Player 4 - ムービークリップのダウンロード元である JPEG ファイルの URL を取得できるようになったのは Flash Player 6 からです。ムービークリップのダウンロード元である GIF ファイルと PNG ファイルの URL を取得できるようになったのは Flash Player 8 からです。

例

次の例では、インスタンス image_mc にロードされたイメージの URL を [出力] パネルに表示します。

this.createEmptyMovieClip("image_mc", 1);
var mclListener:Object = new Object();
mclListener.onLoadInit = function(target_mc:MovieClip) {
    trace("_url: "+target_mc._url);
};
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("http://www.adobe.com/images/shared/product_boxes/112x112/box_studio_112x112.jpg", image_mc);

次の例では、ContextMenu オブジェクト menu_cm をムービークリップ image_mc に割り当てます。オブジェクト menu_cm には [View Image in Browser] というラベルのカスタムメニュー項目があり、この項目には関数 viewImage() が関連付けられています。

var menu_cm:ContextMenu = new ContextMenu();
menu_cm.customItems.push(new ContextMenuItem("View Image in Browser...", viewImage));
this.createEmptyMovieClip("image_mc", this.getNextHighestDepth());
var mclListener:Object = new Object();
mclListener.onLoadInit = function(target_mc:MovieClip) {
    target_mc.menu = menu_cm;
};
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("photo1.jpg", image_mc);

function viewImage(target_mc:MovieClip, obj:Object) {
    getURL(target_mc._url, "_blank");
}

実行時にイメージを右クリック (Windows の場合) または Control キーを押したままクリック (Macintosh の場合) し、コンテキストメニューの [View Image in Browser] を選択すると、ブラウザウィンドウでイメージが開きます。

これらの例で使用している MovieClipLoader クラスには、Flash Player 7 以降が必要です。これらの例で使用している MovieClip.getNextHighestDepth() メソッドには Flash Player 7 以降が必要です。SWF ファイルにバージョン 2 のコンポーネントがある場合は、MovieClip.getNextHighestDepth() メソッドではなく、バージョン 2 のコンポーネントの DepthManager クラスを使用します。