Flash CS3 ドキュメンテーション

ActionScript 2.0 の学習 > テキストとストリングの操作 > ストリングおよび String クラスについて > ストリングの変換と連結

ストリングの変換と連結

toString() メソッドを使用すると、多くのオブジェクトをストリングに変換できます。ほとんどのビルトインオブジェクトはこの変換を行う toString() メソッドを持っています。

var n:Number = 0.470;
trace(typeof(n.toString())); // string

加算演算子 (+) をストリングおよびストリング以外のインスタンスの組み合わせに使用するときは、toString() メソッドを使用する必要はありません。連結の詳細については、このセクションの 2 番目の手順を参照してください。

toLowerCase() メソッドおよび toUpperCase() メソッドは、ストリング内のアルファベット文字をそれぞれ小文字と大文字に変換します。次の例は、ストリングを小文字から大文字に変換する方法を示しています。

ストリングを小文字から大文字に変換するには :

1. 新しい Flash ドキュメントを作成し、convert.fla という名前を付けて保存します。
2. タイムラインのフレーム 1 に次のコードを入力します。

   var myStr:String = "Dr. Bob Roberts, #9.";
   trace(myStr.toLowerCase()); // dr. bob roberts, #9.
   trace(myStr.toUpperCase()); // DR. BOB ROBERTS, #9.
   trace(myStr); // Dr. Bob Roberts, #9.
   

3. Flash ドキュメントを保存して、[制御]-[ムービープレビュー] を選択します。

   メモ

   これらのメソッドを実行しても、ソースストリングは変更されません。ソースストリングを変換するには、次の方法を使用します。

   myStr = myStr.toUpperCase();
   

ストリングを連結すると、2 つのストリングが順番に結合されて 1 つのストリングになります。たとえば、加算演算子 (+) を使用して 2 つのストリングを連結できます。次の例では、2 つのストリングを連結する方法を示します。

2 つのストリングを連結するには :

1. 新しい Flash ドキュメントを作成し、concat.fla という名前を付けて保存します。
2. タイムラインのフレーム 1 に次のコードを追加します。

   var str1:String = "green";
   var str2:String = str1 + "ish";
   trace(str2); // greenish
   //
   var str3:String = "yellow";
   str3 += "ish";
   trace(str3); // yellowish
   

   上記のコードでは、文字列を連結する 2 種類の方法が示されています。最初の方法では、加算演算子 (+) を使用してストリング str1 とストリング "ish" を結合させています。2 番目の方法では、加算後代入 (+=) 演算子を使用して、ストリング "ish" を str3 の現在の値と連結しています。

3. Flash ドキュメントを保存して、[制御]-[ムービープレビュー] を選択します。

String クラスの concat() メソッドを使用してストリングを連結することもできます。次の例は、このメソッドを示しています。

2 つのストリングを concat() メソッドで連結するには :

1. 新しい Flash ドキュメントを作成し、concat2.fla という名前を付けて保存します。
2. タイムラインのフレーム 1 に次のコードを追加します。

   var str1:String = "Bonjour";
   var str2:String = "from";
   var str3:String = "Paris";
   var str4:String = str1.concat(" ", str2, " ", str3);
   trace(str4); // Bonjour from Paris
   

3. [制御]-[ムービープレビュー] を選択して Flash ドキュメントをテストします。

加算演算子 (+) (または加算後代入演算子 (+=)) をストリングとストリング以外のオブジェクトに対して使用すると、ActionScript は、式を評価するためにストリング以外のオブジェクトを自動的にストリングに変換します。この変換は、次のコードの例に示されています。

var version:String = "Flash Player ";
var rel:Number = 9;
version = version + rel;
trace(version); // Flash Player 9

ただし、次の ActionScript コードに示すように、括弧を使用して加算 (+) 演算子に算術的な評価を強制することができます。

trace("Total: $" + 4.55 + 1.46); // 合計 : $4.551.46
trace("Total: $" + (4.55 + 1.46)); // 合計 : $6.01

split() メソッドを使用して、ストリングのサブストリングの配列を作成することができます。この配列は、区切り文字で分割されます。たとえば、カンマまたはタブで区切られたストリングを複数のストリングに分割できます。

たとえば、次のコードは、アンパサンド文字 (&) を区切り文字として使用し、配列をサブストリングに分割できることを示しています。

区切り文字で分割されたサブストリングの配列を作成するには :

1. 新しい Flash ドキュメントを作成し、strsplit.fla という名前を付けて保存します。
2. メインタイムラインのフレーム 1 に次の ActionScript を追加します。

   var queryStr:String = "first=joe&last=cheng&title=manager&startDate=3/6/65";
   var params:Array = queryStr.split("&", 2);
   trace(params); // first=joe,last=cheng
           /* params は 2 つのエレメントを持つ配列に設定
               params[0] == "first=joe"
               params[1] == "last=cheng"
           */
   

3. [制御]-[ムービープレビュー] を選択して Flash ドキュメントをテストします。

   ヒント

   split() メソッドの 2 番目のパラメータは、配列の最大サイズを定義しています。split() メソッドによって作成される配列のサイズを制限しないようにするには、2 番目のパラメータを省略します。

   ヒント

   クエリーストリング (& および = 文字で区切られているストリング) を解析する最も簡単な方法は、LoadVars.decode() メソッドを使用することです。その例を次の ActionScript に示します。

   var queryStr:String = "first=joe&last=cheng&title=manager&startDate=3/6/65";
   var my_lv:LoadVars = new LoadVars();
   my_lv.decode(queryStr);
   trace(my_lv.first); // joe
   

ストリングへの演算子の使用の詳細については、演算子とストリングの使用についてを参照してください。

選択されたストリングとサブストリングを比較および取得する簡単なワードプロセッサを作成する方法を示す、サンプルのソースファイル "strings.fla" については、Flash サンプルページ (www.adobe.com/go/learn_fl_samples_jp) を参照してください。"Samples" zip ファイルをダウンロードし解凍して、"ActionScript2.0/Strings" フォルダに移動してサンプルにアクセスします。

このページに新しいコメントが追加された場合に、電子メールでの通知を希望する。 | コメントレポート

現在のページ: http://livedocs.adobe.com/flash/9.0_jp/main/00000950.html

コメントの追加