カラーのアルファ透明度の値です。指定できる値は 0 ～ 1 です。たとえば、.25 を指定すると、透明度の値として 25% が設定されます。デフォルト値は 1 です。

水平方向のぼかし量。指定できる値は 0 ～ 255 (浮動小数) です。デフォルト値は 6 です。2 のべき乗 (2、4、8、16、32 など) は、他の値と比べて速くレンダリングできるよう最適化されます。

垂直方向のぼかし量。指定できる値は 0 ～ 255 (浮動小数) です。デフォルト値は 6 です。2 のべき乗 (2、4、8、16、32 など) は、他の値と比べて速くレンダリングできるよう最適化されます。

グローのカラーを表します。指定できる値は、16 進数形式 (0xRRGGBB) です。デフォルト値は 0xFF0000 です。

グローが内側グローであるかどうかを示します。true の場合は、内側グローであることを示します。デフォルトは false (外側グロー) で、オブジェクトの外側のエッジにあるグローを示します。

オブジェクトにノックアウト効果を適用するかどうかを指定します。true を指定すると、オブジェクトの塗りが透明になり、ドキュメントの背景色が表示されます。デフォルト値は false (ノックアウト効果なし) です。

フィルタを適用する回数。デフォルト値は、フィルタを 1 回適用することに相当する BitmapFilterQuality.LOW です。値 BitmapFilterQuality.MEDIUM はフィルタを 2 回適用します。値 BitmapFilterQuality.HIGH はフィルタを 3 回適用します。フィルタに設定された値が小さいほど、速くレンダリングできます。

多くのアプリケーションでは、quality の値は低、中、または高で十分です。最大 15 までの値を使用してさまざまな効果を出すことができますが、値が大きくなるほどレンダリング速度が低下します。quality の値を増やす代わりに、blurX と blurY の値を増やすだけで、同様の効果が得られます。この方法を実行すると、より高速にレンダリングされます。

関連項目

インプリントの強さまたは広がりです。値が大きいほど、濃い色がインプリントされるので、グローと背景との間のコントラストが強くなります。指定できる値は 0 ～ 255 です。デフォルトは 2 です。

指定されたパラメータで新しい GlowFilter インスタンスを初期化します。

関連項目

このフィルタオブジェクトのコピーを返します。

1. 必要なクラスを読み込みます。
2. draw メソッドで使用する 3 つのプロパティを宣言し、Sprite の graphics プロパティを介してアクセスする Graphics クラスのメソッドを使用して、オレンジ色の四角形を描画します。
3. コンストラクタ関数を作成します。この関数は、次の処理を行います。
   • draw メソッドを呼び出します。
   • filter という名前の新しい BitmapFilter オブジェクトを作成し、このオブジェクトに getBitmapFilter() の呼び出しによる戻り値を割り当てます。これでフィルタが定義されます。
   • myFilters という名前の新しい配列を作成し、それに filter を追加します。
   • myFilters を BevelFilterExample オブジェクトの filters プロパティに割り当てます。これにより、myFilters で見つかったすべてのフィルタが適用されます。この場合は、filter だけです。

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.GlowFilter;

    public class GlowFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function GlowFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var color:Number = 0x33CCFF;
            var alpha:Number = 0.8;
            var blurX:Number = 35;
            var blurY:Number = 35;
            var strength:Number = 2;
            var inner:Boolean = false;
            var knockout:Boolean = false;
            var quality:Number = BitmapFilterQuality.HIGH;

            return new GlowFilter(color,
                                  alpha,
                                  blurX,
                                  blurY,
                                  strength,
                                  quality,
                                  inner,
                                  knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}