onClipEvent ハンドラ

onClipEvent(movieEvent:Object) {
// your statements here
}

ムービークリップの特定のインスタンスに対して定義されたアクションを起動します。

対応バージョン : ActionScript 1.0、Flash Player 5

パラメータ

movieEvent:Object - movieEvent は、イベントと呼ばれるトリガです。イベントが発生すると、その後ろの中カッコ ({}) 内のステートメントが実行されます。次の値のすべてを、movieEvent パラメータに指定できます。

load - ムービークリップがインスタンス化され、タイムラインに表示されると、アクションが即座に開始されます。

unload - ムービークリップがタイムラインから削除された後、最初のフレームでアクションが開始します。Unload ムービークリップイベントに関連するアクションは、該当するフレームにアクションが割り当てられる前に処理されます。

enterFrame - アクションはムービークリップのフレームレートで継続的にトリガされます。enterFrame クリップイベントに関連するアクションは、該当するフレームに割り当てられているフレームアクションの前に処理されます。

mouseMove - マウスを動かすたびに、アクションが開始されます。現在のマウスの位置を判別するには、_xmouse プロパティと _ymouse プロパティを使用します。

mouseDown - 左マウスボタンを押すと、アクションが開始されます。

mouseUp - 左マウスボタンを離すと、アクションが開始します。

keyDown - キーを押すと、アクションが開始します。最後に押されたキーについての情報を取得するには、Key.getCode() を使用します。

keyUp - キーを離すと、アクションが開始します。最後に押されたキーについての情報を取得するには、Key.getCode() メソッドを使用します。

data - loadVariables() アクションまたは loadMovie() アクションによってデータを取得すると、アクションが開始されます。loadVariables() アクションと共に指定すると、data イベントは最後の変数がロードされたときの 1 回だけ発生します。loadMovie() アクションで指定すると、各データセクションが読み込まれるたびに、data イベントが繰り返し発生します。

例

次の例は、keyDown ムービーイベントで onClipEvent() を使用しており、ムービークリップまたはボタンにアタッチされるように設計されています。通常、keyDown ムービーイベントは Key オブジェクトのメソッドやプロパティと共に使用します。次のスクリプトでは、Key.getCode() を使用して、ユーザーが押したキーを調べます。押されたキーが Key.RIGHT プロパティと一致する場合は、再生ヘッドを次のフレームに送ります。押されたキーが Key.LEFT プロパティと一致する場合は、再生ヘッドを前のフレームに送ります。

onClipEvent (keyDown) {
 if (Key.getCode() == Key.RIGHT) {
 this._parent.nextFrame();
 } else if (Key.getCode() == Key.LEFT) {
 this._parent.prevFrame();
 }
}

次の例では、load および mouseMove ムービーイベントで onClipEvent() を使用します。_ xmouse プロパティと _ ymouse プロパティは、マウスが移動するたびにマウスの位置を追跡します。位置は、実行時に作成されるテキストフィールドに表示されます。

onClipEvent (load) {
 this.createTextField("coords_txt", this.getNextHighestDepth(), 0, 0, 100, 22);
 coords_txt.autoSize = true;
 coords_txt.selectable = false;
}
onClipEvent (mouseMove) {
 coords_txt.text = "X:"+_root._xmouse+",Y:"+_root._ymouse;
}

関連項目

現在のページ: http://livedocs.adobe.com/flash/9.0_jp/main/00001203.html