fl.controls.ProgressBarMode (ActionScript 3.0)

	プロパティ	定義元
		constructor : Object 特定のオブジェクトインスタンスのクラスオブジェクトまたはコンストラクタ関数への参照です。	Object
		prototype : Object [static] クラスまたは関数オブジェクトのプロトタイプオブジェクトへの参照です。	Object

	メソッド	定義元
		hasOwnProperty(name:String):Boolean オブジェクトに指定されたプロパティが定義されているかどうかを示します。	Object
		isPrototypeOf(theClass:Object):Boolean Object クラスのインスタンスが、パラメータとして指定されたオブジェクトのプロトタイプチェーン内にあるかどうかを示します。	Object
		propertyIsEnumerable(name:String):Boolean 指定されたプロパティが存在し列挙できるかどうかを示します。	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void ループ処理に対するダイナミックプロパティの可用性を設定します。	Object
		toString():String 指定されたオブジェクトのストリング表現を返します。	Object
		valueOf():Object 指定されたオブジェクトのプリミティブな値を返します。	Object

	定数	定義元
		EVENT : String = "event" [static] source プロパティで指定されたコンポーネントは、進捗と完了のイベントを送出する必要があります。	ProgressBarMode
		MANUAL : String = "manual" [static] ProgressBar コンポーネントの状態を手動で更新します。	ProgressBarMode
		POLLED : String = "polled" [static] 進行状況はソースをポーリングして更新されます。	ProgressBarMode

定数の詳細

EVENT

定数

public static const EVENT:String = "event"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9.0.28.0

source プロパティで指定されたコンポーネントは、progress および complete イベントを送出する必要があります。ProgressBar はこれらのイベントを使用して、状態を更新します。

例

次の例では、ProgressBar、Label、および UILoader コンポーネントインスタンスを作成し、イメージのロードの進行状況を表示します。


import fl.containers.UILoader;
import fl.controls.Label;
import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;
import fl.events.ComponentEvent;

var url:String = "http://www.helpexamples.com/flash/images/image2.jpg";

var myUILoader:UILoader = new UILoader();
myUILoader.visible = false;
myUILoader.scaleContent = false;
myUILoader.autoLoad = false;
myUILoader.source = url;
myUILoader.addEventListener(ComponentEvent.RESIZE, resizeHandler);
myUILoader.load();

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.mode = ProgressBarMode.EVENT;
myProgressBar.indeterminate = false;
myProgressBar.source = myUILoader;
myProgressBar.setSize(320, 12);
myProgressBar.move((stage.stageWidth - myProgressBar.width) / 2, (stage.stageHeight - myProgressBar.height) / 2);
myProgressBar.addEventListener(Event.COMPLETE, completeHandler);
myProgressBar.addEventListener(ProgressEvent.PROGRESS, progressHandler);
addChild(myProgressBar);

var myLabel:Label = new Label();
myLabel.text = "";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.move(myProgressBar.x, myProgressBar.y + myProgressBar.height);
addChild(myLabel);

function progressHandler(event:ProgressEvent):void {
    trace("progress:", event.bytesLoaded, "of", event.bytesTotal, "bytes");
    myLabel.text = event.bytesLoaded + " of " + event.bytesTotal + " (" + event.currentTarget.percentComplete.toFixed(1) + "%)";
}

function completeHandler(event:Event):void {
    trace("complete:");
    removeChild(myLabel);
    removeChild(myProgressBar);
    myProgressBar.removeEventListener(ProgressEvent.PROGRESS, progressHandler);
    myProgressBar.removeEventListener(Event.COMPLETE, completeHandler);
    addChild(myUILoader);
}

function resizeHandler(event:ComponentEvent):void {
    trace("resize:");
    var myUILdr:UILoader = event.currentTarget as UILoader;
    myUILdr.move((stage.stageWidth - myUILdr.width) / 2, (stage.stageHeight - myUILdr.height) / 2);
    myUILdr.visible = true;
}

MANUAL

定数

public static const MANUAL:String = "manual"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9.0.28.0

ProgressBar コンポーネントの状態を手動で更新します。このモードでは、minimum プロパティと maximum プロパティを指定し、setProgress() メソッドを使用して状態を指定します。

例

次の例では、プログレスバーのステータスを表示する ProgressBar および Label コンポーネントインスタンスを作成します。


import fl.controls.Label;
import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.indeterminate = false;
myProgressBar.mode = ProgressBarMode.MANUAL;
myProgressBar.maximum = 256;
myProgressBar.setSize(320, 16);
myProgressBar.move(10, 10)
addChild(myProgressBar);

var myLabel:Label = new Label();
myLabel.text = "";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.move(myProgressBar.x, myProgressBar.y + myProgressBar.height);
addChild(myLabel);

var t:Timer = new Timer(150);
t.addEventListener(TimerEvent.TIMER, timerHandler);
t.start();

function timerHandler(event:TimerEvent):void {
    myProgressBar.setProgress(myProgressBar.value + 1, myProgressBar.maximum);
    if (myProgressBar.percentComplete == 100) {
        myProgressBar.setProgress(0, myProgressBar.maximum);
    }
    myLabel.text = int(myProgressBar.value) + " of " + int(myProgressBar.maximum) + " (" + int(myProgressBar.percentComplete) + "%)";
}

POLLED

定数

public static const POLLED:String = "polled"

言語バージョン :

ActionScript 3.0

Player のバージョン :

Flash Player 9.0.28.0

進行状況はソースをポーリングして更新されます。source プロパティで、bytesLoaded プロパティと bytesTotal プロパティを公開するオブジェクトを指定する必要があります。

例

次の例では、ProgressBar を使用して FLV ファイルのロードの進行状況を表示します。


import fl.controls.ProgressBar;
import fl.controls.ProgressBarMode;

var url:String = "http://www.helpexamples.com/flash/video/cuepoints.flv";

var nc:NetConnection = new NetConnection();
nc.connect(null);

var ns:NetStream = new NetStream(nc);
ns.client = {onMetaData:metaDataHandler};
ns.play(url);

var vid:Video = new Video();
vid.attachNetStream(ns);
vid.x = (stage.stageWidth - vid.width) / 2;
vid.y = (stage.stageHeight - vid.height) / 2;
addChild(vid);

var myProgressBar:ProgressBar = new ProgressBar();
myProgressBar.mode = ProgressBarMode.POLLED;
myProgressBar.indeterminate = false;
myProgressBar.source = ns;
myProgressBar.setSize(vid.width, myProgressBar.height);
myProgressBar.move(vid.x, vid.y + vid.height);
addChild(myProgressBar);

function metaDataHandler(meta:Object):void {
    try {
        trace("w:" + meta.width, "h:" + meta.height);
        vid.width = meta.width;
        vid.height = meta.height;
        vid.x = (stage.stageWidth - vid.width) / 2;
        vid.y = (stage.stageHeight - vid.height) / 2;
        myProgressBar.width = vid.width;
        myProgressBar.move(vid.x, vid.y + vid.height);
    } catch (error:*) {
        // 
    }
}

現在のページ: http://livedocs.adobe.com/flash/9.0_jp/ActionScriptLangRefV3/fl/controls/ProgressBarMode.html

ActionScript 3.0 コンポーネントリファレンスガイド		すべてのパッケージ \| すべてのクラス \| 言語エレメント \| 索引 \| 付録 \| 規則 \| フレームフレームなし
ProgressBarMode	プロパティ \| メソッド \| 定数

パッケージ	fl.controls
クラス	public class ProgressBarMode
継承	ProgressBarMode Object