import fl.controls.CheckBox;
import fl.controls.ScrollPolicy;
import fl.controls.TextArea;

var str:String;

var plainTextArea:TextArea = new TextArea();
plainTextArea.verticalScrollPolicy = ScrollPolicy.ON;
plainTextArea.setSize(260, 360);
plainTextArea.move(10, 10);
addChild(plainTextArea);

var htmlTextArea:TextArea = new TextArea();
htmlTextArea.verticalScrollPolicy = ScrollPolicy.ON;
htmlTextArea.condenseWhite = true;
htmlTextArea.setSize(260, 360);
htmlTextArea.move(280, 10);
addChild(htmlTextArea);

var condenseCheckBox:CheckBox = new CheckBox();
condenseCheckBox.textField.autoSize = TextFieldAutoSize.LEFT;
condenseCheckBox.label = "condenseWhite:";
condenseCheckBox.selected = htmlTextArea.condenseWhite;
condenseCheckBox.move(htmlTextArea.x, htmlTextArea.y + htmlTextArea.height);
condenseCheckBox.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(condenseCheckBox);

var urlLdr:URLLoader = new URLLoader();
urlLdr.addEventListener(Event.COMPLETE, completeHandler);
urlLdr.dataFormat = URLLoaderDataFormat.TEXT;
urlLdr.load(new URLRequest("http://www.helpexamples.com/flash/lorem.html"));

function completeHandler(event:Event):void {
    str = event.target.data as String;
    plainTextArea.text = str;
    htmlTextArea.htmlText = str;
}

function clickHandler(event:MouseEvent):void {
    var sel:Boolean = event.currentTarget.selected;
    htmlTextArea.condenseWhite = sel;
    htmlTextArea.htmlText = str;
}

import fl.controls.TextArea;
import fl.controls.ScrollPolicy;

var myTextArea:TextArea = new TextArea();
myTextArea.wordWrap = false;
myTextArea.horizontalScrollPolicy = ScrollPolicy.ON;
myTextArea.text = "The quick brown fox jumped over the lazy dog.";
myTextArea.setSize(320, 120);
myTextArea.move(10, 10);
addChild(myTextArea);

import fl.controls.TextArea;

var myText:String = "";
myText += "<p>You can use the <b> tag to create <b>bold</b> text.</p>";
myText += "<p>You can use the <i> tag to create <i>italic</i> text.</p>";
myText += "<p>You can use the <u> tag to create <u>underlined</a> text.</p>";
myText += "<p>You can use the <a> tag to create <a href='http://www.adobe.com'>links to other sites</a>.</p>";
myText += "<p>You can use the <br> tag to create<br>new lines of text<br>whenever you want.</p>";
myText += "<p>You can use the <font> tag to specificy different font <font color='#FF0000'>colors</font>, <font size='16'>sizes</font>, or <font face='Times New Roman'>faces</font>.</p>";
myText += "<p>You can use the <img> tag to load images or SWF files:<br><img src='http://www.helpexamples.com/flash/images/logo.png'>.</p>";

var myTextArea:TextArea = new TextArea();
myTextArea.htmlText = myText;
myTextArea.setSize(320, 240);
myTextArea.move(10, 10);
addChild(myTextArea);

import fl.controls.TextArea;

var str:String = "<p>Check out the following links:</p>";
str += "<li><a href=\"event:flash\"><u>Flash</u></a></li>";
str += "<li><a href=\"event:flex\"><u>Flex</u></a></li>";
str += "<li><a href=\"event:devnet\"><u>Developer Center</u></a></li>";

var myTextArea:TextArea = new TextArea();
myTextArea.htmlText += str;
myTextArea.setSize(320, 120);
myTextArea.move(10, 10);
myTextArea.addEventListener(TextEvent.LINK, linkHandler);
addChild(myTextArea);

function linkHandler(event:TextEvent):void {
    var url:String = "http://www.adobe.com/go/" + event.text;
    var urlReq:URLRequest = new URLRequest(url);
    navigateToURL(urlReq);
}

import fl.controls.Label;
import fl.controls.TextArea;

var myTextArea:TextArea = new TextArea();
myTextArea.maxChars = 500;
myTextArea.setSize(320, 240);
myTextArea.move(10, 10);
myTextArea.addEventListener(TextEvent.TEXT_INPUT, textInputHandler);
addChild(myTextArea);

var charCountLabel:Label = new Label();
charCountLabel.autoSize = TextFieldAutoSize.LEFT;
charCountLabel.move(myTextArea.x, myTextArea.y + myTextArea.height);
addChild(charCountLabel);

charCountLabel.text = myTextArea.length + " of " + myTextArea.maxChars;

function textInputHandler(event:TextEvent):void {
    updateCount();
}

function updateCount():void {
    charCountLabel.text = myTextArea.length + " of " + myTextArea.maxChars;
}

import fl.controls.Label;
import fl.controls.TextArea;

var myTextArea:TextArea = new TextArea()
myTextArea.setSize(320, 240);
myTextArea.move(10, 10);
myTextArea.addEventListener(Event.CHANGE, changeHandler);
addChild(myTextArea);

var widthLabel:Label = new Label();
widthLabel.autoSize = TextFieldAutoSize.LEFT;
widthLabel.text = "textWidth: " + myTextArea.textWidth;
widthLabel.move(340, 10);
addChild(widthLabel);

var heightLabel:Label = new Label();
heightLabel.autoSize = TextFieldAutoSize.LEFT;
heightLabel.text = "textHeight: " + myTextArea.textHeight;
heightLabel.move(340, 30);
addChild(heightLabel);

function changeHandler(event:Event):void {
    widthLabel.text = "textWidth: " + myTextArea.textWidth;
    heightLabel.text = "textHeight: " + myTextArea.textHeight;
}

import fl.controls.Label;
import fl.controls.TextArea;

var myTextArea:TextArea = new TextArea()
myTextArea.setSize(320, 240);
myTextArea.move(10, 10);
myTextArea.addEventListener(Event.CHANGE, changeHandler);
addChild(myTextArea);

var widthLabel:Label = new Label();
widthLabel.autoSize = TextFieldAutoSize.LEFT;
widthLabel.text = "textWidth: " + myTextArea.textWidth;
widthLabel.move(340, 10);
addChild(widthLabel);

var heightLabel:Label = new Label();
heightLabel.autoSize = TextFieldAutoSize.LEFT;
heightLabel.text = "textHeight: " + myTextArea.textHeight;
heightLabel.move(340, 30);
addChild(heightLabel);

function changeHandler(event:Event):void {
    widthLabel.text = "textWidth: " + myTextArea.textWidth;
    heightLabel.text = "textHeight: " + myTextArea.textHeight;
}

import fl.controls.TextArea;
import fl.events.ScrollEvent;

var myTextArea:TextArea = new TextArea();
myTextArea.setSize(160, 120);
myTextArea.move(10, 10);
myTextArea.verticalScrollBar.pageSize = 1;
myTextArea.addEventListener(ScrollEvent.SCROLL, scrollHandler);
addChild(myTextArea);

var myURLLoader:URLLoader = new URLLoader();
myURLLoader.addEventListener(Event.COMPLETE, completeHandler);
myURLLoader.load(new URLRequest("http://www.helpexamples.com/flash/lorem.txt"));

function scrollHandler(event:ScrollEvent):void {
    trace("scroll: " + myTextArea.verticalScrollPosition + " of " + myTextArea.maxVerticalScrollPosition);
}

function completeHandler(event:Event):void {
    var txt:String = URLLoader(event.currentTarget).data as String;
    myTextArea.text = txt;
}

import fl.controls.TextArea;
import fl.controls.ScrollPolicy;

var myTextArea:TextArea = new TextArea();
myTextArea.verticalScrollPolicy = ScrollPolicy.ON;
myTextArea.text = "The quick brown fox jumped over the lazy dog.";
myTextArea.setSize(160, 120);
myTextArea.move(10, 10);
addChild(myTextArea);

import fl.controls.ScrollPolicy;
import fl.controls.Slider;
import fl.controls.SliderDirection
import fl.controls.TextArea;
import fl.events.ScrollEvent;
import fl.events.SliderEvent;

var myTextArea:TextArea = new TextArea();
myTextArea.horizontalScrollPolicy = ScrollPolicy.OFF;
myTextArea.verticalScrollPolicy = ScrollPolicy.OFF;
myTextArea.setSize(320, 240);
myTextArea.move(10, 10);
myTextArea.addEventListener(ScrollEvent.SCROLL, scrollHandler);
addChild(myTextArea)

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.snapInterval = 1;
mySlider.tickInterval = 1;
mySlider.width = myTextArea.width;
mySlider.move(myTextArea.x, myTextArea.y + myTextArea.height + 10);

var urlLdr:URLLoader = new URLLoader();
urlLdr.addEventListener(Event.COMPLETE, completeHandler);
urlLdr.dataFormat = URLLoaderDataFormat.TEXT;
urlLdr.load(new URLRequest("http://www.helpexamples.com/flash/text/lorem.txt"));

function completeHandler(event:Event):void {
    var txt:String = event.target.data as String;
    myTextArea.text = txt;
    myTextArea.drawNow();

    mySlider.minimum = myTextArea.verticalScrollPosition;
    mySlider.maximum = myTextArea.maxVerticalScrollPosition;
    mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
    addChild(mySlider);
}

function scrollHandler(event:ScrollEvent):void {
    trace("scrolled:");
    mySlider.value = event.position;
}

function changeHandler(event:SliderEvent):void {
    trace("changed:");
    myTextArea.verticalScrollPosition = event.value;
}

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

import fl.controls.ScrollBarDirection;
import fl.controls.TextArea;
import fl.events.ScrollEvent;

var myTextArea:TextArea = new TextArea();
myTextArea.setSize(320, 240);
myTextArea.move(10, 10);
myTextArea.addEventListener(ScrollEvent.SCROLL, scrollHandler);
addChild(myTextArea);

var urlLdr:URLLoader = new URLLoader();
urlLdr.addEventListener(Event.COMPLETE, completeHandler);
urlLdr.dataFormat = URLLoaderDataFormat.TEXT;
urlLdr.load(new URLRequest("http://www.helpexamples.com/flash/text/lorem.txt"));

function completeHandler(event:Event):void {
    var txt:String = event.target.data as String;
    myTextArea.text = txt;
}

function scrollHandler(event:ScrollEvent):void {
    var myTA:TextArea = event.currentTarget as TextArea;
    var pos:Number = event.position;
    var maxPos:Number;
    
    if (event.direction == ScrollBarDirection.VERTICAL) {
        maxPos = myTA.maxVerticalScrollPosition;
    } else {
        maxPos = myTA.maxHorizontalScrollPosition;
    }
    trace("scroll: " + event.direction + " (" + pos.toFixed(2) + " of " + maxPos + ")");
}