onHTTPError (FileReference.onHTTPError イベントリスナー)

HTTP エラーのためにアップロードが失敗したときに呼び出されます。

ファイルをダウンロードする際、Flash Player はブラウザのスタックを頼りにするので、このエラーはダウンロードエラーでは利用されません。HTTP エラーのためにダウンロードが失敗した場合は、I/O エラーとして通知されます。

パラメータ

fileRef:FileReference - 処理を開始した FileReference オブジェクト。

httpError:Number - このアップロードの失敗原因である HTTP エラー。たとえば、httpError が 404 である場合はページが見つからなかったことを表します。HTTP エラーの値は、ftp://ftp.isi.edu/in-notes/rfc2616.txt にある HTTP 仕様書のセクション 10.4 と 10.5 に記載されています。

例

次の例では、onHttpError など、想定されるイベント用のリスナーを含む FileReference オブジェクトを作成します。このリスナーは、HTTP エラーが原因でアップロードが失敗した場合にのみトリガされます。

import flash.net.FileReference;

var listener:Object = new Object();

listener.onSelect = function(file:FileReference):Void {
    trace("onSelect: " + file.name);
    if(!file.upload("http://www.yourdomain.com/yourUploadHandlerScript.cfm")) {
        trace("Upload dialog failed to open.");
    }
}

listener.onCancel = function(file:FileReference):Void {
    trace("onCancel");
}

listener.onOpen = function(file:FileReference):Void {
    trace("onOpen: " + file.name);
}

listener.onProgress = function(file:FileReference, bytesLoaded:Number, bytesTotal:Number):Void {
    trace("onProgress with bytesLoaded: " + bytesLoaded + " bytesTotal: " + bytesTotal);
}

listener.onComplete = function(file:FileReference):Void {
    trace("onComplete: " + file.name);
}

listener.onHTTPError = function(file:FileReference):Void {
    trace("onHTTPError: " + file.name);
}

listener.onIOError = function(file:FileReference):Void {
    trace("onIOError: " + file.name);
}

listener.onSecurityError = function(file:FileReference, errorString:String):Void {
    trace("onSecurityError: " + file.name + " errorString: " + errorString);
}

var fileRef:FileReference = new FileReference();
fileRef.addListener(listener);
fileRef.browse();