Flash CS3 ドキュメンテーション

ActionScript 2.0 の学習 > テキストとストリングの操作 > CSS スタイルによるテキストのフォーマット > XML でのスタイルの使用例

XML でのスタイルの使用例

このセクションでは、XML 形式のテキストが使われる FLA ファイルを作成します。HTML でのスタイルの使用例で示したように CSS ファイルからスタイルを読み込むのではなく、ActionScript を使用してスタイルシートを作成します。

XML をスタイルシートでフォーマットするには :

1. Flash 内で新規 FLA ファイルを作成します。
2. テキストツールを使用して、幅 400 ピクセル、高さ 300 ピクセルのテキストフィールドを作成します。
3. プロパティインスペクタを開き ([ウィンドウ]-[プロパティ]-[プロパティ])、テキストフィールドを選択します。
4. プロパティインスペクタで、[テキストの種類] メニューから [ダイナミックテキスト] を選択し、[行タイプ] メニューから [複数行] を選択し、[テキストを HTML としてレンダリング] オプションを選択して、[インスタンス名] テキストボックスに「news_txt」と入力します。
5. タイムライン ([ウィンドウ]-[タイムライン]) のレイヤー 1 上で、最初のフレームを選択します。
6. スタイルシートオブジェクトを作成するために、[アクション] パネルを開き ([ウィンドウ]-[アクション])、[アクション] パネルに次のコードを入力します。

   var styles:TextField.StyleSheet = new TextField.StyleSheet();
   styles.setStyle("mainBody", {
       color:'#000000', 
       fontFamily:'Arial,Helvetica,sans-serif', 
       fontSize:'12', 
       display:'block'
   });
   styles.setStyle("title", {
       color:'#000000', 
       fontFamily:'Arial,Helvetica,sans-serif', 
       fontSize:'18', 
       display:'block', 
       fontWeight:'bold'
   });
   styles.setStyle("byline", {
       color:'#666600', 
       fontWeight:'bold', 
       fontStyle:'italic', 
       display:'inline'
   });
   styles.setStyle("a:link", {
       color:'#FF0000'
   });
   styles.setStyle("a:hover", {
       textDecoration:'underline'
   });
   

   このコードで、setStyle() メソッドを使用してスタイルを定義する styles という名前の新しいスタイルシートオブジェクトを作成します。このスタイルは、この章で先に作成した外部 CSS ファイルと正確に一致します。

7. テキストフィールドに割り当てる XML テキストを作成するには、テキストエディタを開いて新規ドキュメントに次のテキストを入力します。

   <story><title>Flash now has advanced anti-aliasing</title><mainBody><byline>San Francisco, CA</byline>--Adobe Inc. announced today a new version of Flash that features the new advanced anti-aliasing rendering technology. For more information, visit the <a href="http://www.adobe.com">Adobe Flash website</a></mainBody></story>
   

   メモ

   このテキストストリングをコピー & ペーストする場合、テキストストリングに改行が追加されたときには必ず削除してください。[アクション] パネルのポップアップメニューで [隠し文字] を選択し、余分な改行を表示して削除します。

8. テキストファイルを story.xml として保存します。
9. Flash で、手順 6 のコードに続けて次のコードを [アクション] パネルに追加ます。

   このコードでは、story.xml ドキュメントをロードし、テキストフィールドの styleSheet プロパティにスタイルシートオブジェクトを割り当て、XML テキストをテキストフィールドに割り当てます。

   var my_xml:XML = new XML();
   my_xml.ignoreWhite = true;
   my_xml.onLoad = function(success:Boolean):Void {
       if (success) {
           news_txt.styleSheet = styles;
           news_txt.text = my_xml;
       } else {
           trace("Error loading XML.");
       }
   };
   

   my_xml.load("story.xml");

   
   

   メモ

   この ActionScript では、外部ファイルから XML データをロードしています。外部データをロードする方法については、イメージ、サウンドおよびビデオの操作.を参照してください。

10. ファイルを "story.xml" ファイルと同じフォルダ内に news_xml.fla として保存します。
11. SWF ファイルを実行し ([制御]-[ムービープレビュー])、フィールド内のテキストにスタイルが自動的に適用されることを確認します。

このページに新しいコメントが追加された場合に、電子メールでの通知を希望する。 | コメントレポート

現在のページ: http://livedocs.adobe.com/flash/9.0_jp/main/00000919.html

コメントの追加