Flash CS3 ドキュメンテーション

ActionScript 3.0 コンポーネントガイド > UI コンポーネントの使用 > ScrollPane の使用 > ScrollPane を使用したアプリケーションの作成

ScrollPane を使用したアプリケーションの作成

次の手順は、オーサリング時に ScrollPane コンポーネントをアプリケーションに追加する方法を示しています。次の例では、source プロパティで指定されたパスから ScrollPane に画像をロードします。

ScrollPane コンポーネントを使用してアプリケーションを作成するには :

1. 新しい Flash ファイル (ActionScript 3.0) ドキュメントを作成します。
2. ScrollPane コンポーネントを [コンポーネント] パネルからステージまでドラッグし、インスタンス名を aSp にします。
3. [アクション] パネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

   import fl.events.ScrollEvent;
   
   aSp.setSize(300, 200);
   
   function scrollListener(event:ScrollEvent):void {
    trace("horizontalScPosition: " + aSp.horizontalScrollPosition + 
          ", verticalScrollPosition = " + aSp.verticalScrollPosition);
   };
   aSp.addEventListener(ScrollEvent.SCROLL, scrollListener);
   
   function completeListener(event:Event):void {
    trace(event.target.source + " has completed loading.");
   };
   // Add listener.
   aSp.addEventListener(Event.COMPLETE, completeListener);
   
   aSp.source = "http://www.helpexamples.com/flash/images/image1.jpg";
   

4. [制御]-[ムービープレビュー] を選択してアプリケーションを実行します。

この例では、ScrollPane を作成し、そのサイズを設定して、source プロパティを使用してイメージをロードします。さらに、リスナーを 2 つ作成します。1 番目のリスナーは、scroll イベントを待機し、ユーザーが垂直方向または水平方向にスクロールしたときに、イメージの位置を表示します。2 番目のリスナーは、complete イベントを待機し、イメージのロードが完了したことを通知するメッセージを [出力] パネルに表示します。

この例では、ActionScript を使用して ScrollPane を作成し、150 ピクセル (幅) x 300 ピクセル (高さ) の MovieClip (赤色のボックス) を配置します。

ActionScript を使用して ScrollPane インスタンスを作成するには :

1. 新しい Flash ファイル (ActionScript 3.0) ドキュメントを作成します。
2. ScrollPane コンポーネントを [コンポーネント] パネルから [ライブラリ] パネルにドラッグします。
3. DataGrid コンポーネントを [コンポーネント] パネルから [ライブラリ] パネルにドラッグします。
4. [アクション] パネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

   import fl.containers.ScrollPane;
   import fl.controls.ScrollPolicy;
   import fl.controls.DataGrid;
   import fl.data.DataProvider;
   
   var aSp:ScrollPane = new ScrollPane();
   var aBox:MovieClip = new MovieClip();
   drawBox(aBox, 0xFF0000);    //draw a red box
   
   aSp.source = aBox;
   aSp.setSize(150, 200);
   aSp.move(100, 100);
   
   addChild(aSp);
   
   function drawBox(box:MovieClip,color:uint):void {
               box.graphics.beginFill(color, 1);
               box.graphics.drawRect(0, 0, 150, 300);
               box.graphics.endFill();        
   }
   

5. [制御]-[ムービープレビュー] を選択してアプリケーションを実行します。

このページに新しいコメントが追加された場合に、電子メールでの通知を希望する。 | コメントレポート

現在のページ: http://livedocs.adobe.com/flash/9.0_jp/main/00000463.html

コメントの追加