Flash CS3 ドキュメンテーション

ActionScript 3.0 コンポーネントガイド > UI コンポーネントの使用 > TileList の使用 > TileList を使用したアプリケーションの作成

TileList を使用したアプリケーションの作成

この例では、複数の MovieClip を使用して、TileList にペイントカラーの配列を格納します。

TileList コンポーネントを使用してアプリケーションを作成するには :

1. 新しい Flash ファイル (ActionScript 3.0) ドキュメントを作成します。
2. TileList コンポーネントをステージにドラッグし、インスタンス名を aTl にします。
3. [アクション] パネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

   import fl.data.DataProvider;
   import flash.display.DisplayObject;
   
   var aBoxes:Array = new Array();
   var i:uint = 0;
   var colors:Array = new Array(0x00000, 0xFF0000, 0x0000CC, 0x00CC00, 0xFFFF00);
   var colorNames:Array = new Array("Midnight", "Cranberry", "Sky", "Forest", "July");
   var dp:DataProvider = new DataProvider();
   for(i=0; i < colors.length; i++) {
       aBoxes[i] = new MovieClip();
       drawBox(aBoxes[i], colors[i]);    // draw box w next color in array
       dp.addItem( {label:colorNames[i], source:aBoxes[i]} );
   }
   aTl.dataProvider = dp;
   aTl.columnWidth = 110;
   aTl.rowHeight = 130;
   aTl.setSize(280,150);
   aTl.move(150, 150);
   aTl.setStyle("contentPadding", 5);
   
   function drawBox(box:MovieClip,color:uint):void {
               box.graphics.beginFill(color, 1.0);
               box.graphics.drawRect(0, 0, 100, 100);
               box.graphics.endFill();        
   }
   

4. [制御]-[ムービープレビュー] を選択してアプリケーションをテストします。

次の例では、TileList インスタンスを動的に作成し、ColorPicker、ComboBox、NumericStepper、および CheckBox の各コンポーネントのインスタンスを追加します。表示するコンポーネントのラベルと名前が格納された Array を作成し、その Array (dp) を TileList の dataProvider プロパティに割り当てます。columnWidth プロパティと rowHeight プロパティを使用し、setSize() メソッドで TileList のレイアウトを指定して、move() メソッドで TileList をステージに配置します。また、contentPadding スタイルで TileList インスタンスの境界線とコンテンツの間に空白をあけて、sortItemsOn() メソッドではコンテンツをラベルの順序で並べ替えています。

ActionScript を使用して TileList コンポーネントを作成するには :

1. 新しい Flash ファイル (ActionScript 3.0) ドキュメントを作成します。
2. ColorPicker、ComboBox、NumericStepper、CheckBox、および TileList の各コンポーネントを [コンポーネント] パネルから [ライブラリ] パネルにドラッグします。
3. [アクション] パネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

   import fl.controls.CheckBox;
   import fl.controls.ColorPicker;
   import fl.controls.ComboBox;
   import fl.controls.NumericStepper;
   import fl.controls.TileList;
   import fl.data.DataProvider;
   
   var aCp:ColorPicker = new ColorPicker();
   var aCb:ComboBox = new ComboBox();
   var aNs:NumericStepper = new NumericStepper();
   var aCh:CheckBox = new CheckBox();
   var aTl:TileList = new TileList();
   
   var dp:Array = [
       {label:"ColorPicker", source:aCp},
       {label:"ComboBox", source:aCb},
       {label:"NumericStepper", source:aNs},
       {label:"CheckBox", source:aCh},
   ];
   aTl.dataProvider = new DataProvider(dp);
   aTl.columnWidth = 110;
   aTl.rowHeight = 100;
   aTl.setSize(280,130);
   aTl.move(150, 150);
   aTl.setStyle("contentPadding", 5);
   aTl.sortItemsOn("label");
   addChild(aTl);
   

4. [制御]-[ムービープレビュー] を選択してアプリケーションをテストします。

このページに新しいコメントが追加された場合に、電子メールでの通知を希望する。 | コメントレポート

現在のページ: http://livedocs.adobe.com/flash/9.0_jp/main/00000479.html

コメントの追加