import fl.controls.ComboBox;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();

var cb:ComboBox = new ComboBox();
cb.dataProvider = dp;
addChild(cb);

var counter = 0;
var t:Timer = new Timer(500);
t.addEventListener(TimerEvent.TIMER,addAnotherItem);
t.start();

function addAnotherItem(e:TimerEvent = null):void {
    dp.addItem( { label: "Item " + counter++ } );
}

import fl.controls.ComboBox;
import fl.controls.Slider;
import fl.events.SliderEvent;

var mySlider:Slider = new Slider();
mySlider.minimum = 50;
mySlider.maximum = 150;
mySlider.liveDragging = true;
mySlider.snapInterval = 5;
mySlider.tickInterval = 10;
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
mySlider.move(10, 10);
addChild(mySlider);

var myComboBox:ComboBox = new ComboBox();
myComboBox.addItem({label:"Item A"});
myComboBox.addItem({label:"Item B"});
myComboBox.move(10, 30);
addChild(myComboBox);

mySlider.value = myComboBox.dropdownWidth;

function changeHandler(event:SliderEvent):void {
    myComboBox.dropdownWidth = event.value;
}

import fl.controls.ComboBox;

var myComboBox:ComboBox = new ComboBox();
myComboBox.addItem({label:"The quick brown fox"});
myComboBox.addItem({label:"Lorem ipsum"});
myComboBox.addItem({label:"Little Miss Muffet"});
myComboBox.addItem({label:"Goldilocks and the three bears"});
myComboBox.addItem({label:"Jack and Jill"});
myComboBox.move(10, 30);
addChild(myComboBox);

var maxLength:Number = 0;
var i:uint;
for (i = 0; i < myComboBox.length; i++) {
    myComboBox.selectedIndex = i;
    myComboBox.drawNow();
    var currText:String = myComboBox.text;
    var currWidth:Number = myComboBox.textField.textWidth;
    maxLength = Math.max(currWidth, maxLength);
    trace(currText, currWidth, maxLength);
}

myComboBox.selectedIndex = -1;
myComboBox.dropdownWidth = maxLength + 20;
myComboBox.open();

import fl.controls.ComboBox;
import fl.data.DataProvider;
import fl.events.ComponentEvent;

var dp:DataProvider = new DataProvider();

var myComboBox:ComboBox = new ComboBox;
myComboBox.dataProvider = dp;
myComboBox.editable = true;
myComboBox.addEventListener(ComponentEvent.ENTER, enterHandler);
myComboBox.move(10, 10);
addChild(myComboBox);

function enterHandler(event:ComponentEvent):void {
    var myCB:ComboBox = event.currentTarget as ComboBox;
    dp.addItem({label:myCB.text});
    myCB.text = "";
    myCB.sortItemsOn("label", Array.CASEINSENSITIVE);
}

import fl.controls.ComboBox;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem({firstName:"Jane", lastName:"Doe"}); 
dp.addItem({firstName:"Bill", lastName:"Smith"});
dp.addItem({firstName:"Tim", lastName:"Jones"});
dp.sortOn(["firstName","lastName"]);

var myComboBox:ComboBox = new ComboBox();
myComboBox.dataProvider = dp;
myComboBox.labelField = "firstName";
myComboBox.move(10, 10);
addChild(myComboBox);

import fl.data.DataProvider;
import fl.controls.List;

var myDataProvider:DataProvider = new DataProvider();
myDataProvider.addItem({name:"User A", price:0.43});
myDataProvider.addItem({name:"User B", price:0.34});

var users:List = new List();
users.dataProvider = myDataProvider;
users.labelFunction = myLabelFunction;
addChild(users);

function myLabelFunction(item:Object):String {
    return  item.name + " ($" + item.price.toFixed(2) + ")";
}

import fl.controls.ComboBox;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem({firstName:"Jane", lastName:"Doe"}); 
dp.addItem({firstName:"Bill", lastName:"Smith"});
dp.addItem({firstName:"Tim", lastName:"Jones"});
dp.sortOn(["lastName", "firstName"]);

var myComboBox:ComboBox = new ComboBox();
myComboBox.dataProvider = dp;
myComboBox.labelFunction = nameLabelFunction;
myComboBox.move(10, 10);
addChild(myComboBox);

function nameLabelFunction(item:Object):String {
    return item.lastName + ", " + item.firstName;
}

import fl.controls.ComboBox;

var myComboBox:ComboBox = new ComboBox();
myComboBox.addItem({label:"Item A"});
myComboBox.addItem({label:"Item B"});
myComboBox.addItem({label:"Item C"});
myComboBox.addItem({label:"Item D"});
myComboBox.addItem({label:"Item E"});
myComboBox.addItem({label:"Item F"});
myComboBox.rowCount = myComboBox.length / 2;
addChild(myComboBox);

import fl.controls.ComboBox;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem({label:"Item A"});
dp.addItem({label:"Item B"});
dp.addItem({label:"Item C"});
dp.addItem({label:"Item D"});
dp.addItem({label:"Item E"});
dp.addItem({label:"Item F"});

var myComboBox:ComboBox = new ComboBox();
myComboBox.dataProvider = dp;
myComboBox.rowCount = myComboBox.length / 2;
addChild(myComboBox);

import fl.controls.ComboBox;

var cbStyles:Object = ComboBox.getStyleDefinition();
var bW:Number = cbStyles.buttonWidth as Number

var myComboBox:ComboBox = new ComboBox();
myComboBox.prompt = "Please select an option...";
myComboBox.addItem({label:"Option 1"});
myComboBox.addItem({label:"Option 2"});
myComboBox.drawNow();
myComboBox.width = myComboBox.textField.textWidth + 35;
myComboBox.dropdownWidth = myComboBox.width - bW;
myComboBox.move(10, 10);
addChild(myComboBox);

import fl.controls.ComboBox;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem({label:"Getting Started"});
dp.addItem({label:"New Features"});
dp.addItem({label:"ActionScript"});
dp.addItem({label:"Components"});
dp.sortOn("label", Array.CASEINSENSITIVE);

var myComboBox:ComboBox = new ComboBox();
myComboBox.prompt = "Topics (" + dp.length + ")";
myComboBox.dataProvider = dp;
myComboBox.width = 150;
myComboBox.move(10, 10);
addChild(myComboBox);

import fl.controls.ComboBox;
import fl.data.DataProvider;
import fl.events.ComponentEvent;

var dp:DataProvider = new DataProvider();

var myComboBox:ComboBox = new ComboBox();
myComboBox.dataProvider = dp;
myComboBox.editable = true;
myComboBox.restrict = "0-9A-F";
myComboBox.textField.maxChars = 6;
myComboBox.addEventListener(ComponentEvent.ENTER, enterHandler);
myComboBox.move(10, 10);
addChild(myComboBox);

function enterHandler(event:ComponentEvent):void {
    var colorStr:String = ComboBox(event.currentTarget).text;
    var colorNum:uint = uint("0x" + colorStr);
    dp.addItem({label:colorStr, value:colorNum});
    dp.sortOn("value", Array.NUMERIC);
    event.currentTarget.text = "";
}

import fl.controls.ComboBox;
import fl.controls.Slider;
import fl.events.SliderEvent;

var numItems:uint = 8;

var mySlider:Slider = new Slider();
mySlider.tickInterval = 1;
mySlider.snapInterval = 1;
mySlider.minimum = 1;
mySlider.maximum = numItems;
mySlider.liveDragging = true;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

var myComboBox:ComboBox = new ComboBox();
myComboBox.move(10, 30);
addChild(myComboBox);

var i:uint;
for (i = 0; i < numItems; i++) {
    myComboBox.addItem({label:"Item " + i});
}

function changeHandler(event:SliderEvent):void {
    myComboBox.rowCount = event.value;
}

import fl.controls.ComboBox;
import fl.controls.Slider;
import fl.data.DataProvider;
import fl.events.SliderEvent;

var items:XML = <items>
        <item label="Item 1" />
        <item label="Item 2" />
        <item label="Item 3" />
        <item label="Item 4" />
    </items>;

var dp:DataProvider = new DataProvider(items);

var mySlider:Slider = new Slider();
mySlider.liveDragging = true;
mySlider.tickInterval = 1;
mySlider.snapInterval = 1;
mySlider.minimum = 0;
mySlider.maximum = dp.length - 1;
mySlider.width = 100;
mySlider.move(10, 10);
mySlider.addEventListener(SliderEvent.CHANGE, changeHandler);
addChild(mySlider);

var myComboBox:ComboBox = new ComboBox();
myComboBox.dataProvider = dp;
myComboBox.move(10, 30);
addChild(myComboBox);

function changeHandler(event:SliderEvent):void {
    myComboBox.selectedIndex = event.value;
}

import fl.controls.ComboBox;
import fl.controls.Label;

var myComboBox:ComboBox = new ComboBox();
myComboBox.prompt = "Please select an item...";
myComboBox.addItem({label:"Item 1"});
myComboBox.addItem({label:"Item 2"});
myComboBox.addItem({label:"Item 3"});
myComboBox.addItem({label:"Item 4"});
myComboBox.width = 150;
myComboBox.move(10, 10);
myComboBox.addEventListener(Event.CHANGE, changeHandler);
addChild(myComboBox);

var myLabel:Label = new Label();
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.text = "selectedIndex:" + myComboBox.selectedIndex;
myLabel.move(myComboBox.x + myComboBox.width + 10, myComboBox.y);
addChild(myLabel);

function changeHandler(event:Event):void {
    myLabel.text = "selectedIndex:" + myComboBox.selectedIndex;
}

import fl.controls.Button;
import fl.controls.ComboBox;
import fl.controls.List;

var myComboBox:ComboBox = new ComboBox();
myComboBox.prompt = "Select an item";
myComboBox.addItem({label:"Item A"});
myComboBox.addItem({label:"Item B"});
myComboBox.addItem({label:"Item C"});
myComboBox.move(10, 10);
addChild(myComboBox);

var myButton:Button = new Button();
myButton.label = "Copy";
myButton.move(myComboBox.x + myComboBox.width + 10, myComboBox.y);
myButton.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(myButton);

var myList:List = new List();
myList.rowCount = myList.length;
myList.selectable = false;
myList.move(myComboBox.x, myComboBox.y + myComboBox.height + 10);
addChild(myList);

function clickHandler(event:MouseEvent):void {
    if (myComboBox.selectedIndex > -1) {
        myList.addItem(myComboBox.selectedItem);
        myList.rowCount = myList.length;
    }
}

import fl.controls.ComboBox;
import fl.controls.Label;

var myComboBox:ComboBox = new ComboBox();
myComboBox.prompt = "Select a user:";
myComboBox.addItem({firstName:"Jane", lastName:"Doe"}); 
myComboBox.addItem({firstName:"Bill", lastName:"Smith"});
myComboBox.addItem({firstName:"Tim", lastName:"Jones"});
myComboBox.labelFunction = nameLabelFunction;
myComboBox.width = 120;
myComboBox.move(10, 10);
myComboBox.addEventListener(Event.CHANGE, changeHandler);
addChild(myComboBox);

var firstNameLabel:Label = new Label();
firstNameLabel.text = "";
firstNameLabel.autoSize = TextFieldAutoSize.LEFT;
firstNameLabel.move(myComboBox.x, myComboBox.y + myComboBox.height);
addChild(firstNameLabel);

var lastNameLabel:Label = new Label();
lastNameLabel.text = "";
lastNameLabel.autoSize = TextFieldAutoSize.LEFT;
lastNameLabel.move(firstNameLabel.x, firstNameLabel.y + firstNameLabel.height);
addChild(lastNameLabel);

function changeHandler(event:Event):void {
    var cb:ComboBox = event.currentTarget as ComboBox;
    var item:Object = cb.selectedItem;
    if (cb.selectedIndex > -1) {
        firstNameLabel.text = item.firstName;
        lastNameLabel.text = item.lastName;
    }
}

function nameLabelFunction(item:Object):String {
    return item.lastName + ", " + item.firstName;
}

import fl.controls.ComboBox;
import fl.controls.Label;

var myComboBox:ComboBox = new ComboBox();
myComboBox.prompt = "Select a user:";
myComboBox.addItem({firstName:"Jane", lastName:"Doe"}); 
myComboBox.addItem({firstName:"Bill", lastName:"Smith"});
myComboBox.addItem({firstName:"Tim", lastName:"Jones"});
myComboBox.labelFunction = nameLabelFunction;
myComboBox.width = 120;
myComboBox.move(10, 10);
myComboBox.addEventListener(Event.CHANGE, changeHandler);
addChild(myComboBox);

var myLabel:Label = new Label();
myLabel.text = "";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.move(myComboBox.x, myComboBox.y + myComboBox.height);
addChild(myLabel);

function changeHandler(event:Event):void {
    var cb:ComboBox = event.currentTarget as ComboBox;
    myLabel.text = "selectedLabel: " + cb.selectedLabel;
}

function nameLabelFunction(item:Object):String {
    return item.lastName + ", " + item.firstName;
}

import fl.controls.ComboBox;
import fl.controls.TextArea;
import fl.events.ComponentEvent;

var myComboBox:ComboBox = new ComboBox();
myComboBox.editable = true;
myComboBox.addEventListener(TextEvent.TEXT_INPUT, textInputHandler);
myComboBox.addEventListener(ComponentEvent.ENTER, enterHandler);
myComboBox.width = 300;
myComboBox.move(10, 10);
addChild(myComboBox);

var myTextArea:TextArea = new TextArea();
myTextArea.wordWrap = false;
myTextArea.setSize(300, 200);
myTextArea.move(myComboBox.x, myComboBox.y + myComboBox.height + 10);
addChild(myTextArea)

function textInputHandler(event:TextEvent):void {
    myTextArea.appendText(event.type + ":\n");
    myTextArea.appendText("\t" + event.currentTarget.text + "\n");
    myTextArea.appendText("\t" + event.text + "\n");
    myTextArea.appendText("\n");
    
    autoScroll(myTextArea);
}

function enterHandler(event:ComponentEvent):void {
    myTextArea.appendText(event.type + ":\n");
    myTextArea.appendText("\t" + event.currentTarget.text + "\n");
    myTextArea.appendText("\n");
    autoScroll(myTextArea);
}

function autoScroll(ta:TextArea):void {
    ta.verticalScrollPosition = ta.maxVerticalScrollPosition;
}

import fl.controls.ComboBox;

var myComboBox:ComboBox = new ComboBox();
myComboBox.editable = true;
myComboBox.textField.maxChars = 8;
myComboBox.move(10, 10);
addChild(myComboBox);

import fl.controls.ComboBox;

var comicSansTF:TextFormat = new TextFormat();
comicSansTF.font = "Comic Sans MS";

var myComboBox:ComboBox = new ComboBox();
myComboBox.textField.setStyle("textFormat", comicSansTF);
myComboBox.addItem({label:"Item A"});
myComboBox.addItem({label:"Item B"});
myComboBox.addItem({label:"Item C"});
myComboBox.addItem({label:"Item D"});
myComboBox.move(10, 10);
addChild(myComboBox);

import fl.controls.ComboBox;
import fl.data.DataProvider;

var myTextFormat:TextFormat = new TextFormat();
myTextFormat.font = "Comic Sans MS";
myTextFormat.color = 0xFF0000;

var fontArray:Array = Font.enumerateFonts(true);
fontArray.sortOn("fontName", Array.CASEINSENSITIVE);

var dp:DataProvider = new DataProvider(fontArray);

var myComboBox:ComboBox = new ComboBox();
myComboBox.dataProvider = dp;
myComboBox.dropdown.iconField = null;
myComboBox.labelField = "fontName";
myComboBox.textField.setStyle("textFormat", myTextFormat);
myComboBox.dropdown.setRendererStyle("textFormat", myTextFormat);
myComboBox.width = 200;
myComboBox.move(10, 10);
addChild(myComboBox);

import fl.controls.ComboBox;
import fl.controls.Label;

var myComboBox:ComboBox = new ComboBox();
myComboBox.prompt = "Select a user:";
myComboBox.addItem({firstName:"Jane", lastName:"Doe"}); 
myComboBox.addItem({firstName:"Bill", lastName:"Smith"});
myComboBox.addItem({firstName:"Tim", lastName:"Jones"});
myComboBox.labelFunction = nameLabelFunction;
myComboBox.width = 120;
myComboBox.move(10, 10);
myComboBox.addEventListener(Event.CHANGE, changeHandler);
myComboBox.editable = true;
addChild(myComboBox);

var myLabel:Label = new Label();
myLabel.text = "";
myLabel.autoSize = TextFieldAutoSize.LEFT;
myLabel.move(myComboBox.x, myComboBox.y + myComboBox.height);
addChild(myLabel);

function changeHandler(event:Event):void {
    var cb:ComboBox = event.currentTarget as ComboBox;
    myLabel.text = "value: " + cb.value;
}

function nameLabelFunction(item:Object):String {
    var str:String;
    if (item == null) {
        str = myComboBox.value;
    } else {
        str = item.lastName + ", " + item.firstName;
    }
    return str;
}

import fl.controls.ComboBox;

var myComboBox:ComboBox = new ComboBox();
myComboBox.addItem({label:"Item 1"});
myComboBox.addItem({label:"Item 2"});
myComboBox.addItem({label:"Item 3"});
myComboBox.move(10, 10);
myComboBox.addEventListener(Event.OPEN, openHandler);
myComboBox.addEventListener(Event.CLOSE, closeHandler);
addChild(myComboBox);

var isOpen:Boolean = false;

var timer:Timer = new Timer(1000);
timer.addEventListener(TimerEvent.TIMER, timerHandler);
timer.start();

function openHandler(event:Event):void {
    isOpen = true;
}

function closeHandler(event:Event):void {
    isOpen = false;
}

function timerHandler(event:TimerEvent):void {
    if (isOpen) {
        myComboBox.close();
    } else {
        myComboBox.open();
    }
}

import fl.controls.ComboBox;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;

var myComboBox:ComboBox = new ComboBox();
myComboBox.addItem({label:"Item 1", price:0.34});
myComboBox.addItem({label:"Item 2", price:13.19});
myComboBox.addItem({label:"item 3", price:2.96});
myComboBox.addItem({label:"Item 4", price:3.49});
myComboBox.addItem({label:"Item 5", price:1.27});
myComboBox.move(10, 10);
addChild(myComboBox);

var indexCol:DataGridColumn = new DataGridColumn("index");
indexCol.headerText = "";
indexCol.sortOptions = Array.NUMERIC;

var labelCol:DataGridColumn = new DataGridColumn("label");
labelCol.sortOptions = Array.CASEINSENSITIVE;

var priceCol:DataGridColumn = new DataGridColumn("price");
priceCol.sortOptions = Array.NUMERIC;

var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(indexCol);
myDataGrid.addColumn(labelCol);
myDataGrid.addColumn(priceCol);
myDataGrid.move(10, 40);
myDataGrid.rowCount = myComboBox.length;
myDataGrid.width = 180;
addChild(myDataGrid);

var i:uint;
var item:Object;
for (i = 0; i < myComboBox.length; i++) {
    item = myComboBox.getItemAt(i);
    myDataGrid.addItem({index:i, label:item.label, price:item.price});
}

import fl.controls.*;
import fl.containers.*;
import fl.controls.listClasses.*;
import fl.controls.dataGridClasses.*;
import fl.controls.progressBarClasses.*;
import fl.core.UIComponent;
import fl.data.DataProvider;

var dp:DataProvider = new DataProvider();
dp.addItem( { label: "BaseScrollPane",    data:BaseScrollPane } );
dp.addItem( { label: "Button",             data:Button } );
dp.addItem( { label: "CellRenderer",    data:CellRenderer } );
dp.addItem( { label: "CheckBox",         data:CheckBox } );
dp.addItem( { label: "ColorPicker",     data:ColorPicker } );
dp.addItem( { label: "ComboBox",         data:ComboBox } );
dp.addItem( { label: "DataGrid",         data:DataGrid } );
dp.addItem( { label: "HeaderRenderer",    data:HeaderRenderer } );
dp.addItem( { label: "ImageCell",        data:ImageCell } );
dp.addItem( { label: "IndeterminateBar",data:IndeterminateBar } );
dp.addItem( { label: "Label",             data:Label } );
dp.addItem( { label: "List",             data:List } );
dp.addItem( { label: "NumericStepper",     data:NumericStepper } );
dp.addItem( { label: "ProgressBar",     data:ProgressBar } );
dp.addItem( { label: "RadioButton",     data:RadioButton } );
dp.addItem( { label: "ScrollPane",         data:ScrollPane } );
dp.addItem( { label: "Slider",             data:Slider } );
dp.addItem( { label: "TextArea",         data:TextArea } );
dp.addItem( { label: "TextInput",         data:TextInput } );
dp.addItem( { label: "TileList",         data:TileList } );
dp.addItem( { label: "UILoader",         data:UILoader } );
dp.addItem( { label: "UIComponent",     data:UIComponent } );

var cb:ComboBox = new ComboBox();
cb.move(10,10);
cb.setSize(300,25);
cb.prompt = "Select a component to view its styles";
cb.rowCount = 12;
cb.dataProvider = dp;
cb.addEventListener(Event.CHANGE, showStyleDefinition);
addChild(cb);

var dg:DataGrid = new DataGrid();
dg.setSize(425,300);
dg.move(10,50);
dg.columns = [ new DataGridColumn("StyleName"), new DataGridColumn("DefaultValue") ];
addChild(dg);

function showStyleDefinition(e:Event):void {
    var componentClass:Class = e.target.selectedItem.data as Class;
    var styles:Object = componentClass["getStyleDefinition"].call(this);
    trace(styles.toString());
    var styleData:DataProvider = new DataProvider();
    for(var i:* in styles) {
        trace(i + " : " + styles[i]);
        styleData.addItem( { StyleName:i, DefaultValue:styles[i] } );
    }
    styleData.sortOn("StyleName");
    dg.dataProvider = styleData;
}

import fl.controls.Button;
import fl.controls.ComboBox;
import fl.controls.TextInput;

var greenTF:TextFormat;
var redTF:TextFormat;
var myTextInput:TextInput;
var addButton:Button;
var myComboBox:ComboBox;
var removeButton:Button;

greenTF = new TextFormat();
greenTF.color = 0x006600;

redTF = new TextFormat();
redTF.color = 0xFF0000;

myTextInput = new TextInput();
myTextInput.maxChars = 20;
myTextInput.restrict = "a-zA-Z";
myTextInput.move(10, 10);
addChild(myTextInput);

addButton = new Button();
addButton.label = "(+) Add";
addButton.setStyle("textFormat", greenTF);
addButton.move(120, 10);
addButton.addEventListener(MouseEvent.CLICK, addClickHandler);
addChild(addButton);

myComboBox = new ComboBox();
myComboBox.move(10, 40);
addChild(myComboBox);

removeButton = new Button();
removeButton.label = "(-) Remove All";
removeButton.setStyle("textFormat", redTF);
removeButton.move(120, 40);
removeButton.addEventListener(MouseEvent.CLICK, removeClickHandler);
addChild(removeButton);

function addClickHandler(event:MouseEvent):void {
    if (myTextInput.length > 0) {
        trace("adding item...");
        myComboBox.addItem({label:myTextInput.text});
        myComboBox.sortItemsOn("label", Array.CASEINSENSITIVE);
        myTextInput.text = "";
    }
}

function removeClickHandler(event:MouseEvent):void {
    trace("removing all items...");
    myComboBox.removeAll();
}

import fl.controls.List;
import fl.events.ListEvent;

var myList:List = new List();
myList.addItem( { label: "Carrot" } );
myList.addItem( { label: "Turnip" } );
myList.addItem( { label: "Tomato" } );
myList.addItem( { label: "Blueberry" } );
myList.addEventListener(ListEvent.ITEM_CLICK,removeSelectedItem);
addChild(myList);

function removeSelectedItem(e:ListEvent):void {
    myList.removeItem(e.item);
}

import fl.controls.Button;
import fl.controls.ComboBox;
import fl.controls.TextArea;
import fl.controls.TextInput;

var myComboBox:ComboBox = new ComboBox();
myComboBox.prompt = "Select a user...";
myComboBox.addItem({label:"Person 1"});
myComboBox.addItem({label:"Person 2"});
myComboBox.addItem({label:"Person 3"});
myComboBox.addItem({label:"Person 4"});
myComboBox.width = 150;
myComboBox.move(10, 10);
myComboBox.addEventListener(Event.CHANGE, changeHandler);
addChild(myComboBox);

var myTextInput:TextInput = new TextInput();
myTextInput.restrict = "a-zA-Z0-9";
myTextInput.maxChars = 12;
myTextInput.move(10, 40);
addChild(myTextInput)

var myButton:Button = new Button();
myButton.label = "Replace item";
myButton.addEventListener(MouseEvent.CLICK, clickHandler);
myButton.move(120, 40);
addChild(myButton);

var myTextArea:TextArea = new TextArea();
myTextArea.editable = false;
myTextArea.setSize(320, 240);
myTextArea.move(10, 70);
addChild(myTextArea);

function changeHandler(event:Event):void {
    myTextInput.text = myComboBox.selectedLabel;
}

function clickHandler(event:MouseEvent):void {
    var cIndex:int = myComboBox.selectedIndex;
    if (cIndex > -1) {
        var newItem:Object = {label:myTextInput.text};
        var oldItem:Object = myComboBox.replaceItemAt(newItem, cIndex);
        myComboBox.selectedIndex = cIndex;
        myTextArea.appendText("[index:" + cIndex + "] old:'" + oldItem.label +"', new:'" + newItem.label + "'\n");
        myTextArea.verticalScrollPosition = myTextArea.maxVerticalScrollPosition;
    }
}

import fl.controls.ComboBox;

var cb:ComboBox = new ComboBox();
cb.addItem( { label: "Mercury" } );
cb.addItem( { label: "Venus" } );
cb.addItem( { label: "Earth" } );
cb.addItem( { label: "planet" } );
cb.sortItems(upperCaseSort);
addChild(cb);

function upperCaseSort(a:Object, b:Object):Boolean {
    return a.label.toUpperCase() > b.label.toUpperCase();
}

import fl.controls.ComboBox;

var cb:ComboBox = new ComboBox();
addChild(cb);

// First, populate the ComboBox with the elements.
cb.addItem( { label: "Bananas" } );
cb.addItem( { label: "Apples" } );
cb.addItem( { label: "cherries" } );
cb.addItem( { label: "Grapes" } );

// The following statement sorts using the order parameter set to "ASC", 
// and results in a sort that places "cherries" at the bottom of the list 
// because the sort is case-sensitive.
cb.sortItemsOn("label", "ASC"); 
// resulting order: Apples, Bananas, Grapes, cherries

// The following statement sorts using the order parameter set to "DESC", 
// and results in a sort that places "cherries" at the top of the list 
// because the sort is case-sensitive.
cb.sortItemsOn("label", "DESC");
// resulting order: cherries, Grapes, Bananas, Apples

// The following statement sorts using the optionsFlag parameter set to 
// Array.CASEINSENSITIVE. Note that an ascending sort is the default setting.
cb.sortItemsOn("label", Array.CASEINSENSITIVE);
// resulting order: Apples, Bananas, cherries, Grapes

// The following statement sorts using the optionsFlag parameter set to 
// Array.CASEINSENSITIVE | Array.DESCENDING.
cb.sortItemsOn("label", Array.CASEINSENSITIVE | Array.DESCENDING);
// resulting order: Grapes, cherries, Bananas, Apples

import fl.controls.ComboBox;

var myComboBox:ComboBox = new ComboBox();
myComboBox.addItem({firstName:"Jane", lastName:"Doe"}); 
myComboBox.addItem({firstName:"Bill", lastName:"Smith"});
myComboBox.addItem({firstName:"Tim", lastName:"Jones"});
myComboBox.sortItemsOn("lastName", Array.CASEINSENSITIVE);
myComboBox.labelFunction = nameLabelFunction;
myComboBox.move(10, 10);
addChild(myComboBox);

function nameLabelFunction(item:Object):String {
    return item.lastName + ", " + item.firstName;
}

import fl.controls.ComboBox;

var myComboBox:ComboBox = new ComboBox();
myComboBox.addItem({label:"Item 1"});
myComboBox.addItem({label:"Item 2"});
myComboBox.addItem({label:"Item 3"});
myComboBox.move(10, 10);
myComboBox.addEventListener(Event.OPEN, openHandler);
myComboBox.addEventListener(Event.CLOSE, closeHandler);
addChild(myComboBox);

var isOpen:Boolean = false;

var timer:Timer = new Timer(1000);
timer.addEventListener(TimerEvent.TIMER, timerHandler);
timer.start();

function openHandler(event:Event):void {
    isOpen = true;
}

function closeHandler(event:Event):void {
    isOpen = false;
}

function timerHandler(event:TimerEvent):void {
    if (isOpen) {
        myComboBox.close();
    } else {
        myComboBox.open();
    }
}

import fl.controls.ComboBox;
import fl.controls.TextArea;
import fl.events.ListEvent;

var myComboBox:ComboBox = new ComboBox();
myComboBox.addItem({label:"Item 1"});
myComboBox.addItem({label:"Item 2"});
myComboBox.addItem({label:"Item 3"});
myComboBox.move(10, 10);
myComboBox.addEventListener(Event.OPEN, openHandler);
myComboBox.addEventListener(Event.CLOSE, closeHandler);
myComboBox.addEventListener(ListEvent.ITEM_ROLL_OVER, itemRollOverHandler);
myComboBox.addEventListener(ListEvent.ITEM_ROLL_OUT, itemRollOutHandler);
myComboBox.addEventListener(MouseEvent.ROLL_OVER, rollOverHandler);
myComboBox.addEventListener(MouseEvent.ROLL_OUT, rollOutHandler);
myComboBox.dropdown.addEventListener(MouseEvent.ROLL_OVER, dropdownRollOverHandler)
myComboBox.dropdown.addEventListener(MouseEvent.ROLL_OUT, dropdownRollOutHandler);
addChild(myComboBox);

var myTextArea:TextArea = new TextArea();
myTextArea.editable = false;
myTextArea.setSize(320, 240);
myTextArea.move(120, 10);
addChild(myTextArea);

function openHandler(event:Event):void {
    logEvent("ComboBox open");
}

function closeHandler(event:Event):void {
    logEvent("ComboBox close");
}

function itemRollOverHandler(event:ListEvent):void {
    var rowIdx:uint = event.rowIndex as uint;
    logEvent("ComboBox itemRollOver: " + "`" + myComboBox.getItemAt(rowIdx).label + "`");
}

function itemRollOutHandler(event:ListEvent):void {
    var rowIdx:uint = event.rowIndex as uint;
    logEvent("ComboBox itemRollOut: " + "`" + myComboBox.getItemAt(rowIdx).label + "`");
}

function rollOverHandler(event:MouseEvent):void {
    logEvent("ComboBox rollOver");
    myComboBox.open();
}

function rollOutHandler(event:MouseEvent):void {
    logEvent("ComboBox rollOut");
    myComboBox.close();
}

function dropdownRollOverHandler(event:MouseEvent):void {
    logEvent("ComboBox.dropdown rollOver");
    // reopen ComboBox after it gets closed by the ComboBox rollOut event
    myComboBox.open();
}

function dropdownRollOutHandler(event:MouseEvent):void {
    logEvent("ComboBox.dropdown rollOut");
    myComboBox.close();
}

function logEvent(text:String):void {
    myTextArea.appendText(text + "\n");
    myTextArea.verticalScrollPosition = myTextArea.maxVerticalScrollPosition;
}

import fl.controls.Button;
import fl.controls.ComboBox;

var myComboBox:ComboBox = new ComboBox();
myComboBox.addItem({label:"Item 1"});
myComboBox.addItem({label:"Item 2"});
myComboBox.addItem({label:"Item 3"});
myComboBox.move(10, 10);
myComboBox.addEventListener(MouseEvent.ROLL_OVER, rollOverHandler);
myComboBox.dropdown.addEventListener(MouseEvent.ROLL_OVER, rollOverHandler);
myComboBox.dropdown.addEventListener(MouseEvent.ROLL_OUT, rollOutHandler);
addChild(myComboBox);

var myButton:Button = new Button();
myButton.emphasized = true;
myButton.label = "open ComboBox";
myButton.move(120, 10);
myButton.addEventListener(MouseEvent.CLICK, clickHandler);
addChild(myButton);

var closeTimer:Timer = new Timer(1000, 1);
closeTimer.addEventListener(TimerEvent.TIMER_COMPLETE, timerCompleteHandler);

function clickHandler(event:MouseEvent):void {
    myComboBox.open();
    closeTimer.reset();
    closeTimer.start();
}

function timerCompleteHandler(event:TimerEvent):void {
    myComboBox.close();
}

function rollOverHandler(event:MouseEvent):void {
    closeTimer.stop();
}

function rollOutHandler(event:MouseEvent):void {
    myComboBox.close();
}