ベベルの角度です。有効な値の範囲は 0 ～ 360°です。デフォルト値は 45°です。

角度の値は、オブジェクトに対する架空の光源の角度を表し、オブジェクトに対する効果の相対位置を決定します。distance プロパティが 0 に設定された場合、効果がオブジェクトからオフセットされないため、angle プロパティは適用されません。

水平方向のぼかし量 (ピクセル単位) です。指定できる値は 0 ～ 255 (浮動小数) です。デフォルト値は 4 です。2 のべき乗 (2、4、8、16、32 など) は、他の値と比べて速くレンダリングできるよう最適化されます。

垂直方向のぼかし量 (ピクセル単位) です。指定できる値は 0 ～ 255 (浮動小数) です。デフォルト値は 4 です。2 のべき乗 (2、4、8、16、32 など) は、他の値と比べて速くレンダリングできるよう最適化されます。

ベベルのオフセット距離です。この値はピクセル単位で指定します (浮動小数値)。デフォルトは 4 です。

ハイライトカラーのアルファ透明度の値です。値には、0 ～ 1 の正規化した値を指定します。たとえば、.25 を指定すると、透明度の値として 25% が設定されます。デフォルト値は 1 です。

ベベルのハイライトカラーです。指定できる値は、16 進数形式 (0xRRGGBB) です。デフォルト値は 0xFFFFFF です。

true の場合は、ノックアウト効果を適用します。その結果、オブジェクトの塗りが透明になり、ドキュメントの背景色が表示されます。デフォルト値は false (ノックアウトなし) です。

フィルタを適用する回数。デフォルト値は、フィルタを 1 回適用することに相当する BitmapFilterQuality.LOW です。値 BitmapFilterQuality.MEDIUM はフィルタを 2 回適用します。値 BitmapFilterQuality.HIGH はフィルタを 3 回適用します。フィルタに設定された値が小さいほど、速くレンダリングできます。

多くのアプリケーションでは、quality の値は低、中、または高で十分です。最大 15 までの値を使用してさまざまな効果を出すことができますが、値が大きくなるほどレンダリング速度が低下します。quality の値を増やす代わりに、blurX と blurY の値を増やすだけで、同様の効果が得られます。この方法を実行すると、より高速にレンダリングされます。

次の BitmapFilterQuality 定数を使用して、quality プロパティの値を指定できます。

• BitmapFilterQuality.LOW
• BitmapFilterQuality.MEDIUM
• BitmapFilterQuality.HIGH

シャドウカラーのアルファ透明度の値です。この値には、0 ～ 1 に正規化した値を指定します。たとえば、.25 を指定すると、透明度の値として 25% が設定されます。デフォルトは 1 です。

ベベルのシャドウカラーです。指定できる値は、16 進数形式 (0xRRGGBB) です。デフォルト値は 0x000000 です。

インプリントの強さまたは広がりです。有効な値の範囲は 0 ～ 255 です。値が大きいほど、濃い色がインプリントされるので、ベベルと背景との間のコントラストが強くなります。デフォルト値は 1 です。

オブジェクトでのベベルの配置です。内側および外側のベベルは、内側または外側のエッジに配置され、フルベベルはオブジェクト全体に配置されます。指定できる値は、次の BitmapFilterType 定数です。

• BitmapFilterType.INNER
• BitmapFilterType.OUTER
• BitmapFilterType.FULL

指定されたパラメータで新しい BevelFilter インスタンスを初期化します。

関連項目

このフィルタオブジェクトのコピーを返します。

1. 必要なクラスを読み込みます。
2. draw() 関数で使用する 3 つのプロパティを宣言します。この関数は、ベベルフィルタを適用するオブジェクトを描画します。
3. BevelFilterExample() コンストラクタ関数を作成します。この関数は、次の処理を行います。
   • draw() 関数を呼び出します。この関数は後で宣言されます。
   • filter 変数を BitmapFilter オブジェクトとして宣言し、これを getBitmapFilter() を呼び出した戻り値に割り当てます。
   • 新しい配列オブジェクト myFilters を作成し、その配列に filter を追加します。さらに myFilters を BevelFilterExample オブジェクトの filters プロパティに割り当てます。これにより、myFilters で見つかったすべてのフィルタが適用されます。この場合は、filter だけです。
4. getBitmapFilter 関数を作成して、フィルタのプロパティを作成して設定します。
5. draw() 関数を作成します。この関数は、Sprite クラスの graphics プロパティを介してアクセスする Graphics クラスのメソッドを使用して、四角形を描画します。

package {
    import flash.display.Sprite;
    import flash.filters.BevelFilter;
    import flash.filters.BitmapFilter;
    import flash.filters.BitmapFilterQuality;
    import flash.filters.BitmapFilterType;

    public class BevelFilterExample extends Sprite {
        private var bgColor:uint = 0xFFCC00;
        private var size:uint    = 80;
        private var offset:uint  = 50;

        public function BevelFilterExample() {
            draw();
            var filter:BitmapFilter = getBitmapFilter();
            var myFilters:Array = new Array();
            myFilters.push(filter);
            filters = myFilters;
        }

        private function getBitmapFilter():BitmapFilter {
            var distance:Number       = 5;
            var angleInDegrees:Number = 45;
            var highlightColor:Number = 0xFFFF00;
            var highlightAlpha:Number = 0.8;
            var shadowColor:Number    = 0x0000FF;
            var shadowAlpha:Number    = 0.8;
            var blurX:Number          = 5;
            var blurY:Number          = 5;
            var strength:Number       = 5;
            var quality:Number        = BitmapFilterQuality.HIGH;
            var type:String           = BitmapFilterType.INNER;
            var knockout:Boolean      = false;

            return new BevelFilter(distance,
                                   angleInDegrees,
                                   highlightColor,
                                   highlightAlpha,
                                   shadowColor,
                                   shadowAlpha,
                                   blurX,
                                   blurY,
                                   strength,
                                   quality,
                                   type,
                                   knockout);
        }

        private function draw():void {
            graphics.beginFill(bgColor);
            graphics.drawRect(offset, offset, size, size);
            graphics.endFill();
        }
    }
}