Flash CS3 ドキュメンテーション

ActionScript 3.0 コンポーネントガイド > UI コンポーネントの使用 > ColorPicker の使用 > ColorPicker を使用したアプリケーションの作成

ColorPicker を使用したアプリケーションの作成

次の例では、オーサリング時に、アプリケーションに ColorPicker コンポーネントを追加します。この例では、ColorPicker でカラーを変更するたびに、changeHandler() 関数が drawBox() 関数を呼び出し、ColorPicker で選択されたカラーの新しいボックスを描画します。

ColorPicker コンポーネントを使用してアプリケーションを作成するには :

1. 新しい Flash ファイル (ActionScript 3.0) ドキュメントを作成します。
2. ColorPicker を [コンポーネント] パネルからステージの中央までドラッグし、インスタンス名を aCp にします。
3. [アクション] パネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

   import fl.events.ColorPickerEvent;
   
   var aBox:MovieClip = new MovieClip();
   drawBox(aBox, 0xFF0000);    //draw a red box
   addChild(aBox);
   
   aCp.addEventListener(ColorPickerEvent.CHANGE,changeHandler);
   
   function changeHandler(event:ColorPickerEvent):void {
       drawBox(aBox, event.target.selectedColor);
   }
   
   function drawBox(box:MovieClip,color:uint):void {
               box.graphics.beginFill(color, 1);
               box.graphics.drawRect(100, 150, 100, 100);
               box.graphics.endFill();        
   }
   

4. [制御]-[ムービープレビュー] を選択します。
5. ColorPicker をクリックし、ボックスに塗るカラーを選択します。

次の例では、ColorPicker() コンストラクタおよび addChild() を使用して、ステージ上に ColorPicker を作成します。ColorPicker で表示するカラーを指定するために、colors プロパティを、赤色 (0xFF0000)、緑色 (0x00FF00)、および青色 (0x0000FF) のカラー値に設定しています。さらに TextArea を作成して、ColorPicker で別のカラーを選択するたびに、その TextArea 内のテキストが同じ色になるように変更します。

ActionScript を使用して ColorPicker を作成するには :

1. 新しい Flash ファイル (ActionScript 3.0) ドキュメントを作成します。
2. ColorPicker コンポーネントを [コンポーネント] パネルから [ライブラリ] パネルにドラッグします。
3. TextArea コンポーネントを [コンポーネント] パネルから [ライブラリ] パネルにドラッグします。
4. [アクション] パネルを開いて、メインタイムライン内でフレーム 1 を選択し、次の ActionScript コードを入力します。

   import fl.controls.ColorPicker;
   import fl.controls.TextArea;
   import fl.events.ColorPickerEvent;
   
   var aCp:ColorPicker = new ColorPicker();
   var aTa:TextArea = new TextArea();
   var aTf:TextFormat = new TextFormat();
   
   aCp.move(100, 100);
   aCp.addEventListener(ColorPickerEvent.CHANGE, changeHandler);
   
   aTa.text = "Lorem ipsum dolor sit amet, consectetuer adipiscing elit. Vivamus quis nisl vel tortor nonummy vulputate. Quisque sit amet eros sed purus euismod tempor. Morbi tempor. Class aptent taciti sociosqu ad litora torquent per conubia nostra, per inceptos hymenaeos. Curabitur diam. Suspendisse at purus in ipsum volutpat viverra. Nulla pellentesque libero id libero.";
   aTa.setSize(200, 200);
   aTa.move(200,100);
   
   addChild(aCp);
   addChild(aTa);
   
   function changeHandler(event:ColorPickerEvent):void {
       if(TextFormat(aTa.getStyle("textFormat"))){
           aTf = TextFormat(aTa.getStyle("textFormat"));
       }
       aTf.color = event.target.selectedColor;
       aTa.setStyle("textFormat", aTf);
   }
   

5. [制御]-[ムービープレビュー] を選択します。

このページに新しいコメントが追加された場合に、電子メールでの通知を希望する。 | コメントレポート

現在のページ: http://livedocs.adobe.com/flash/9.0_jp/main/00000431.html

コメントの追加