flash.events.Event (ActionScript 3.0)

	プロパティ	定義元
		bubbles : Boolean [read-only] イベントがバブリングイベントかどうかを示します。	Event
		cancelable : Boolean [read-only] イベントに関連付けられた動作を回避できるかどうかを示します。	Event
		constructor : Object 特定のオブジェクトインスタンスのクラスオブジェクトまたはコンストラクタ関数への参照です。	Object
		currentTarget : Object [read-only] イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。	Event
		eventPhase : uint [read-only] イベントフローの現在の段階です。	Event
		prototype : Object [static] クラスまたは関数オブジェクトのプロトタイプオブジェクトへの参照です。	Object
		target : Object [read-only] イベントターゲットです。	Event
		type : String [read-only] イベントのタイプです。	Event

	メソッド	定義元
		Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false) イベントリスナーにパラメータとして渡す Event オブジェクトを作成します。	Event
		clone():Event Event サブクラスのインスタンスを複製します。	Event
		formatToString(className:String, ... arguments):String カスタム Event クラスに toString() メソッドを実装するためのユーティリティ関数です。	Event
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isDefaultPrevented():Boolean イベントで preventDefault() が呼び出されたかどうかを確認します。	Event
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメータとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		preventDefault():void イベントのデフォルトの動作をキャンセルできる場合に、その動作をキャンセルします。	Event
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し列挙できるかどうかを示します。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		stopImmediatePropagation():void イベントフローの現在のノードおよび後続するノードで、イベントリスナーが処理されないようにします。	Event
		stopPropagation():void イベントフローの現在のノードに後続するノードで、イベントリスナーが処理されないようにします。	Event
		toString():String Event オブジェクトのすべてのプロパティを含むストリングを返します。	Event
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

	定数	定義元
		ACTIVATE : String = "activate" [static] activate イベントオブジェクトの type プロパティ値を定義します。	Event
		ADDED : String = "added" [static] added イベントオブジェクトの type プロパティ値を定義します。	Event
		ADDED_TO_STAGE : String = "addedToStage" [static] addedToStage イベントオブジェクトの type プロパティ値を定義します。	Event
		CANCEL : String = "cancel" [static] cancel イベントオブジェクトの type プロパティ値を定義します。	Event
		CHANGE : String = "change" [static] change イベントオブジェクトの type プロパティ値を定義します。	Event
		CLOSE : String = "close" [static] close イベントオブジェクトの type プロパティ値を定義します。	Event
		COMPLETE : String = "complete" [static] complete イベントオブジェクトの type プロパティ値を定義します。	Event
		CONNECT : String = "connect" [static] connect イベントオブジェクトの type プロパティ値を定義します。	Event
		DEACTIVATE : String = "deactivate" [static] deactivate イベントオブジェクトの type プロパティ値を定義します。	Event
		ENTER_FRAME : String = "enterFrame" [static] enterFrame イベントオブジェクトの type プロパティ値を定義します。	Event
		FULLSCREEN : String = "fullScreen" [static] fullScreen イベントオブジェクトの type プロパティ値を定義します。	Event
		ID3 : String = "id3" [static] id3 イベントオブジェクトの type プロパティ値を定義します。	Event
		INIT : String = "init" [static] init イベントオブジェクトの type プロパティの値を定義します。	Event
		MOUSE_LEAVE : String = "mouseLeave" [static] mouseLeave イベントオブジェクトの type プロパティ値を定義します。	Event
		OPEN : String = "open" [static] open イベントオブジェクトの type プロパティ値を定義します。	Event
		REMOVED : String = "removed" [static] removed イベントオブジェクトの type プロパティ値を定義します。	Event
		REMOVED_FROM_STAGE : String = "removedFromStage" [static] removedFromStage イベントオブジェクトの type プロパティ値を定義します。	Event
		RENDER : String = "render" [static] render イベントオブジェクトの type プロパティ値を定義します。	Event
		RESIZE : String = "resize" [static] resize イベントオブジェクトの type プロパティ値を定義します。	Event
		SCROLL : String = "scroll" [static] scroll イベントオブジェクトの type プロパティ値を定義します。	Event
		SELECT : String = "select" [static] select イベントオブジェクトの type プロパティ値を定義します。	Event
		SOUND_COMPLETE : String = "soundComplete" [static] soundComplete イベントオブジェクトの type プロパティ値を定義します。	Event
		TAB_CHILDREN_CHANGE : String = "tabChildrenChange" [static] tabChildrenChange イベントオブジェクトの type プロパティ値を定義します。	Event
		TAB_ENABLED_CHANGE : String = "tabEnabledChange" [static] tabEnabledChange イベントオブジェクトの type プロパティ値を定義します。	Event
		TAB_INDEX_CHANGE : String = "tabIndexChange" [static] tabIndexChange イベントオブジェクトの type プロパティ値を定義します。	Event
		UNLOAD : String = "unload" [static] unload イベントオブジェクトの type プロパティ値を定義します。	Event

プロパティの詳細

bubbles

プロパティ

bubbles:Boolean [read-only]

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントがバブリングイベントかどうかを示します。イベントがバブル可能な場合、この値は true です。バブル不可能な場合は、false です。

イベントが発生すると、イベントフローの 3 つの段階に進みます。表示リストの一番上の階層からターゲットノードの直前までのキャプチャ段階、ターゲットノードに対応するターゲット段階、ターゲットノードの次のノードから表示リスト階層に戻るまでのバブリング段階があります。

activate イベントや unload イベントなど一部のイベントにはバブリング段階がありません。バブリング段階のないイベントの bubbles プロパティの値は false です。

実装
public function get bubbles():Boolean

関連項目

イベントオブジェクト

cancelable

プロパティ

cancelable:Boolean [read-only]

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントに関連付けられた動作を回避できるかどうかを示します。動作がキャンセル可能な場合、この値は true です。キャンセル不可能な場合は、false です。

実装
public function get cancelable():Boolean

関連項目

Event.preventDefault()
イベントオブジェクト

currentTarget

プロパティ

currentTarget:Object [read-only]

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。たとえば、ユーザーが [OK] ボタンをクリックした場合、currentTarget は、そのボタンまたは、そのイベントに対してイベントリスナーを登録している祖先の 1 つを含むノードになります。

実装
public function get currentTarget():Object

関連項目

イベントオブジェクト

eventPhase

プロパティ

eventPhase:uint [read-only]

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントフローの現在の段階です。このプロパティには、次の数値が含まれます。

1 はキャプチャ段階 (EventPhase.CAPTURING_PHASE)
2 はターゲット段階 (EventPhase.AT_TARGET)
3 はバブリング段階 (EventPhase.BUBBLING_PHASE)

実装
public function get eventPhase():uint

関連項目

イベントオブジェクト

target

プロパティ

target:Object [read-only]

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントターゲットです。このプロパティにはターゲットノードが含まれます。たとえば、ユーザーが [OK] ボタンをクリックした場合、ターゲットノードはそのボタンを含む表示リストノードです。

実装
public function get target():Object

関連項目

イベントオブジェクト

type

プロパティ

type:String [read-only]

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントのタイプです。タイプでは大小文字が区別されます。

実装
public function get type():String

関連項目

イベントオブジェクト

コンストラクタの詳細

Event

()

コンストラクタ

public function Event(type:String, bubbles:Boolean = false, cancelable:Boolean = false)

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントリスナーにパラメータとして渡す Event オブジェクトを作成します。

パラメータ

	`type:String` — `Event.type` としてアクセス可能なイベントタイプです。

	`bubbles:Boolean` (default = `false`) — Event オブジェクトがイベントフローのバブリング段階で処理されるかどうかを判断します。デフォルト値は `false` です。

	`cancelable:Boolean` (default = `false`) — Event オブジェクトがキャンセル可能かどうかを判断します。デフォルト値は `false` です。

メソッドの詳細

clone

()

メソッド

public function clone():Event

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

Event サブクラスのインスタンスを複製します。

Event オブジェクトの元のインスタンスのコピーである、新しい Event オブジェクトを返します。通常、clone() を呼び出さないでください。イベントを再送出すると、つまり、ハンドラから dispatchEvent(event) を呼び出すと (このハンドラは event を処理しているハンドラ)、EventDispatcher クラスが自動的にこのメソッドを呼び出します。

新しい Event オブジェクトには、元のオブジェクトのすべてのプロパティが含まれます。

カスタム Event クラスを作成する場合は、カスタムクラスのプロパティが複製されるように、継承された Event.clone() メソッドをオーバーライドする必要があります。イベントサブクラスに追加するすべてのプロパティを設定しなかった場合、再送出されたイベントをリスナーが処理するときに、プロパティに正しい値が含まれません。

この例では、PingEvent は Event のサブクラスであるため、独自のバージョンの clone() を実装します。

  class PingEvent extends Event { var URL:String; public override function clone():Event { return new PingEvent(type, bubbles, cancelable, URL); } }

戻り値

Event — 元のオブジェクトと同一の新しい Event オブジェクトです。

関連項目

イベントオブジェクト

formatToString

()

メソッド

public function formatToString(className:String, ... arguments):String

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

カスタム Event クラスに toString() メソッドを実装するためのユーティリティ関数です。toString() メソッドのオーバーライドを推奨しますが、必須ではありません。

  class PingEvent extends Event { var URL:String; public override function toString():String { return formatToString("PingEvent", "type", "bubbles", "cancelable", "eventPhase", "URL"); } }

パラメータ

	`className:String` — カスタム Event クラスの名前です。上の例では、`className` パラメータは `PingEvent` です。

	`... arguments` — Event クラスのプロパティとカスタム Event クラスに追加するプロパティです。上の例では、`...arguments` パラメータに、`type`、`bubbles`、`cancelable`、`eventPhase`、および `URL` が含まれます。

戻り値

String — カスタム Event クラスの名前と ...arguments パラメータのストリング値です。

isDefaultPrevented

()

メソッド

public function isDefaultPrevented():Boolean

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントで preventDefault() が呼び出されたかどうかをチェックします。preventDefault() が呼び出された場合は true、それ以外の場合は false を返します。

戻り値

Boolean — preventDefault() が呼び出された場合は true、それ以外の場合は false を返します。

preventDefault

()

メソッド

public function preventDefault():void

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントのデフォルトの動作をキャンセルできる場合に、その動作をキャンセルします。

多くのイベントには、Flash Player がデフォルトで実行する動作が関連付けられています。たとえば、ユーザーがテキストフィールドに文字を入力した場合、デフォルト動作では文字がテキストフィールドに表示されます。TextEvent.TEXT_INPUT イベントのデフォルト動作はキャンセルできるため、preventDefault() メソッドを使用して文字を表示しないようにすることができます。

キャンセルできない動作の例としては、Event.REMOVED イベントに関連付けられているデフォルト動作があります。このイベントは、Flash Player が表示リストから表示オブジェクトを削除しようとすると生成されます。このデフォルト動作 (要素の削除) はキャンセルできません。つまり、preventDefault() メソッドはこのデフォルト動作には効果がありません。

Event.cancelable プロパティを使用して、特定のイベントに関連付けられているデフォルト動作をキャンセルできるかどうかを確認できます。Event.cancelable の値が true の場合、preventDefault() を使用してイベントをキャンセルできます。それ以外の場合、preventDefault() の効果はありません。

stopImmediatePropagation

()

メソッド

public function stopImmediatePropagation():void

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントフローの現在のノードおよび後続するノードで、イベントリスナーが処理されないようにします。このメソッドはすぐに有効になり、現在のノードのイベントリスナーに影響します。これに対し、stopPropagation() メソッドは、現在のノードのイベントリスナーの処理がすべて終了するまで有効になりません。

メモ : このメソッドは、このイベントに関連付けられている動作をキャンセルしません。その機能については、「preventDefault()」を参照してください。

stopPropagation

()

メソッド

public function stopPropagation():void

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

イベントフローの現在のノードに後続するノードで、イベントリスナーが処理されないようにします。このメソッドは、現在のノード (currentTarget) のイベントリスナーには影響しません。これに対し、stopImmediatePropagation() メソッドは、現在のノードとそれ以降のノードで、イベントリスナーが処理されないようにします。このメソッドを繰り返し呼び出しても影響はありません。このメソッドは、イベントフローの任意の段階で呼び出すことができます。

toString

()

メソッド

public function toString():String

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

Event オブジェクトのすべてのプロパティを含むストリングを返します。ストリングは次の形式です。

[Event type=value bubbles=value cancelable=value]

戻り値

String — Event オブジェクトのすべてのプロパティを含むストリングです。

関連項目

イベントオブジェクト

定数の詳細

ACTIVATE

定数

public static const ACTIVATE:String = "activate"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (activate イベントオブジェクト) の値を定義します。

メモ :このイベントは "キャプチャ段階" を通過せず、ターゲットが表示リストにあるかどうかに関わらず、ターゲットに直接送出されます。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	ACTIVATE イベントに対するリスナーが登録された任意の DisplayObject インスタンスです。

ADDED

定数

public static const ADDED:String = "added"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (added イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`true`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	表示リストに追加される DisplayObejct インスタンスです。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

ADDED_TO_STAGE

定数

public static const ADDED_TO_STAGE:String = "addedToStage"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9.0.28.0

type プロパティ (addedToStage イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	直接または DisplayObject インスタンスが含まれているサブツリーを追加することで、オンステージ表示リストに追加される DisplayObject インスタンスです。DisplayObject インスタンスが直接追加される場合、このイベントの前に `added` イベントが発生します。

CANCEL

定数

public static const CANCEL:String = "cancel"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (cancel イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	操作をキャンセルするオブジェクトへの参照です。

関連項目

flash.net.FileReference.cancel

CHANGE

定数

public static const CHANGE:String = "change"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (change イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`true`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	値が変更されたオブジェクトです。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

定数

public static const CLOSE:String = "close"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (close イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	接続が閉じられたオブジェクトです。

COMPLETE

定数

public static const COMPLETE:String = "complete"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (complete イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	ロードが完了したネットワークオブジェクトです。

CONNECT

定数

public static const CONNECT:String = "connect"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (connect イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	ネットワーク接続を確立した Socket オブジェクトまたは XMLSocket オブジェクトです。

DEACTIVATE

定数

public static const DEACTIVATE:String = "deactivate"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (deactivate イベントオブジェクト) の値を定義します。

メモ :このイベントは "キャプチャ段階" を通過せず、ターゲットが表示リストにあるかどうかに関わらず、ターゲットに直接送出されます。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	DEACTIVATE イベントに対するリスナーが登録された任意の DisplayObject インスタンスです。

ENTER_FRAME

定数

public static const ENTER_FRAME:String = "enterFrame"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (enterFrame イベントオブジェクト) の値を定義します。

メモ :このイベントは "キャプチャ段階" を通過せず、ターゲットが表示リストにあるかどうかに関わらず、ターゲットに直接送出されます。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	ENTER_FRAME イベントに対するリスナーが登録された任意の DisplayObject インスタンスです。

関連項目

flash.display.DisplayObject.enterFrame

FULLSCREEN

定数

public static const FULLSCREEN:String = "fullScreen"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (fullScreen イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	Stage オブジェクトです。

関連項目

flash.display.Stage.fullScreen

ID3

定数

public static const ID3:String = "id3"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (id3 イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	ID3 データが現在使用可能な MP3 をロードしている Sound オブジェクトです。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

関連項目

flash.media.Sound.id3

INIT

定数

public static const INIT:String = "init"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (init イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	ロードする SWF ファイルに関係のある LoaderInfo オブジェクトです。

関連項目

flash.display.LoaderInfo.init

MOUSE_LEAVE

定数

public static const MOUSE_LEAVE:String = "mouseLeave"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (mouseLeave イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	Stage オブジェクトです。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

OPEN

定数

public static const OPEN:String = "open"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (open イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	接続をオープンしたネットワークオブジェクトです。

REMOVED

定数

public static const REMOVED:String = "removed"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (removed イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`true`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	表示リストから削除される DisplayObejct インスタンスです。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

REMOVED_FROM_STAGE

定数

public static const REMOVED_FROM_STAGE:String = "removedFromStage"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9.0.28.0

type プロパティ (removedFromStage イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	直接または DisplayObject インスタンスが含まれているサブツリーを削除することで、オンステージ表示リストから削除される DisplayObject インスタンスです。DisplayObject インスタンスが直接削除される場合、このイベントの前に `removed` イベントが発生します。

RENDER

定数

public static const RENDER:String = "render"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (render イベントオブジェクト) の値を定義します。

メモ :このイベントは "キャプチャ段階" を通過せず、ターゲットが表示リストにあるかどうかに関わらず、ターゲットに直接送出されます。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、デフォルトの動作をキャンセルできないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	RENDER イベントに対するリスナーが登録された任意の DisplayObject インスタンスです。

RESIZE

定数

public static const RESIZE:String = "resize"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (resize イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	Stage オブジェクトです。

関連項目

flash.display.Stage.resize

SCROLL

定数

public static const SCROLL:String = "scroll"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (scroll イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	スクロールされた TextField オブジェクトです。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

関連項目

flash.text.TextField.scroll

SELECT

定数

public static const SELECT:String = "select"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (select イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	アイテムが選択された FileReference オブジェクトです。

関連項目

flash.net.FileReference.select

SOUND_COMPLETE

定数

public static const SOUND_COMPLETE:String = "soundComplete"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (soundComplete イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	サウンドの再生が終了した Sound オブジェクトです。

関連項目

flash.media.SoundChannel.soundComplete

TAB_CHILDREN_CHANGE

定数

public static const TAB_CHILDREN_CHANGE:String = "tabChildrenChange"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (tabChildrenChange イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`true`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	tabChildren フラグが変更されたオブジェクトです。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

TAB_ENABLED_CHANGE

定数

public static const TAB_ENABLED_CHANGE:String = "tabEnabledChange"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (tabEnabledChange イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`true`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	tabEnabled フラグが変更された InteractiveObject です。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

TAB_INDEX_CHANGE

定数

public static const TAB_INDEX_CHANGE:String = "tabIndexChange"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (tabIndexChange イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`true`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	tabIndex が変更されたオブジェクトです。`target` は、必ずしもイベントリスナーを登録した表示リスト内のオブジェクトとは限りません。現在イベントを処理している表示リスト内のオブジェクトにアクセスするには、`currentTarget` プロパティを使用します。

UNLOAD

定数

public static const UNLOAD:String = "unload"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9

type プロパティ (unload イベントオブジェクト) の値を定義します。

このイベントには、次のプロパティがあります。

プロパティ	値
`bubbles`	`false`
`cancelable`	`false` は、キャンセルするデフォルトの動作がないことを示します。
`currentTarget`	イベントリスナーで Event オブジェクトをアクティブに処理しているオブジェクトです。
`target`	アンロードまたは置き換える SWF ファイルに関係のある LoaderInfo オブジェクトです。

関連項目

flash.display.LoaderInfo.unload

例例の使用法

EventExample.as

次の例では、EventExample クラスと Square カスタムクラスを使用して、イベントバブリングを管理する方法を示します。

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;

    public class EventExample extends Sprite {
        
        public function EventExample() {
            var square_0:Square = new Square(300, 0x336633);
            addChild(square_0);
            
            var square_1:Square = new Square(250, 0x669966);
            square_0.addChild(square_1);

            var square_2:Square = new Square(200, 0x66CC66);
            square_1.addChild(square_2);

            var square_3:Square = new Square(150, 0xAA0000);
            square_3.shouldBubble = false;
            square_2.addChild(square_3);

            var square_4:Square = new Square(100, 0x66FF66);
            square_3.addChild(square_4);

            var square_5:Square = new Square(50, 0xCC0000);
            square_5.shouldBubble = false;
            square_4.addChild(square_5);

            this.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        
        private function clickHandler(e:Event):void {
            trace(">> stage: " + e.type + " event from " + e.target.name + " called on " + this.name);
            trace(">> --------------------------------------------");
        }
    }
}

import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

class Square extends Sprite {
    private var sideLen:int;
    private var color:Number;
    public var shouldBubble:Boolean = true;

    public function Square(sideLen:int, color:Number) {
        this.sideLen = sideLen;
        this.color = color;
        init();
        draw();
    }
        
    private function init():void {
        buttonMode = true;
        this.addEventListener(MouseEvent.CLICK, firstClickHandler);
        this.addEventListener(MouseEvent.CLICK, secondClickHandler);
        this.addEventListener(MouseEvent.CLICK, thirdClickHandler);
    }
        
    private function draw():void {
        this.graphics.beginFill(color);
        this.graphics.drawRect(0, 0, sideLen, sideLen);
    }
        
    private function firstClickHandler(e:Event):void {
        trace(">> 1e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopPropagation();
        }
    }

    private function secondClickHandler(e:Event):void {
        trace(">> 2e: " + e.type + " event from " + e.target.name + " called on " + this.name);
        if(!shouldBubble) {
            e.stopImmediatePropagation();
            trace(">> --------------------------------------------");
        }
    }

    private function thirdClickHandler(e:Event):void {
        trace(">> 3e: " + e.type + " event from " + e.target.name + " called on " + this.name);
    }
}

EventExample2.as

次の例では、ADDED イベントと ADDED_TO_STAGE イベントの相違、および REMOVED イベントと REMOVED_FROM_STAGE イベントの相違を示すインタラクティブなデモンストレーションを作成します。スプラインをクリックすると、そのスプラインと、その中にネストされているものがすべてステージから削除されます。たとえば、最も大きなスプラインをクリックすると、1つの REMOVED イベントと 3 つの REMOVED_FROM_STAGE イベントが発生します。

 package {
    import flash.display.Sprite;
    import flash.events.*;

    public class EventExample2 extends Sprite {
        public function EventExample2():void {
            var parentSprite:Sprite = createSprite("parentSprite",200);
            var childSprite:Sprite = createSprite("childSprite",100);
            var childOfChildSprite:Sprite = createSprite("childOfChildSprite",50);
            
            trace(":: Adding to Stage ::");
            this.addChild(parentSprite);
            trace(":: Adding to Stage ::");
            parentSprite.addChild(childSprite);
            trace(":: Adding to Stage ::");
            childSprite.addChild(childOfChildSprite);
        }
        private function createSprite(name:String,size:uint):Sprite {
            trace(":: Creating Sprite ::");
            var newSprite:Sprite = new Sprite();
            newSprite.name = name;
            newSprite.graphics.beginFill(0xFFFFFF * Math.random(),1);
            newSprite.graphics.drawRect(0,0,size,size);
            newSprite.graphics.endFill();
            newSprite.addEventListener(Event.ADDED, spriteAdded);
            newSprite.addEventListener(Event.ADDED_TO_STAGE, spriteAddedToStage);
            newSprite.addEventListener(Event.REMOVED, spriteRemoved);
            newSprite.addEventListener(Event.REMOVED_FROM_STAGE, spriteRemovedFromStage);
            newSprite.addEventListener(MouseEvent.CLICK, remove);
            return newSprite;
        }
        private function remove(event:Event) {
            if(event.target == event.currentTarget) {
                trace(":: Removing Clicked Sprite ::");
                var target:Sprite = Sprite(event.target);
                target.parent.removeChild(target);
            }
        }
        private function spriteRemovedFromStage(event:Event):void {
            trace("REMOVED_FROM_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteRemoved(event:Event):void {
            trace("REMOVED: " + event.target.name + " from " + event.currentTarget.name);
        }
        private function spriteAddedToStage(event:Event):void {
            trace("ADDED_TO_STAGE: " + event.target.name + " : " + event.currentTarget.name);
        }
        private function spriteAdded(event:Event):void {
            trace("ADDED: " + event.target.name + " within " + event.currentTarget.name);
        }
    }
}

現在のページ: http://livedocs.adobe.com/flash/9.0_jp/ActionScriptLangRefV3/flash/events/Event.html

ActionScript 3.0 コンポーネントリファレンスガイド		すべてのパッケージ \| すべてのクラス \| 言語エレメント \| 索引 \| 付録 \| 規則 \| フレームフレームなし
Event	プロパティ \| メソッド \| 定数 \| 例

パッケージ	flash.events
クラス	public class Event
継承	Event Object
サブクラス	ActivityEvent, CaptionChangeEvent, CaptionTargetEvent, ColorPickerEvent, ComponentEvent, ContextMenuEvent, DataChangeEvent, FocusEvent, HTTPStatusEvent, KeyboardEvent, LayoutEvent, ListEvent, MetadataEvent, MotionEvent, MouseEvent, NetStatusEvent, ProgressEvent, ScrollEvent, SliderEvent, SoundEvent, StatusEvent, SyncEvent, TextEvent, TimerEvent, TweenEvent, VideoEvent