Flash CS3 ドキュメンテーション

ActionScript 2.0 の学習 > クラス > アプリケーションでのカスタムクラスの使用について > クラスファイルのメソッドとプロパティの使用

クラスファイルのメソッドとプロパティの使用

OOP では、クラスのメンバー (プロパティまたはメソッド) はインスタンスメンバーまたはクラスメンバーになります。クラスのインスタンスごとにインスタンスメンバーが作成されます。これらは、クラス定義内で初期化されるときに、クラスのプロトタイプに定義されます。これに対し、クラスメンバーはクラスごとに 1 回だけ作成されます。クラスメンバーは静的メンバーと呼ばれることもあります。

プロパティとは、オブジェクトを定義する属性です。たとえば、length は配列のエレメント数を指定するプロパティで、すべての配列に備わっています。メソッドとは、クラスに関連付けられた関数です。関数とメソッドの詳細については、関数とメソッドを参照してください。

次の例では、クラスファイルでメソッドを作成する方法を示します。

class Sample {
  public function myMethod():Void {
    trace("myMethod");
  }
} 

次に、ドキュメントでメソッドを実行します。インスタンスメソッドを呼び出したり、インスタンスプロパティにアクセスしたりするには、クラスのインスタンスを参照します。次の例では、カスタム Picture クラス (次の実習で作成) のインスタンスである picture01 で、showInfo() メソッドを呼び出しています。

var img1:Picture = new Picture("http://www.helpexamples.com/flash/images/image1.jpg");
// showInfo() メソッドを呼び出す。
img1.showInfo();

次の例では、カスタム Picture クラスを記述して写真の各情報を維持する方法について説明しています。

FLA ファイルで Picture クラスと PictureClass クラスを使用するには :

1. [ファイル]-[新規] を選択し、[ActionScript ファイル] を選択します。ドキュメントを Picture.as という名前で保存し、[OK] をクリックします。

   このドキュメントにカスタム Picture クラスを記述します。

2. 次の ActionScript コードをスクリプトウィンドウに入力します。

   /**
       Picture クラス
       作成者 : John Doe
       バージョン : 0.53
       変更日 : 6/24/2005
       著作権 : Adobe Systems Incorporated
   
       Picture クラスはイメージとその URL のコンテナとして使用される。
   */
   
   class Picture {
       private var __infoObj:Object;
   
       public function Picture(src:String) {
           this.__infoObj = new Object();
           this.__infoObj.src = src;
       }
   
       public function showInfo():Void {
           trace(this.toString());
       }
       private function toString():String {
           return "[Picture src=" + this.__infoObj.src + "]";
       }
   
       public function get src():String {
           return this.__infoObj.src;
       }
       public function set src(value:String):Void {
           this.__infoObj.src = value;
       }    
   }
   

3. ActionScript ファイルを保存します。
4. [ファイル]-[新規] を選択し、[Flash ドキュメント] を選択して新しい FLA ファイルを作成します。Picture クラスファイルを保存したディレクトリと同じディレクトリに picture_test.fla という名前で保存します。
5. 次の ActionScript コードをタイムラインのフレーム 1 に入力します。

   var picture1:Picture = new Picture("http://www.helpexamples.com/flash/images/image1.jpg");
   picture1.showInfo();
   this.createEmptyMovieClip("img_mc", 9);
   img_mc.loadMovie(picture1.src);
   

6. Flash ドキュメントを保存します。
7. [制御]-[ムービープレビュー] を選択してドキュメントをテストします。

   次のテキストが [出力] パネルに表示されます。

   [Picture src=http://www.helpexamples.com/flash/images/image1.jpg]
   

XML データとカスタムクラスファイルを使用して動的にメニューを作成する方法を示すサンプルについては、Flash サンプルページ (www.adobe.com/go/learn_fl_samples_jp) を参照してください。このサンプルでは、ActionScript XmlMenu() コンストラクタを呼び出し、XML メニューファイルへのパスおよび現在のタイムラインへの参照をパラメータとして渡します。"Samples" zip ファイルをダウンロードし解凍して、"ActionScript2.0/XML_Menu" フォルダに移動して次のサンプルにアクセスします。

• XmlMenu.as
• xmlmenu.fla

このページに新しいコメントが追加された場合に、電子メールでの通知を希望する。 | コメントレポート

現在のページ: http://livedocs.adobe.com/flash/9.0_jp/main/00000778.html

コメントの追加