位置の変更

myShape.x = 17;
myShape.y = 212;

// ステージの左上隅にシェイプを配置
// 親の位置には関係なく配置する。

// Sprite を作成し、x:200、y:200 に配置する。
var mySprite:Sprite = new Sprite();
mySprite.x = 200;
mySprite.y = 200;
this.addChild(mySprite);

// 参照用に、Sprite の 0,0 座標の位置にドットを描画する。
mySprite.graphics.lineStyle(1, 0x000000);
mySprite.graphics.beginFill(0x000000);
mySprite.graphics.moveTo(0, 0);
mySprite.graphics.lineTo(1, 0);
mySprite.graphics.lineTo(1, 1);
mySprite.graphics.lineTo(0, 1);
mySprite.graphics.endFill();

// 円の Shape インスタンスを作成する。
var circle:Shape = new Shape();
mySprite.addChild(circle);

// 半径 50 で、Shape の x:50、y:50 に中心点がある円を描画する。
circle.graphics.lineStyle(1, 0x000000);
circle.graphics.beginFill(0xff0000);
circle.graphics.drawCircle(50, 50, 50);
circle.graphics.endFill();

// ステージの 0, 0 座標に左上隅が来るようにシェイプを移動する。
var stagePoint:Point = new Point(0, 0);
var targetPoint:Point = mySprite.globalToLocal(stagePoint);
circle.x = targetPoint.x;
circle.y = targetPoint.y;

// このコードは、startDrag() 方式を使用してドラッグ & ドロップ操作を
// 作成する。
// 四角形は DisplayObject (MovieClip または Sprite インスタンスなど)。

import flash.events.MouseEvent;

// この関数は、マウスボタンが押されたときに呼び出される。
function startDragging(event:MouseEvent):void
{
    square.startDrag();
}

// この関数は、マウスボタンが離されたときに呼び出される。
function stopDragging(event:MouseEvent):void
{
    square.stopDrag();
}

square.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
square.addEventListener(MouseEvent.MOUSE_UP, stopDragging);

function startDragging(event:MouseEvent):void
{
    square.startDrag();
    circle.startDrag();
}

// このコードは、マウス追従方式を使用してドラッグ & ドロップ操作を
// 作成する。
// 円は DisplayObject (MovieClip または Sprite インスタンスなど)。

import flash.events.MouseEvent;

var offsetX:Number;
var offsetY:Number;

// この関数は、マウスボタンが押されたときに呼び出される。
function startDragging(event:MouseEvent):void
{
    // マウスボタンが押されたときのカーソルの位置と
    // マウスボタンが押されたときの円の x, y 座標との
    // 差を記録する。
    offsetX = event.stageX - circle.x;
    offsetY = event.stageY - circle.y;
    
    // mouseMove イベントの監視を開始するよう Flash Player に指示する。
    stage.addEventListener(MouseEvent.MOUSE_MOVE, dragCircle);
}

// この関数は、マウスボタンが離されたときに呼び出される。
function stopDragging(event:MouseEvent):void
{
    // mouseMove イベントの監視を停止するよう Flash Player に指示する。
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, dragCircle);
}

// この関数は、マウスボタンが押されている間、
// マウスを移動するたびに呼び出される。
function dragCircle(event:MouseEvent):void
{
    // カーソルの位置に円を移動し、
    // カーソルの位置とドラッグされるオブジェクトの 
    // 位置とのオフセットを保持する。
    circle.x = event.stageX - offsetX;
    circle.y = event.stageY - offsetY;

    // このイベントの後、画面を更新するよう Flash Player に指示する。
    event.updateAfterEvent();
}

circle.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
circle.addEventListener(MouseEvent.MOUSE_UP, stopDragging);

// このコードは、マウス追従方式を使用してドラッグ & ドロップ操作を
// 作成する。
// 円と四角形は DisplayObject (MovieClip または Sprite 
// インスタンスなど)。

import flash.display.DisplayObject;
import flash.events.MouseEvent;

var offsetX:Number;
var offsetY:Number;
var draggedObject:DisplayObject;

// この関数は、マウスボタンが押されたときに呼び出される。
function startDragging(event:MouseEvent):void
{
    // ドラッグ中のオブジェクトを記憶
    draggedObject = DisplayObject(event.target);
    
    // マウスボタンが押されたときのカーソルの位置と
    // マウスボタンが押されたとき、ドラッグされているオブジェクトの x, y 座標との
    // 差 (オフセット) を記録する。
    offsetX = event.stageX - draggedObject.x;
    offsetY = event.stageY - draggedObject.y;
    
    // 選択したオブジェクトを表示リストの一番上に移動
    stage.addChild(draggedObject);
    
    // mouseMove イベントの監視を開始するよう Flash Player に指示する。
    stage.addEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}

// この関数は、マウスボタンが離されたときに呼び出される。
function stopDragging(event:MouseEvent):void
{
    // mouseMove イベントの監視を停止するよう Flash Player に指示する。
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, dragObject);
}

// この関数は、マウスボタンが押されている間、
// マウスを移動するたびに呼び出される。
function dragObject(event:MouseEvent):void
{
    // ドラッグされるオブジェクトをカーソルの位置に移動し、
    // カーソルの位置とドラッグされるオブジェクトの位置との 
    // オフセットを保持する。
    draggedObject.x = event.stageX - offsetX;
    draggedObject.y = event.stageY - offsetY;
    
    // このイベントの後、画面を更新するよう Flash Player に指示する。
    event.updateAfterEvent();
}

circle.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
circle.addEventListener(MouseEvent.MOUSE_UP, stopDragging);

square.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);
square.addEventListener(MouseEvent.MOUSE_UP, stopDragging);