beginBitmapFill (MovieClip.beginBitmapFill メソッド)

描画領域をビットマップイメージで塗りつぶします。ビットマップを繰り返すか、タイリング表示して、領域を塗りつぶすことができます。

パラメータ

bmp:BitmapData - 透明または不透明なビットマップイメージ。

matrix:Matrix (オプション) - flash.geom.Matrix クラスのマトリックスオブジェクト。これを使用してビットマップ上に変形を定義できます。たとえば、次のマトリックスを使用すると、ビットマップを 45 度 (π/4 ラジアン) 回転できます。

var matrix = new flash.geom.Matrix(); 
matrix.rotate(Math.PI/4);

repeat:Boolean (オプション) - true の場合、ビットマップイメージが一定のパターンでタイリング表示されます。false の場合、ビットマップイメージは繰り返されません。ビットマップからはみ出す塗り領域にはビットマップのエッジが使用されます。

たとえば、次のビットマップ (20 x 20 ピクセルのチェッカーボードのパターン) を考えます。

次の例のように repeat が true に設定されている場合、ビットマップの塗りでビットマップが繰り返されます。

repeat が false に設定されている場合、エッジのピクセルがビットマップの外側の塗り領域に使用されます。

smoothing:Boolean (オプション) - false の場合、最近傍アルゴリズムを使用して拡大されたビットマップイメージがレンダリングされ、ピクセル化されたように見えます。true の場合、双線形アルゴリズムを使用して拡大されたビットマップイメージがレンダリングされます。最近傍アルゴリズムを使用したレンダリングは、通常はかなり高速です。このパラメータのデフォルト値は false です。

例

次のコードでは、単純なビットマップを定義した後、beginBitmapFill() メソッドを使用して、このビットマップをタイリング表示してムービークリップを塗りつぶします。

import flash.display.*;
import flash.geom.*;

var bmpd:BitmapData = new BitmapData(20,20);
var rect1:Rectangle = new Rectangle(0,0,10,10);
var rect2:Rectangle = new Rectangle(0, 10, 10, 20);
var rect3:Rectangle = new Rectangle(10, 0, 20, 10);
var rect4:Rectangle = new Rectangle(10, 10, 20, 20);
bmpd.fillRect(rect1, 0xAA0000FF);
bmpd.fillRect(rect2, 0xAA00FF00);
bmpd.fillRect(rect3, 0xAAFF0000);
bmpd.fillRect(rect4, 0xAA999999);

this.createEmptyMovieClip("bmp_fill_mc", this.getNextHighestDepth());
with (bmp_fill_mc) {
    matrix = new Matrix(); 
    matrix.rotate(Math.PI/8);
    repeat = true;
    smoothing = true;
    beginBitmapFill(bmpd, matrix, repeat, smoothing);
    moveTo(0, 0);
    lineTo(0, 60);
    lineTo(60, 60);
    lineTo(60, 0);
    lineTo(0, 0);
    endFill();
}

bmp_fill_mc._xscale = 200;
bmp_fill_mc._yscale = 200;

SWF ファイルにバージョン 2 のコンポーネントがある場合は、この例で使用している MovieClip.getNextHighestDepth() メソッドではなく、バージョン 2 コンポーネントの DepthManager クラスを使用します。