onSecurityError (FileReference.onSecurityError イベントリスナー)

セキュリティエラーのためにアップロードまたはダウンロードが失敗したときに呼び出されます。呼び出し側の SWF ファイルが自分のドメインの外にある SWF ファイルにアクセスしようとして、アクセス権限がないと発生します。クロスドメインポリシーファイルを使用することで、このエラーに対処できます。

パラメータ

fileRef:FileReference - 処理を開始した FileReference オブジェクト。

errorString:String - onSecurityError が呼び出される原因となったエラーを示します。この値は "securitySandboxError" です。

例

次の例では、onSecurityError など、想定されるイベント用のリスナーを含む FileReference オブジェクトを作成します。この onSecurityError リスナーは、セキュリティエラーが原因でアップロードが失敗した場合にのみトリガされます。

import flash.net.FileReference;

var listener:Object = new Object();

listener.onSelect = function(file:FileReference):Void {
    trace("onSelect: " + file.name);
    if(!file.upload("http://www.yourdomain.com/yourUploadHandlerScript.cfm")) {
        trace("Upload dialog failed to open.");
    }
}

listener.onCancel = function(file:FileReference):Void {
    trace("onCancel");
}

listener.onOpen = function(file:FileReference):Void {
    trace("onOpen: " + file.name);
}

listener.onProgress = function(file:FileReference, bytesLoaded:Number, bytesTotal:Number):Void {
    trace("onProgress with bytesLoaded: " + bytesLoaded + " bytesTotal: " + bytesTotal);
}

listener.onComplete = function(file:FileReference):Void {
    trace("onComplete: " + file.name);
}

listener.onHTTPError = function(file:FileReference):Void {
    trace("onHTTPError: " + file.name);
}

listener.onIOError = function(file:FileReference):Void {
    trace("onIOError: " + file.name);
}

listener.onSecurityError = function(file:FileReference, errorString:String):Void {
    trace("onSecurityError: " + file.name + " errorString: " + errorString);
}

var fileRef:FileReference = new FileReference();
fileRef.addListener(listener);
fileRef.browse();