MIME コンテンツタイプの POST データです。

メモ : FileReference.upload() メソッドおよび FileReference.download() メソッドは URLRequest.contentType パラメータをサポートしていません。

URL リクエストで送信されるデータを含むオブジェクトです。

このプロパティは method プロパティと一緒に使用します。URLRequest.method の値が POST の場合、データは HTTP POST メソッドが指定された URLRequest オブジェクトを使用して転送されます。

URLRequest.method の値が GET の場合、データは HTTP GET メソッドが指定された URLRequest オブジェクトを使用して送信される変数を定義するものです。

URLRequest API は、ストリング以外に、バイナリ POST と URL エンコード変数もサポートします。データオブジェクト型には、ByteArray、URLVariables、または String を指定できます。

データが使用される方法は、使用されるオブジェクトの型によって異なります。

• オブジェクトが ByteArray オブジェクトの場合、ByteArray オブジェクトのバイナリデータは POST データとして使用されます。GET の場合、ByteArray 型のデータはサポートされません。FileReference.upload() および FileReference.download() の場合も、ByteArray 型のデータはサポートされません。
• オブジェクトが URLVariables オブジェクトで、メソッドが POST の場合、変数は x-www-form-urlencoded 形式を使用してエンコードされ、結果のストリングが POST データとして使用されます。例外は FileReference.upload() の呼び出しです。この場合、変数は、multipart/form-data ポストの個別のフィールドとして送信されます。
• オブジェクトが URLVariables オブジェクトで、メソッドが GET の場合、URLVariables オブジェクトは URLRequest オブジェクトによって送信される変数を定義します。
• それ以外の場合、オブジェクトはストリングに変換され、そのストリングが POST または GET データとして使用されます。

このデータは、navigateToURL() や FileReference.upload() などのメソッドで URLRequest オブジェクトが使用されるまで送信されません。

関連項目

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLVariables;

    public class URLVariablesExample extends Sprite {

        public function URLVariablesExample() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            navigateToURL(request);
        }
    }
}

HTTP フォーム送信メソッドが GET または POST のどちらの操作であるかを制御します。有効な値は、URLRequestMethod.GET または URLRequestMethod.POST です。

デフォルト値 : URLRequestMethod.GET.

関連項目

package {
    import flash.display.Sprite;
    import flash.net.navigateToURL;
    import flash.net.URLRequest;
    import flash.net.URLRequestMethod;
    import flash.net.URLVariables;

    public class URLRequest_method extends Sprite {

        public function URLRequest_method() {
            var url:String = "http://www.[yourDomain].com/application.jsp";
            var request:URLRequest = new URLRequest(url);
            
            var variables:URLVariables = new URLVariables();
            variables.exampleSessionId = new Date().getTime();
            variables.exampleUserLabel = "guest";
            request.data = variables;
            request.method = URLRequestMethod.POST;
            
            navigateToURL(request);
        }
    }
}

HTTP リクエストヘッダの配列が HTTP リクエストに追加されます。配列は URLRequestHeader オブジェクトから構成されます。配列の各オブジェクトは、次のように名前ストリングと値ストリングを含む URLRequestHeader オブジェクトである必要があります。

  var rhArray:Array = new Array(new URLRequestHeader("Content-Type", "text/html"));
  

Flash Player ではリクエストヘッダに対して一定の制限が設定されています。詳細については、URLRequestHeader クラスの説明を参照してください。

FileReference.upload() および FileReference.download() メソッドは URLRequest.requestHeaders パラメータをサポートしていません。

関連項目

リクエストされる URL です。デフォルトで、URL はサブドメインを含めて呼び出し元の SWF ファイルと同じドメインに置かれている必要があります。たとえば、www.adobe.com と store.adobe.com にある SWF ファイルは異なるドメインにあります。異なるドメインからデータをロードするには、データをホストするサーバーにクロスドメインポリシーファイルを配置します。詳細については、URLRequest クラスの説明のセキュリティに関する説明を参照してください。

メモ : IPv6 (Internet Protocol version 6) は Flash Player Update 3 以降のバージョンでサポートされます。IPv6 は、128 ビットのアドレスをサポートするインターネットプロトコルのバージョンです (32 ビットのアドレスをサポートする、以前の IPv4 プロトコルの機能を向上したものです)。ネットワークインターフェイスでの IPv6 のアクティブ化が必要になる場合があります。詳細については、データをホストするオペレーティングシステムのヘルプを参照してください。ホストしているシステムで IPv6 がサポートされる場合、次に示すように、角括弧 ([]) 内に URL の IPv6 数値リテラルアドレスを指定できます。

     rtmp://[2001:db8:ccc3:ffff:0:444d:555e:666f]:1935/test
     

URLRequest オブジェクトを作成します。System.useCodePage が true の場合、リクエストは Unicode ではなく、システムのコードページを使ってエンコードされます。System.useCodePage が false の場合、リクエストはシステムのコードページではなく、Unicode を使ってエンコードされます。

関連項目

この例を実行するには、XMLFile.xml というファイルを SWF ファイルと同じディレクトリに配置します。

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.*;

    public class URLRequestExample extends Sprite {

        public function URLRequestExample() {
            var loader:URLLoader = new URLLoader();
            configureListeners(loader);

            var request:URLRequest = new URLRequest("XMLFile.xml");
            try {
                loader.load(request);
            } catch (error:Error) {
                trace("Unable to load requested document.");
            }
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.COMPLETE, completeHandler);
            dispatcher.addEventListener(Event.OPEN, openHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            dispatcher.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpStatusHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
        }

        private function completeHandler(event:Event):void {
            var loader:URLLoader = URLLoader(event.target);
            trace("completeHandler: " + loader.data);
        }

        private function openHandler(event:Event):void {
            trace("openHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function httpStatusHandler(event:HTTPStatusEvent):void {
            trace("httpStatusHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }
    }
}