コールバックメソッドが呼び出されるオブジェクトを示します。デフォルトのオブジェクトは、作成されるローカル接続 this です。client プロパティを別のオブジェクトに設定すると、その別のオブジェクトでコールバックメソッドを呼び出すことができます。

関連項目

現在の SWF ファイルが存在するドメインを表すストリングです。

Flash Player 9 以降用にパブリッシュされた SWF では、現在の SWF ファイルのサブドメインを含むドメインを示すストリングを返します。たとえば、現在の SWF ファイルが www.adobe.com にある場合は、"www.adobe.com" を返します。

現在の SWF ファイルがクライアントコンピュータ上のローカルファイルである場合は、"localhost" を返します。

このプロパティの最も一般的な使用方法としては、送信側 LocalConnection オブジェクトのドメイン名を、受信側 LocalConnection オブジェクトで呼び出すメソッドのパラメータとして組み込みます。あるいは、LocalConnection.allowDomain() と組み合わせて使用して、特定のドメインからのコマンドを受け入れます。同じドメイン内にある LocalConnection オブジェクト間でのみ通信する場合は、通常、このプロパティを使用する必要はありません。

関連項目

LocalConnection オブジェクトを作成します。LocalConnection オブジェクトを使用すると、同じクライアントコンピュータ上で実行している異なる SWF ファイル間で通信できるようになります。

関連項目

この LocalConnection インスタンスに LocalConnection 呼び出しを送信できる 1 つ以上のドメインを指定します。

このメソッドを使用して、セキュアでないプロトコルでホストされている SWF ファイルから、セキュアなプロトコル (HTTPS) を使用してホストされている SWF ファイルへのアクセスを許可することはできません。この場合は、allowInsecureDomain() メソッドを使用してくだい。

場合によっては、このメソッドを使用して、親 SWF ファイルにドメインの不明な子 SWF ファイルからの LocalConnection 呼び出しを受け入れさせたいと思うこともあります。たとえば、ロードバランシングリダイレクトやサードパーティ製サーバーを使用する場合などです。このような場合、ロードに使用される LoaderInfo オブジェクトの url プロパティを使用すれば、allowDomain() メソッドで使用するドメインを取得できます。たとえば、Loader オブジェクトを使用して子 SWF ファイルをロードする場合、このファイルがロードされれば、Loader オブジェクトの contentLoaderInfo.url プロパティをチェックすることにより、完全な URL ストリングから子 SWF ファイルのドメインを解析できます。この場合、SWF ファイルがロードされるまで待つようにしてください。ファイルが完全にロードされるまで、contentLoaderInfo.url プロパティが最終的な正しい値に設定されないためです。

また、これとは反対の場合もあります。つまり、子 SWF ファイルにドメインの不明な親からの LocalConnection 呼び出しを受け入れさせたいという場合もあります。この場合は、ドメインパラメータがロードされた SWF ファイルの loaderInfo.url プロパティのドメインに一致するかどうかをチェックすることにより、このメソッドを実装できます。この場合も、loaderInfo.url に含まれている完全な URL からドメインを解析する必要があります。この状況では、親 SWF ファイルがロードされるまで待つ必要はありません。親 SWF ファイルは子 SWF ファイルがロードされた時点で既にロードされているからです。

このメソッドを使用するときは、Flash Player セキュリティモデルを考慮してください。デフォルトでは、LocalConnection オブジェクトはそれを作成した SWF ファイルのサンドボックスに関連づけられ、LocalConnection オブジェクトのクロスドメイン呼び出しは、受信側 SWF ファイルで LocalConnection.allowDomain() メソッドが呼び出されていない限り許可されません。

詳細については、以下を参照してください。

• セキュリティに関する章 (『ActionScript 3.0 のプログラミング』) と LiveDocs に関する最新のコメント
• Flash Player 9 セキュリティに関するホワイトペーパー

メモ : allowDomain() メソッドは、ActionScript 1.0 および 2.0 での形式から変更されています。これらの以前のバージョンでは、allowDomain は実装するコールバックメソッドでした。ActionScript 3.0 では、allowDomain() は LocalConnection のビルトインメソッドとして呼び出されます。変更された allowDomain() は flash.system.Security.allowDomain() とほぼ同じように作用します。

パラメータ

関連項目

この LocalConnection オブジェクトに LocalConnection 呼び出しを送信できる 1 つ以上のドメインを指定します。

allowInsecureDomain() メソッドは allowDomain() メソッドと同じように作用しますが、allowInsecureDomain() メソッドは、HTTPS 以外でロードされた SWF ファイルが HTTPS でロードされた SWF ファイルに LocalConnection 呼び出しを送信することも許可する点が異なります。この違いは、HTTPS を使用してロードされた SWF ファイルから allowInsecureDomain() メソッドを呼び出す場合にのみ意味があります。同じドメイン内の非 HTTPS と HTTPS の境界を越える場合でも、allowInsecureDomain() メソッドを呼び出す必要があります。デフォルトでは、同じドメイン内でも 非 HTTPS SWF ファイルから HTTPS SWF ファイルへの LocalConnection 呼び出しは許可されません。

allowInsecureDomain() を呼び出すことは、HTTPS によるセキュリティが損なわれる恐れがあるため、お勧めできません。HTTPS によって SWF ファイルをロードする場合は、SWF ファイルがネットワークによる配信中に不正操作を受けないことを十分に確信できます。非 HTTPS SWF ファイルによる HTTPS SWF ファイルへの LocalConnection 呼び出しを許可した場合、配信中に不正操作された可能性のある SWF からの呼び出しを受け付けることになります。これは、HTTPS SWF ファイルに到着した LocalConnection 呼び出しの正当性を信頼できないため、一般に特別な警戒を必要とします。

デフォルトでは、HTTPS プロトコルを使用してホストされた SWF ファイルは、HTTPS プロトコルを使用してホストされた他の SWF ファイルにのみアクセスできます。この実装方法により、HTTPS プロトコルが提供する整合性が保たれます。

このメソッドでデフォルトの動作を変更することはお勧めできません。デフォルトの動作を変更すると、HTTPS のセキュリティが損なわれます。ただし、デフォルトの動作を変更せざるをえない場合もあります。たとえば、Flash Player 9 以降用にパブリッシュされた HTTPS ファイルに対して、Flash Player 6 またはそれ以前のバージョン用にパブリッシュされた HTTP ファイルからのアクセスを許可しなければならない場合などです。

詳細については、以下を参照してください。

• セキュリティに関する章 (『ActionScript 3.0 のプログラミング』) と LiveDocs に関する最新のコメント
• Flash Player 9 セキュリティに関するホワイトペーパー

パラメータ

関連項目

LocalConnection オブジェクトを閉じます (切断します)。このコマンドは、LocalConnection オブジェクトがもうコマンドを受け入れないようにする場合に実行します。たとえば、connect() コマンドを、別の SWF ファイルで同じ connectionName パラメータを使用して実行する場合などです。

関連項目

send() コマンド (送信側 LocalConnection オブジェクト) からのコマンドを受け取るように LocalConnection オブジェクトを準備します。このコマンドを使用するオブジェクトは受信側 LocalConnection オブジェクトと呼ばれます。受信側と送信側のオブジェクトは、同じクライアントコンピュータ上で実行する必要があります。

競合状況を避けるため、このメソッドを呼び出す前に、LocalConnection クラスの例に示すように、受信側の LocalConnection オブジェクトに関連付けられているメソッドを定義します。

デフォルトでは、Flash Player は connectionName を解決して " superdomain :connectionName" の値を取得します。ここで superdomain は、connect() コマンドを含む SWF ファイルのスーパードメインを表します。たとえば、受信側 LocalConnection オブジェクトを含む SWF ファイルが www.someDomain.com に配置されている場合、connectionName は "someDomain.com:connectionName" に解決されます。SWF ファイルがクライアントコンピュータに配置されている場合、superdomain には "localhost" が割り当てられます。

またデフォルトでは、受信側 LocalConnection オブジェクトは、接続名が " superdomain :connectionName" の値に解決される送信側 LocalConnection オブジェクトからのコマンドだけを受け入れます。このため、同じドメインに置かれている SWF ファイル間の通信は簡単です。

同じドメインの SWF ファイル間のみの通信を実装する場合は、先頭がアンダースコア (_) でなくドメイン名を含まないストリングを connectionName に指定します ("myDomain:connectionName" など)。connect(connectionName) メソッドと同じストリングを使用してください。

異なるドメイン内の SWF ファイル間の通信を実装する場合は、アンダースコア (_) で始まるストリングを connectionName に指定すると、受信側 LocalConnection オブジェクトを含む SWF ファイルのドメイン間ポータビリティが高まります。考えられる 2 つの状況を次に示します。

• connectionName のストリングがアンダースコア (_) で始まっていない場合、Flash Player により、"myDomain:connectionName" のように、スーパードメインとコロンの接頭辞が追加されます。これにより、他のドメインの同じ名前を持つ接続とのコンフリクトは回避できますが、すべての送信側 LocalConnection オブジェクトは、"myDomain:connectionName" のようにこのスーパードメインを指定する必要があります。受信側 LocalConnection オブジェクトを含む SWF ファイルが別のドメインに移動された場合は、"anotherDomain:connectionName" のように、新しいスーパードメインに応じて接頭辞が変更されます。すべての送信側 LocalConnection オブジェクトは、新しいスーパードメインを参照するように手動で編集する必要があります。
• connectionName のストリングが、"_connectionName" のようにアンダースコアで始まっている場合、ストリングに接頭辞は追加されません。つまり、受信側と送信側の LocalConnection オブジェクトは、connectionName にまったく同じストリングを使用します。受信側オブジェクトが allowDomain() を使用し、どのドメインからの接続も受け入れるように指定した場合は、送信側 LocalConnection オブジェクトを変更せずに、受信側 LocalConnection オブジェクトを含む SWF ファイルを別のドメインに移動させることができます。

詳細については、クラスの概要の説明、connectionName (send()) の説明、および allowDomain() エントリと domain エントリを参照してください。

メモ : コロンは、connectionName のストリングとスーパードメインを区切る特殊文字として使用されます。connectionName にコロンを含むストリングを指定するのは無効です。

このメソッドを使用するときは、Flash Player セキュリティモデルを考慮してください。デフォルトでは、LocalConnection オブジェクトはそれを作成した SWF ファイルのサンドボックスに関連づけられ、LocalConnection オブジェクトのクロスドメイン呼び出しは、受信側 SWF ファイルで LocalConnection.allowDomain() メソッドが呼び出されていない限り許可されません。SWF ファイルがこのメソッドを使用しないようにするには、SWF コンテンツを含んでいる HTML ページに allowNetworking パラメータ (object タグおよび embed タグ) を設定します。

詳細については、以下を参照してください。

• セキュリティに関する章 (『ActionScript 3.0 のプログラミング』) と LiveDocs に関する最新のコメント
• Flash Player 9 セキュリティに関するホワイトペーパー

パラメータ

関連項目

methodName で指定されたメソッドを呼び出します。このとき connect( connectionName ) メソッド (受信側 LocalConnection オブジェクト) で確立された接続が使用されます。このコマンドを使用するオブジェクトは送信側 LocalConnection オブジェクト と呼ばれます。送信側オブジェクトと受信側オブジェクトを含む SWF ファイルは、同じクライアントコンピュータ上で実行する必要があります。

このコマンドにパラメータとして渡すことができるデータの量は 40 KB に制限されます。シンタックスが正しいにもかかわらず、send() が ArgumentError をスローする場合は、send() 要求を複数のコマンドに分割してそれぞれのデータを 40 KB より小さくしてみてください。

connect() エントリで説明されているように、デフォルトでは connectionName に現在のスーパードメインが追加されます。異なるドメイン間の通信を実装する場合は、送信側と受信側の両方の LocalConnection オブジェクトの connectionName を、現在のスーパードメインが connectionName に追加されないように定義する必要があります。これには、次の 2 つの方法があります。

• 送信側と受信側の両方の LocalConnection オブジェクトで、connectionName の先頭にアンダースコア (_) を使用します。受信側オブジェクトを含む SWF ファイルでは LocalConnection.allowDomain() を使用して、どのドメインからの接続も受け入れるように指定します。この方法では、送信側と受信側の SWF ファイルを任意のドメインに配置できます。
• 送信側 LocalConnection オブジェクトの connectionName にスーパードメインを含めます。たとえば、myDomain.com:myConnectionName と指定します。受信側オブジェクトでは、LocalConnection.allowDomain() を使用して、指定したスーパードメイン (この例では myDomain.com) からの接続を受け入れるように指定するか、またはどのドメインからの接続も受け入れるように指定します。

メモ : 受信側 LocalConnection オブジェクトの connectionName ではスーパードメインを指定できません。スーパードメインを指定できるのは送信側 LocalConnection オブジェクトだけです。

このメソッドを使用するときは、Flash Player セキュリティモデルを考慮してください。デフォルトでは、LocalConnection オブジェクトはそれを作成した SWF ファイルのサンドボックスに関連づけられ、LocalConnection オブジェクトのクロスドメイン呼び出しは、受信側 SWF ファイルで LocalConnection.allowDomain() メソッドが呼び出されていない限り許可されません。SWF ファイルがこのメソッドを使用しないようにするには、SWF コンテンツを含んでいる HTML ページに allowNetworking パラメータ (object タグおよび embed タグ) を設定します。

詳細については、以下を参照してください。

• セキュリティに関する章 (『ActionScript 3.0 のプログラミング』) と LiveDocs に関する最新のコメント
• Flash Player 9 セキュリティに関するホワイトペーパー

パラメータ

関連項目

非同期形式で、つまりネイティブ非同期コードから例外がスローされると送出されます。

このイベントには、次のプロパティがあります。

LocalConnection.send() の呼び出しで、異なるセキュリティサンドボックスにデータを送信しようとすると送出されます。

このイベントには、次のプロパティがあります。

関連項目

LocalConnection オブジェクトがステータスを報告するときに送出されます。LocalConnection.send() が正常に実行された場合、status イベントオブジェクトの level プロパティの値は "status" になります。また、呼び出しに失敗した場合、level プロパティの値は "error" になります。受信側 SWF ファイルで接続が拒否されると、送信側 SWF ファイルへの通知なしで呼び出しが失敗する可能性があります。

このイベントには、次のプロパティがあります。

関連項目

LocalConnectionSenderExample SWF ファイルでは LocalConnection インスタンスが作成され、ボタンが押されると call() メソッドを使用して SWF ファイル内の lcHandler というメソッドが呼び出されます。このとき接続名 "myConnection" が使用され、パラメータとして TextField の内容が渡されます。

LocalConnectionReceiverExample SWF ファイルでは LocalConnection インスタンスが作成され、connect() メソッドが呼び出されて、この SWF ファイルが接続名 "myConnection" 宛のメッセージの受信者に指定されます。さらにこのクラスには、lcHandler() というパブリックメソッドが含まれています。これは、LocalConnectionSenderExample SWF ファイルによって呼び出されるメソッドです。メソッドが呼び出されると、パラメータとして渡されるテキストがステージ上の TextField に追加されます。

メモ :この例をテストするには、両方の SWF ファイルを同じコンピュータ上に同時にロードする必要があります。

// Code in LocalConnectionSenderExample.as
package {
    import flash.display.Sprite;
    import flash.events.MouseEvent;
    import flash.net.LocalConnection;
    import flash.text.TextField;
    import flash.text.TextFieldType;
    import flash.events.StatusEvent;
    import flash.text.TextFieldAutoSize;

    public class LocalConnectionSenderExample extends Sprite {
        private var conn:LocalConnection;
        
        // UI elements
        private var messageLabel:TextField;
        private var message:TextField;
        private var sendBtn:Sprite;
        
        public function LocalConnectionSenderExample() {
            buildUI();
            sendBtn.addEventListener(MouseEvent.CLICK, sendMessage);
            conn = new LocalConnection();
            conn.addEventListener(StatusEvent.STATUS, onStatus);
        }
        
        private function sendMessage(event:MouseEvent):void {
            conn.send("myConnection", "lcHandler", message.text);
        }
        
        private function onStatus(event:StatusEvent):void {
            switch (event.level) {
                case "status":
                    trace("LocalConnection.send() succeeded");
                    break;
                case "error":
                    trace("LocalConnection.send() failed");
                    break;
            }
        }
        
        private function buildUI():void {
            const hPadding:uint = 5;
            // messageLabel
            messageLabel = new TextField();
            messageLabel.x = 10;
            messageLabel.y = 10;
            messageLabel.text = "Text to send:";
            messageLabel.autoSize = TextFieldAutoSize.LEFT;
            addChild(messageLabel);
            
            // message
            message = new TextField();
            message.x = messageLabel.x + messageLabel.width + hPadding;
            message.y = 10;
            message.width = 120;
            message.height = 20;
            message.background = true;
            message.border = true;
            message.type = TextFieldType.INPUT;
            addChild(message);
            
            // sendBtn
            sendBtn = new Sprite();
            sendBtn.x = message.x + message.width + hPadding;
            sendBtn.y = 10;
            var sendLbl:TextField = new TextField();
            sendLbl.x = 1 + hPadding;
            sendLbl.y = 1;
            sendLbl.selectable = false;
            sendLbl.autoSize = TextFieldAutoSize.LEFT;
            sendLbl.text = "Send";
            sendBtn.addChild(sendLbl);
            sendBtn.graphics.lineStyle(1);
            sendBtn.graphics.beginFill(0xcccccc);
            sendBtn.graphics.drawRoundRect(0, 0, (sendLbl.width + 2 + hPadding + hPadding), (sendLbl.height + 2), 5, 5);
            sendBtn.graphics.endFill();
            addChild(sendBtn);
        }
    }
}