コールバックメソッドが呼び出されるオブジェクトを示します。デフォルト値はこの NetConnection インスタンスです。client プロパティを別のオブジェクトに設定すると、コールバックメソッドはそのオブジェクトで呼び出されます。

永続的な RTMP 接続を介して (true)、またはそれ以外の方法で (false) サーバーに接続されていることを示します。HTTP を介して接続された場合、このプロパティは false です。ただし、アプリケーションサーバー上の Flash Remoting サービスに接続した場合は true です。

Flash Media Server で NetConnection.connect() を正常に呼び出すために使用する、"none"、"HTTP"、"HTTPS"、"CONNECT" のいずれかのプロキシタイプです。接続がトンネリングされていない場合、この値は "none" です。HTTP を使用して接続がトンネリングされている場合は "HTTP" です。HTTPS を使用して接続がトンネリングされている場合は "HTTPS" です。また、HTTP CONNECT メソッドを使用して接続がトンネリングされている場合は "CONNECT" です。

SWF ファイルで作成された NetConnection オブジェクトのデフォルトオブジェクトのエンコードです。バイナリデータにオブジェクトを書き込むかバイナリデータからオブジェクトを読み取るときに、データの直列化に使用される AMF (Action Message Format) のバージョンが defaultObjectEncoding プロパティに示されます。これらは、ActionScript 3.0 フォーマット (ObjectEncoding.AMF3) または ActionScript 1.0 および ActionScript 2.0 フォーマット (ObjectEncoding.AMF0) です。

デフォルト値は ObjectEncoding.AMF3 です。NetConnection.defaultObjectEncoding を変更しても、既存の NetConnection インスタンスには影響せず、それ以降に作成されたインスタンスにのみ影響します。

オブジェクトエンコードを SWF ファイル全体で設定せず個別に設定するには、NetConnection オブジェクトの objectEncoding プロパティを設定します。

詳細については、objectEncoding プロパティの説明を参照してください。

関連項目

この NetConnection インスタンスのオブジェクトエンコードです。

バイナリデータにオブジェクトを書き込むかバイナリデータからオブジェクトを読み取るときに、データの直列化に使用する必要のある AMF (Action Message Format) のバージョンが defaultObjectEncoding プロパティに示されます。これらは、ActionScript 3.0 フォーマット (ObjectEncoding.AMF3) または ActionScript 1.0 および ActionScript 2.0 フォーマット (ObjectEncoding.AMF0) です。objectEncoding プロパティを設定することにより、NetConnection インスタンスの AMF のバージョンを設定します。

ActionScript 3.0 SWF ファイルで Flash Player 9 以前にリリースされたサーバーと通信する必要がある場合は、このプロパティを理解することが重要です。次の 3 つのシナリオが可能です。

• AMF3 をサポートするサーバー (たとえば、Flex Data Services 2 または Flash Media Server 3) に接続します。defaultObjectEncoding のデフォルト値は ObjectEncoding.AMF3 です。この SWF ファイルに作成されるすべての NetConnection インスタンスでは、AMF3 直列化を使用します。使用する AMF エンコーディングを Flash Player に通知する必要はありません。
• AMF3 をサポートしないサーバー (たとえば、Flash Media Server 2) に接続します。このシナリオでは、静的な NetConnection.defaultObjectEncoding プロパティを ObjectEncoding.AMF0 に設定します。この SWF ファイルに作成されるすべての NetConnection インスタンスでは、AMF0 直列化を使用します。objectEncoding プロパティを設定する必要はありません。
• 異なるエンコーディングバージョンを使用する複数のサーバーに接続する場合。defaultObjectEncoding を使用せずに、各接続の objectEncoding プロパティを使用して、接続ごとにオブジェクトエンコーディングを設定します。このプロパティを ObjectEncoding.AMF0 に設定すると、AMF0 エンコーディングを使用するサーバー (、Flash Media Server 2 など) に接続します。ObjectEncoding.AMF3 に設定すると、AMF3 エンコーディングを使用するサーバー (Flex Data Services 2 など) に接続します。

NetConnection インスタンスが接続されたら、その objectEncoding プロパティは読み取り専用になります。

サーバーへの接続に誤ったエンコーディングを使用した場合、Flash Player により netStatus イベントが送出されます。NetStatusEvent.info プロパティには、code プロパティ値 NetConnection.Connect.Failed を持つ情報オブジェクトとオブジェクトエンコードが正しくないことを示す説明が含まれています。

関連項目

サーバーへの初期接続に失敗した場合に実行する代替手段を指定します。proxyType プロパティを設定してから NetConnection.connect() メソッドを呼び出す必要があります。

指定できる値は、"none"、"HTTP"、"CONNECT"、および "best" です。

Flash Player 9 では、このプロパティのデフォルト値は "none" です。この値を変更しない場合、Flash Player は RTMPS に HTTPS トンネリングを使用します。このプロパティが "best" に設定されている場合、クライアントはネイティブ SSL を使用して接続を試みます。接続に失敗すると、別の接続方法が試みられます。プロパティが "HTTP" に設定されていて、直接接続に失敗した場合は、HTTP トンネリングが使用されます。プロパティが "CONNECT" に設定されており、直接接続に失敗した場合は、トンネリングの CONNECT メソッドが使用されます。これに失敗すると、接続は HTTP トンネリングにフォールバックされなくなります。

メモ : Flash Player 9 では、このプロパティは RTMP、RTMPS、または RTMPT を使用している場合にのみ適用できます。CONNECT メソッドは、プロキシサーバー経由でネットワークに接続しているユーザーにのみ適用できます。

NetConnection.connect() メソッドに渡された URI。NetConnection.connect() が呼び出されていない場合、または URI が渡されていない場合、このプロパティは undefined になります。

HTTPS ではなく、ネイティブ TLS を使用してセキュア接続が確立されたかどうかを示します。このプロパティは、NetConnection オブジェクトが接続されている場合にのみ有効です。

NetConnection オブジェクトを作成します。connect() オブジェクトを呼び出して接続を作成します。

SWF ファイルで Flash Player 9 以前にリリースされたサーバーと通信する必要がある場合、NetConnection オブジェクトの objectEncoding プロパティの設定作業が必要になることがあります。

関連項目

コンテキストヘッダを AMF (Action Message Format) パケット構造に追加します。このヘッダは、将来のすべての AMF パケットと共に送信されます。同じ名前を使用して NetConnection.addHeader() を呼び出すと、既存のヘッダが新しいヘッダに置き換えられます。新しいヘッダは、NetConnection オブジェクトのある間存在し続けます。ヘッダの名前を使用して NetConnection.addHeader() を呼び出し、未定義のオブジェクトを削除して、ヘッダを削除できます。

パラメータ

Flash Media Server 上または Flash Remoting を実行しているアプリケーションサーバー上のコマンドまたはメソッドを呼び出します。NetConnection.call() を呼び出す前に、NetConnection.connect() を呼び出してサーバーに接続する必要があります。このメソッドに渡すには、サーバーサイド関数を作成する必要があります。

パラメータ

ローカルで開始した接続またはサーバーへの接続を閉じ、NetConnection.Connect.Closed を code プロパティとして、netStatus イベントを送出します。

このメソッドは、接続上で実行されているすべての NetStream オブジェクトを切断します。キューに未送信のデータはすべて破棄されます。接続を閉じずにローカルまたはサーバーストリームを終了するには、NetStream.close() を使用します。接続を閉じて新しい接続を作成する場合は、新しい NetConnection オブジェクトを呼び出し、connect() メソッドをもう一度呼び出す必要があります。

close() メソッドは、この接続上で実行されているすべてのリモート共有オブジェクトも切断します。ただし、再接続するために共有オブジェクトを再作成する必要はありません。SharedObject.connect() を呼び出すだけで、共有オブジェクトへの接続を再確立できます。また、共有オブジェクトへの接続が再確立されると、NetConnection.close() を発行したときにキュー内にあった共有オブジェクトのデータがすべて送信されます。

Flash Media Server では、クライアントからサーバーへの接続が不要になったときは close() を呼び出すことをお勧めします。close() を呼び出すと、使用されていない接続が最も短時間でクリーンアップされます。予備の手段として、アイドル状態の接続を自動的に閉じるようにサーバーを設定できます。詳細については、Flash Media Server の設定と管理のガイドを参照してください。

関連項目

Flash Player と Flash Media Server アプリケーションの間に双方向の接続を作成します。NetConnection オブジェクトは、クライアントとサーバーの間のパイプに似ています。NetStream オブジェクトで、パイプを通してストリームを送信します。Flash Media Server でサポートされるコーデックとファイル形式の詳細については、Flash Media Server のマニュアルを参照してください。

Flash Media Server がない場合は、NetConnection.connect() を呼び出して、ローカルファイルシステムまたは Web サーバーからビデオファイルや MP3 ファイルを再生します。サポートされるコーデックとファイル形式の詳細については、http://www.adobe.com/go/hardware_scaling_en を参照してください。

Flash Player と Flash Remoting サービスを実行しているアプリケーションサーバーの間に双方向の接続を作成します。NetServices クラスを使用して、NetConnection オブジェクトでアプリケーションサーバーの関数を呼び出し、アプリケーションサーバーから結果を取得します。詳細については、Flash Remoting のマニュアルを参照してください。

このメソッドを使用する場合は、Flash Player セキュリティモデルおよび次のセキュリティについての考慮事項を検討してください。

• デフォルトでは、Flash Player でのサンドボックス間のアクセスは拒否されます。クロスドメインポリシーファイルを使用すると、Web サイトでリソースにアクセスできるようになります。
• アプリケーションで、サーバー上のリソースへのアクセスを拒否できます。Flash Media Server アプリケーションに、アクセスを拒否するサーバーサイドコードを追加する必要があります。詳細については、Flash Media Server のマニュアルを参照してください。
• 呼び出し元 SWF ファイルがローカルファイルシステムのサンドボックスに配置されている場合は、NetConnection.connect() を使用できません。
• SWF ファイルがこのメソッドを使用しないようにするには、SWF コンテンツを含んでいる HTML ページに allowNetworking パラメータ (object タグおよび embed タグ) を設定します。

詳細については、以下を参照してください。

• セキュリティに関する章 (『ActionScript 3.0 のプログラミング』) と LiveDocs に関する最新のコメント
• Flash Player 9 セキュリティに関するホワイトペーパー

パラメータ

関連項目

非同期形式で、つまりネイティブ非同期コードから例外がスローされると送出されます。

このイベントには、次のプロパティがあります。

入出力エラーが発生してネットワーク処理が失敗したときに送出されます。

このイベントには、次のプロパティがあります。

NetConnection オブジェクトが、そのステータスまたはエラーの状況をレポートするときに送出されます。netStatus イベントには info プロパティが含まれます。このプロパティは、接続試行が成功したかどうかなど、イベントに関する特定の情報を含む情報オブジェクトです。

このイベントには、次のプロパティがあります。

関連項目

NetConnection.call() の呼び出しによって呼び出し元のセキュリティサンドボックスの外部にあるサーバーに接続しようとすると送出されます。

このイベントには、次のプロパティがあります。

関連項目

この例では、Video オブジェクトと NetStream オブジェクトを作成し、Video.attachNetStream() メソッドと NetStream.play() メソッドを呼び出すコードがハンドラ関数に配置されます。ハンドラは、NetConnection オブジェクトとの接続が成功した場合にのみ呼び出されます。つまり、netStatus イベントが返す info オブジェクトの code プロパティが成功を示しているときです。接続に成功するまで待ってから、NetStream.play() を呼び出すことをお勧めします。

package {
    import flash.display.Sprite;
    import flash.events.NetStatusEvent;
    import flash.events.SecurityErrorEvent;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;
    import flash.events.Event;

    public class NetConnectionExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetConnectionExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Stream not found: " + videoURL);
                    break;
            }
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }

        private function connectStream():void {
            stream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.client = new CustomClient();
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }
    }
}

class CustomClient {
    public function onMetaData(info:Object):void {
        trace("metadata: duration=" + info.duration + " width=" + info.width + " height=" + info.height + " framerate=" + info.framerate);
    }
    public function onCuePoint(info:Object):void {
        trace("cuepoint: time=" + info.time + " name=" + info.name + " type=" + info.type);
    }
}